Contract Source Code (Solidity Standard Json-Input format)

IDE

• Blockscan IDE
• 🤖 Code ReaderBeta
• Remix IDE

More Options

• Similar
• Sol2Uml
• Submit Audit
• Compare

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermController} from "./interfaces/ITermController.sol";
import {ITermEventEmitter} from "./interfaces/ITermEventEmitter.sol";
import {TermAuctionGroup} from "./lib/TermAuctionGroup.sol";
import {TermContractGroup} from "./lib/TermContractGroup.sol";
import {TermAuction} from "./TermAuction.sol";
import {TermAuctionBidLocker} from "./TermAuctionBidLocker.sol";
import {TermAuctionOfferLocker} from "./TermAuctionOfferLocker.sol";
import {TermPriceConsumerV3} from "./TermPriceConsumerV3.sol";
import {TermRepoCollateralManager} from "./TermRepoCollateralManager.sol";
import {TermRepoLocker} from "./TermRepoLocker.sol";
import {TermRepoRolloverManager} from "./TermRepoRolloverManager.sol";
import {TermRepoServicer} from "./TermRepoServicer.sol";
import {TermRepoToken} from "./TermRepoToken.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import {Versionable} from "./lib/Versionable.sol";

/// @author TermLabs
/// @title Term Initializer
/// @notice This contract provides utility methods for initializing/pairing a set of term/auction contracts
/// @dev This contract operates at the protocol level and provides utility functions for deploying terms/auctions
contract TermInitializer is AccessControlUpgradeable, Versionable {
    // ========================================================================
    // = Errors ===============================================================
    // ========================================================================

    error DeployingPaused();

    // ========================================================================
    // = Access Roles =========================================================
    // ========================================================================

    bytes32 public constant DEPLOYER_ROLE = keccak256("DEPLOYER_ROLE");
    bytes32 public constant INITIALIZER_APPROVAL_ROLE =
        keccak256("INITIALIZER_APPROVAL_ROLE");
    bytes32 public constant DEVOPS_ROLE = keccak256("DEVOPS_ROLE");

    // ========================================================================
    // = State Variables ======================================================
    // ========================================================================

    ITermController internal controller;
    ITermEventEmitter internal emitter;
    TermPriceConsumerV3 internal priceOracle;
    bool internal deployingPaused;

    // ========================================================================
    // = Modifiers  ===========================================================
    // ========================================================================

    modifier whileDeployingNotPaused() {
        if (deployingPaused) {
            revert DeployingPaused();
        }
        _;
    }

    // ========================================================================
    // = Initialize (https://docs.openzeppelin.com/contracts/4.x/upgradeable) =
    // ========================================================================

    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor(address initializerApprovalRole_, address devopsWallet_) {
        _grantRole(DEVOPS_ROLE, devopsWallet_);
        _grantRole(INITIALIZER_APPROVAL_ROLE, initializerApprovalRole_);
        _grantRole(DEPLOYER_ROLE, msg.sender);
        deployingPaused = false;
    }

    function pairTermContracts(
        ITermController controller_,
        ITermEventEmitter emitter_,
        TermPriceConsumerV3 priceOracle_
    ) external onlyRole(DEPLOYER_ROLE) {
        controller = controller_;
        emitter = emitter_;
        priceOracle = priceOracle_;
    }

    // ========================================================================
    // = Interface/API ========================================================
    // ========================================================================

    /// @notice Sets up a set of deployed term contracts
    function setupTerm(
        TermContractGroup calldata termContractGroup,
        address devOpsMultiSig,
        address adminWallet,
        string memory termVersion,
        string memory auctionVersion
    ) external onlyRole(INITIALIZER_APPROVAL_ROLE) whileDeployingNotPaused {
        require(
            controller.isTermDeployed(
                address(termContractGroup.termRepoServicer)
            ),
            "Non-Term TRS"
        );
        require(
            controller.isTermDeployed(
                address(termContractGroup.termRepoCollateralManager)
            ),
            "Non-Term TRCM"
        );
        require(
            controller.isTermDeployed(
                address(termContractGroup.termRepoLocker)
            ),
            "Non-Term TRL"
        );
        require(
            controller.isTermDeployed(address(termContractGroup.termRepoToken)),
            "Non-Term TRT"
        );
        require(
            controller.isTermDeployed(
                address(termContractGroup.rolloverManager)
            ),
            "Non-Term TRM"
        );

        require(
            controller.isTermDeployed(
                address(termContractGroup.termAuctionBidLocker)
            ),
            "Non-Term TABL"
        );
        require(
            controller.isTermDeployed(
                address(termContractGroup.termAuctionOfferLocker)
            ),
            "Non-Term TAOL"
        );
        require(
            controller.isTermDeployed(address(termContractGroup.auction)),
            "Non-Term TA"
        );

        require(
            address(termContractGroup.termRepoServicer) != address(0),
            "Zero Address Servicer"
        );
        require(
            address(termContractGroup.termRepoCollateralManager) != address(0),
            "Zero Address Collateral Manager"
        );
        require(
            address(termContractGroup.termRepoLocker) != address(0),
            "Zero Address Locker"
        );
        require(
            address(termContractGroup.termRepoToken) != address(0),
            "Zero Address RepoToken"
        );
        require(
            address(termContractGroup.rolloverManager) != address(0),
            "Zero Address RolloverManager"
        );
        require(
            address(termContractGroup.termAuctionBidLocker) != address(0),
            "Zero Address termAuctionBidLocker"
        );
        require(
            address(termContractGroup.termAuctionOfferLocker) != address(0),
            "Zero Address termAuctionOfferLocker"
        );
        require(
            address(termContractGroup.auction) != address(0),
            "Zero Address auction"
        );

        emitter.pairTermContract(address(termContractGroup.termRepoLocker));

        controller.pairAuction(address(termContractGroup.auction));

        termContractGroup.termRepoLocker.pairTermContracts(
            address(termContractGroup.termRepoCollateralManager),
            address(termContractGroup.termRepoServicer),
            emitter,
            devOpsMultiSig,
            adminWallet
        );

        emitter.pairTermContract(address(termContractGroup.termRepoToken));
        termContractGroup.termRepoToken.pairTermContracts(
            address(termContractGroup.termRepoServicer),
            emitter,
            devOpsMultiSig,
            adminWallet
        );

        emitter.pairTermContract(
            address(termContractGroup.termAuctionBidLocker)
        );
        termContractGroup.termAuctionBidLocker.pairTermContracts(
            address(termContractGroup.auction),
            termContractGroup.termRepoServicer,
            emitter,
            termContractGroup.termRepoCollateralManager,
            priceOracle,
            devOpsMultiSig,
            adminWallet
        );

        emitter.pairTermContract(
            address(termContractGroup.termAuctionOfferLocker)
        );
        termContractGroup.termAuctionOfferLocker.pairTermContracts(
            address(termContractGroup.auction),
            emitter,
            termContractGroup.termRepoServicer,
            devOpsMultiSig,
            adminWallet
        );

        emitter.pairTermContract(address(termContractGroup.auction));
        termContractGroup.auction.pairTermContracts(
            emitter,
            controller,
            termContractGroup.termRepoServicer,
            termContractGroup.termAuctionBidLocker,
            termContractGroup.termAuctionOfferLocker,
            devOpsMultiSig,
            adminWallet,
            auctionVersion
        );

        emitter.pairTermContract(address(termContractGroup.termRepoServicer));
        termContractGroup.termRepoServicer.pairTermContracts(
            address(termContractGroup.termRepoLocker),
            address(termContractGroup.termRepoCollateralManager),
            address(termContractGroup.termRepoToken),
            address(termContractGroup.termAuctionOfferLocker),
            address(termContractGroup.auction),
            address(termContractGroup.rolloverManager),
            devOpsMultiSig,
            adminWallet,
            termVersion
        );

        emitter.pairTermContract(
            address(termContractGroup.termRepoCollateralManager)
        );
        termContractGroup.termRepoCollateralManager.pairTermContracts(
            address(termContractGroup.termRepoLocker),
            address(termContractGroup.termRepoServicer),
            address(termContractGroup.termAuctionBidLocker),
            address(termContractGroup.auction),
            address(controller),
            address(priceOracle),
            address(termContractGroup.rolloverManager),
            devOpsMultiSig,
            adminWallet
        );

        emitter.pairTermContract(address(termContractGroup.rolloverManager));
        termContractGroup.rolloverManager.pairTermContracts(
            address(termContractGroup.termRepoServicer),
            emitter,
            devOpsMultiSig,
            adminWallet
        );
    }

    /// @notice Sets up a set of deployed term contracts
    function setupAuction(
        TermRepoServicer termRepoServicer,
        TermRepoCollateralManager termRepoCollateralManager,
        TermAuctionOfferLocker termAuctionOfferLocker,
        TermAuctionBidLocker termAuctionBidLocker,
        TermAuction auction,
        address devOpsMultiSig,
        address adminWallet,
        string calldata auctionVersion
    ) external onlyRole(INITIALIZER_APPROVAL_ROLE) whileDeployingNotPaused {
        require(
            controller.isTermDeployed(address(termRepoServicer)),
            "Non-Term TRS"
        );
        require(
            controller.isTermDeployed(address(termRepoCollateralManager)),
            "Non-Term TRCM"
        );

        require(
            controller.isTermDeployed(address(termAuctionBidLocker)),
            "Non-Term TABL"
        );
        require(
            controller.isTermDeployed(address(termAuctionOfferLocker)),
            "Non-Term TAOL"
        );
        require(controller.isTermDeployed(address(auction)), "Non-Term TA");

        require(
            address(termAuctionBidLocker) != address(0),
            "Zero Address termAuctionBidLocker"
        );
        require(
            address(termAuctionOfferLocker) != address(0),
            "Zero Address termAuctionOfferLocker"
        );
        require(
            address(auction) != address(0),
            "Zero Address auction"
        );


        controller.pairAuction(address(auction));

        emitter.pairTermContract(address(termAuctionBidLocker));
        termAuctionBidLocker.pairTermContracts(
            address(auction),
            termRepoServicer,
            emitter,
            termRepoCollateralManager,
            priceOracle,
            devOpsMultiSig,
            adminWallet
        );

        emitter.pairTermContract(address(termAuctionOfferLocker));
        termAuctionOfferLocker.pairTermContracts(
            address(auction),
            emitter,
            termRepoServicer,
            devOpsMultiSig,
            adminWallet
        );

        emitter.pairTermContract(address(auction));
        auction.pairTermContracts(
            emitter,
            controller,
            termRepoServicer,
            termAuctionBidLocker,
            termAuctionOfferLocker,
            devOpsMultiSig,
            adminWallet,
            auctionVersion
        );

        termRepoCollateralManager.reopenToNewAuction(
            TermAuctionGroup({
                auction: auction,
                termAuctionBidLocker: termAuctionBidLocker,
                termAuctionOfferLocker: termAuctionOfferLocker
            })
        );

        termRepoServicer.reopenToNewAuction(
            TermAuctionGroup({
                auction: auction,
                termAuctionBidLocker: termAuctionBidLocker,
                termAuctionOfferLocker: termAuctionOfferLocker
            })
        );
    }

    // ========================================================================
    // = Pause Functions ======================================================
    // ========================================================================

    function pauseDeploying() external onlyRole(DEVOPS_ROLE) {
        deployingPaused = true;
    }

    function unpauseDeploying() external onlyRole(DEVOPS_ROLE) {
        deployingPaused = false;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface AggregatorV3Interface {
  function decimals() external view returns (uint8);

  function description() external view returns (string memory);

  function version() external view returns (uint256);

  function getRoundData(
    uint80 _roundId
  ) external view returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound);

  function latestRoundData()
    external
    view
    returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/AccessControl.sol)

pragma solidity ^0.8.0;

import "./IAccessControlUpgradeable.sol";
import "../utils/ContextUpgradeable.sol";
import "../utils/StringsUpgradeable.sol";
import "../utils/introspection/ERC165Upgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControlUpgradeable is Initializable, ContextUpgradeable, IAccessControlUpgradeable, ERC165Upgradeable {
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }

    mapping(bytes32 => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    function __AccessControl_init() internal onlyInitializing {
    }

    function __AccessControl_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControlUpgradeable).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }

    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        StringsUpgradeable.toHexString(account),
                        " is missing role ",
                        StringsUpgradeable.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");

        _revokeRole(role, account);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * May emit a {RoleGranted} event.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)

pragma solidity ^0.8.0;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControlUpgradeable {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (interfaces/draft-IERC1822.sol)

pragma solidity ^0.8.0;

/**
 * @dev ERC1822: Universal Upgradeable Proxy Standard (UUPS) documents a method for upgradeability through a simplified
 * proxy whose upgrades are fully controlled by the current implementation.
 */
interface IERC1822ProxiableUpgradeable {
    /**
     * @dev Returns the storage slot that the proxiable contract assumes is being used to store the implementation
     * address.
     *
     * IMPORTANT: A proxy pointing at a proxiable contract should not be considered proxiable itself, because this risks
     * bricking a proxy that upgrades to it, by delegating to itself until out of gas. Thus it is critical that this
     * function revert if invoked through a proxy.
     */
    function proxiableUUID() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (interfaces/IERC1967.sol)

pragma solidity ^0.8.0;

/**
 * @dev ERC-1967: Proxy Storage Slots. This interface contains the events defined in the ERC.
 *
 * _Available since v4.8.3._
 */
interface IERC1967Upgradeable {
    /**
     * @dev Emitted when the implementation is upgraded.
     */
    event Upgraded(address indexed implementation);

    /**
     * @dev Emitted when the admin account has changed.
     */
    event AdminChanged(address previousAdmin, address newAdmin);

    /**
     * @dev Emitted when the beacon is changed.
     */
    event BeaconUpgraded(address indexed beacon);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (interfaces/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../token/ERC20/extensions/IERC20MetadataUpgradeable.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (interfaces/IERC5267.sol)

pragma solidity ^0.8.0;

interface IERC5267Upgradeable {
    /**
     * @dev MAY be emitted to signal that the domain could have changed.
     */
    event EIP712DomainChanged();

    /**
     * @dev returns the fields and values that describe the domain separator used by this contract for EIP-712
     * signature.
     */
    function eip712Domain()
        external
        view
        returns (
            bytes1 fields,
            string memory name,
            string memory version,
            uint256 chainId,
            address verifyingContract,
            bytes32 salt,
            uint256[] memory extensions
        );
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (proxy/beacon/IBeacon.sol)

pragma solidity ^0.8.0;

/**
 * @dev This is the interface that {BeaconProxy} expects of its beacon.
 */
interface IBeaconUpgradeable {
    /**
     * @dev Must return an address that can be used as a delegate call target.
     *
     * {BeaconProxy} will check that this address is a contract.
     */
    function implementation() external view returns (address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/ERC1967/ERC1967Upgrade.sol)

pragma solidity ^0.8.2;

import "../beacon/IBeaconUpgradeable.sol";
import "../../interfaces/IERC1967Upgradeable.sol";
import "../../interfaces/draft-IERC1822Upgradeable.sol";
import "../../utils/AddressUpgradeable.sol";
import "../../utils/StorageSlotUpgradeable.sol";
import {Initializable} from "../utils/Initializable.sol";

/**
 * @dev This abstract contract provides getters and event emitting update functions for
 * https://eips.ethereum.org/EIPS/eip-1967[EIP1967] slots.
 *
 * _Available since v4.1._
 */
abstract contract ERC1967UpgradeUpgradeable is Initializable, IERC1967Upgradeable {
    // This is the keccak-256 hash of "eip1967.proxy.rollback" subtracted by 1
    bytes32 private constant _ROLLBACK_SLOT = 0x4910fdfa16fed3260ed0e7147f7cc6da11a60208b5b9406d12a635614ffd9143;

    /**
     * @dev Storage slot with the address of the current implementation.
     * This is the keccak-256 hash of "eip1967.proxy.implementation" subtracted by 1, and is
     * validated in the constructor.
     */
    bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;

    function __ERC1967Upgrade_init() internal onlyInitializing {
    }

    function __ERC1967Upgrade_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev Returns the current implementation address.
     */
    function _getImplementation() internal view returns (address) {
        return StorageSlotUpgradeable.getAddressSlot(_IMPLEMENTATION_SLOT).value;
    }

    /**
     * @dev Stores a new address in the EIP1967 implementation slot.
     */
    function _setImplementation(address newImplementation) private {
        require(AddressUpgradeable.isContract(newImplementation), "ERC1967: new implementation is not a contract");
        StorageSlotUpgradeable.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
    }

    /**
     * @dev Perform implementation upgrade
     *
     * Emits an {Upgraded} event.
     */
    function _upgradeTo(address newImplementation) internal {
        _setImplementation(newImplementation);
        emit Upgraded(newImplementation);
    }

    /**
     * @dev Perform implementation upgrade with additional setup call.
     *
     * Emits an {Upgraded} event.
     */
    function _upgradeToAndCall(address newImplementation, bytes memory data, bool forceCall) internal {
        _upgradeTo(newImplementation);
        if (data.length > 0 || forceCall) {
            AddressUpgradeable.functionDelegateCall(newImplementation, data);
        }
    }

    /**
     * @dev Perform implementation upgrade with security checks for UUPS proxies, and additional setup call.
     *
     * Emits an {Upgraded} event.
     */
    function _upgradeToAndCallUUPS(address newImplementation, bytes memory data, bool forceCall) internal {
        // Upgrades from old implementations will perform a rollback test. This test requires the new
        // implementation to upgrade back to the old, non-ERC1822 compliant, implementation. Removing
        // this special case will break upgrade paths from old UUPS implementation to new ones.
        if (StorageSlotUpgradeable.getBooleanSlot(_ROLLBACK_SLOT).value) {
            _setImplementation(newImplementation);
        } else {
            try IERC1822ProxiableUpgradeable(newImplementation).proxiableUUID() returns (bytes32 slot) {
                require(slot == _IMPLEMENTATION_SLOT, "ERC1967Upgrade: unsupported proxiableUUID");
            } catch {
                revert("ERC1967Upgrade: new implementation is not UUPS");
            }
            _upgradeToAndCall(newImplementation, data, forceCall);
        }
    }

    /**
     * @dev Storage slot with the admin of the contract.
     * This is the keccak-256 hash of "eip1967.proxy.admin" subtracted by 1, and is
     * validated in the constructor.
     */
    bytes32 internal constant _ADMIN_SLOT = 0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103;

    /**
     * @dev Returns the current admin.
     */
    function _getAdmin() internal view returns (address) {
        return StorageSlotUpgradeable.getAddressSlot(_ADMIN_SLOT).value;
    }

    /**
     * @dev Stores a new address in the EIP1967 admin slot.
     */
    function _setAdmin(address newAdmin) private {
        require(newAdmin != address(0), "ERC1967: new admin is the zero address");
        StorageSlotUpgradeable.getAddressSlot(_ADMIN_SLOT).value = newAdmin;
    }

    /**
     * @dev Changes the admin of the proxy.
     *
     * Emits an {AdminChanged} event.
     */
    function _changeAdmin(address newAdmin) internal {
        emit AdminChanged(_getAdmin(), newAdmin);
        _setAdmin(newAdmin);
    }

    /**
     * @dev The storage slot of the UpgradeableBeacon contract which defines the implementation for this proxy.
     * This is bytes32(uint256(keccak256('eip1967.proxy.beacon')) - 1)) and is validated in the constructor.
     */
    bytes32 internal constant _BEACON_SLOT = 0xa3f0ad74e5423aebfd80d3ef4346578335a9a72aeaee59ff6cb3582b35133d50;

    /**
     * @dev Returns the current beacon.
     */
    function _getBeacon() internal view returns (address) {
        return StorageSlotUpgradeable.getAddressSlot(_BEACON_SLOT).value;
    }

    /**
     * @dev Stores a new beacon in the EIP1967 beacon slot.
     */
    function _setBeacon(address newBeacon) private {
        require(AddressUpgradeable.isContract(newBeacon), "ERC1967: new beacon is not a contract");
        require(
            AddressUpgradeable.isContract(IBeaconUpgradeable(newBeacon).implementation()),
            "ERC1967: beacon implementation is not a contract"
        );
        StorageSlotUpgradeable.getAddressSlot(_BEACON_SLOT).value = newBeacon;
    }

    /**
     * @dev Perform beacon upgrade with additional setup call. Note: This upgrades the address of the beacon, it does
     * not upgrade the implementation contained in the beacon (see {UpgradeableBeacon-_setImplementation} for that).
     *
     * Emits a {BeaconUpgraded} event.
     */
    function _upgradeBeaconToAndCall(address newBeacon, bytes memory data, bool forceCall) internal {
        _setBeacon(newBeacon);
        emit BeaconUpgraded(newBeacon);
        if (data.length > 0 || forceCall) {
            AddressUpgradeable.functionDelegateCall(IBeaconUpgradeable(newBeacon).implementation(), data);
        }
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/AddressUpgradeable.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
     * constructor.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!AddressUpgradeable.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: setting the version to 255 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized != type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint8) {
        return _initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _initializing;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/UUPSUpgradeable.sol)

pragma solidity ^0.8.0;

import "../../interfaces/draft-IERC1822Upgradeable.sol";
import "../ERC1967/ERC1967UpgradeUpgradeable.sol";
import {Initializable} from "./Initializable.sol";

/**
 * @dev An upgradeability mechanism designed for UUPS proxies. The functions included here can perform an upgrade of an
 * {ERC1967Proxy}, when this contract is set as the implementation behind such a proxy.
 *
 * A security mechanism ensures that an upgrade does not turn off upgradeability accidentally, although this risk is
 * reinstated if the upgrade retains upgradeability but removes the security mechanism, e.g. by replacing
 * `UUPSUpgradeable` with a custom implementation of upgrades.
 *
 * The {_authorizeUpgrade} function must be overridden to include access restriction to the upgrade mechanism.
 *
 * _Available since v4.1._
 */
abstract contract UUPSUpgradeable is Initializable, IERC1822ProxiableUpgradeable, ERC1967UpgradeUpgradeable {
    /// @custom:oz-upgrades-unsafe-allow state-variable-immutable state-variable-assignment
    address private immutable __self = address(this);

    /**
     * @dev Check that the execution is being performed through a delegatecall call and that the execution context is
     * a proxy contract with an implementation (as defined in ERC1967) pointing to self. This should only be the case
     * for UUPS and transparent proxies that are using the current contract as their implementation. Execution of a
     * function through ERC1167 minimal proxies (clones) would not normally pass this test, but is not guaranteed to
     * fail.
     */
    modifier onlyProxy() {
        require(address(this) != __self, "Function must be called through delegatecall");
        require(_getImplementation() == __self, "Function must be called through active proxy");
        _;
    }

    /**
     * @dev Check that the execution is not being performed through a delegate call. This allows a function to be
     * callable on the implementing contract but not through proxies.
     */
    modifier notDelegated() {
        require(address(this) == __self, "UUPSUpgradeable: must not be called through delegatecall");
        _;
    }

    function __UUPSUpgradeable_init() internal onlyInitializing {
    }

    function __UUPSUpgradeable_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev Implementation of the ERC1822 {proxiableUUID} function. This returns the storage slot used by the
     * implementation. It is used to validate the implementation's compatibility when performing an upgrade.
     *
     * IMPORTANT: A proxy pointing at a proxiable contract should not be considered proxiable itself, because this risks
     * bricking a proxy that upgrades to it, by delegating to itself until out of gas. Thus it is critical that this
     * function revert if invoked through a proxy. This is guaranteed by the `notDelegated` modifier.
     */
    function proxiableUUID() external view virtual override notDelegated returns (bytes32) {
        return _IMPLEMENTATION_SLOT;
    }

    /**
     * @dev Upgrade the implementation of the proxy to `newImplementation`.
     *
     * Calls {_authorizeUpgrade}.
     *
     * Emits an {Upgraded} event.
     *
     * @custom:oz-upgrades-unsafe-allow-reachable delegatecall
     */
    function upgradeTo(address newImplementation) public virtual onlyProxy {
        _authorizeUpgrade(newImplementation);
        _upgradeToAndCallUUPS(newImplementation, new bytes(0), false);
    }

    /**
     * @dev Upgrade the implementation of the proxy to `newImplementation`, and subsequently execute the function call
     * encoded in `data`.
     *
     * Calls {_authorizeUpgrade}.
     *
     * Emits an {Upgraded} event.
     *
     * @custom:oz-upgrades-unsafe-allow-reachable delegatecall
     */
    function upgradeToAndCall(address newImplementation, bytes memory data) public payable virtual onlyProxy {
        _authorizeUpgrade(newImplementation);
        _upgradeToAndCallUUPS(newImplementation, data, true);
    }

    /**
     * @dev Function that should revert when `msg.sender` is not authorized to upgrade the contract. Called by
     * {upgradeTo} and {upgradeToAndCall}.
     *
     * Normally, this function will use an xref:access.adoc[access control] modifier such as {Ownable-onlyOwner}.
     *
     * ```solidity
     * function _authorizeUpgrade(address) internal override onlyOwner {}
     * ```
     */
    function _authorizeUpgrade(address newImplementation) internal virtual;

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuardUpgradeable is Initializable {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    function __ReentrancyGuard_init() internal onlyInitializing {
        __ReentrancyGuard_init_unchained();
    }

    function __ReentrancyGuard_init_unchained() internal onlyInitializing {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20Upgradeable.sol";
import "./extensions/IERC20MetadataUpgradeable.sol";
import "../../utils/ContextUpgradeable.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20Upgradeable is Initializable, ContextUpgradeable, IERC20Upgradeable, IERC20MetadataUpgradeable {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    function __ERC20_init(string memory name_, string memory symbol_) internal onlyInitializing {
        __ERC20_init_unchained(name_, symbol_);
    }

    function __ERC20_init_unchained(string memory name_, string memory symbol_) internal onlyInitializing {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address from, address to, uint256 amount) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(address from, address to, uint256 amount) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[45] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/ERC20Permit.sol)

pragma solidity ^0.8.0;

import "./IERC20PermitUpgradeable.sol";
import "../ERC20Upgradeable.sol";
import "../../../utils/cryptography/ECDSAUpgradeable.sol";
import "../../../utils/cryptography/EIP712Upgradeable.sol";
import "../../../utils/CountersUpgradeable.sol";
import {Initializable} from "../../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on `{IERC20-approve}`, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * _Available since v3.4._
 *
 * @custom:storage-size 51
 */
abstract contract ERC20PermitUpgradeable is Initializable, ERC20Upgradeable, IERC20PermitUpgradeable, EIP712Upgradeable {
    using CountersUpgradeable for CountersUpgradeable.Counter;

    mapping(address => CountersUpgradeable.Counter) private _nonces;

    // solhint-disable-next-line var-name-mixedcase
    bytes32 private constant _PERMIT_TYPEHASH =
        keccak256("Permit(address owner,address spender,uint256 value,uint256 nonce,uint256 deadline)");
    /**
     * @dev In previous versions `_PERMIT_TYPEHASH` was declared as `immutable`.
     * However, to ensure consistency with the upgradeable transpiler, we will continue
     * to reserve a slot.
     * @custom:oz-renamed-from _PERMIT_TYPEHASH
     */
    // solhint-disable-next-line var-name-mixedcase
    bytes32 private _PERMIT_TYPEHASH_DEPRECATED_SLOT;

    /**
     * @dev Initializes the {EIP712} domain separator using the `name` parameter, and setting `version` to `"1"`.
     *
     * It's a good idea to use the same `name` that is defined as the ERC20 token name.
     */
    function __ERC20Permit_init(string memory name) internal onlyInitializing {
        __EIP712_init_unchained(name, "1");
    }

    function __ERC20Permit_init_unchained(string memory) internal onlyInitializing {}

    /**
     * @inheritdoc IERC20PermitUpgradeable
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) public virtual override {
        require(block.timestamp <= deadline, "ERC20Permit: expired deadline");

        bytes32 structHash = keccak256(abi.encode(_PERMIT_TYPEHASH, owner, spender, value, _useNonce(owner), deadline));

        bytes32 hash = _hashTypedDataV4(structHash);

        address signer = ECDSAUpgradeable.recover(hash, v, r, s);
        require(signer == owner, "ERC20Permit: invalid signature");

        _approve(owner, spender, value);
    }

    /**
     * @inheritdoc IERC20PermitUpgradeable
     */
    function nonces(address owner) public view virtual override returns (uint256) {
        return _nonces[owner].current();
    }

    /**
     * @inheritdoc IERC20PermitUpgradeable
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view override returns (bytes32) {
        return _domainSeparatorV4();
    }

    /**
     * @dev "Consume a nonce": return the current value and increment.
     *
     * _Available since v4.1._
     */
    function _useNonce(address owner) internal virtual returns (uint256 current) {
        CountersUpgradeable.Counter storage nonce = _nonces[owner];
        current = nonce.current();
        nonce.increment();
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20Upgradeable.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20MetadataUpgradeable is IERC20Upgradeable {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20PermitUpgradeable {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20Upgradeable {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20Upgradeable.sol";
import "../extensions/IERC20PermitUpgradeable.sol";
import "../../../utils/AddressUpgradeable.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20Upgradeable {
    using AddressUpgradeable for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20Upgradeable token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20Upgradeable token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20Upgradeable token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20Upgradeable token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20Upgradeable token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20Upgradeable token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20PermitUpgradeable token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20Upgradeable token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20Upgradeable token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && AddressUpgradeable.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Counters.sol)

pragma solidity ^0.8.0;

/**
 * @title Counters
 * @author Matt Condon (@shrugs)
 * @dev Provides counters that can only be incremented, decremented or reset. This can be used e.g. to track the number
 * of elements in a mapping, issuing ERC721 ids, or counting request ids.
 *
 * Include with `using Counters for Counters.Counter;`
 */
library CountersUpgradeable {
    struct Counter {
        // This variable should never be directly accessed by users of the library: interactions must be restricted to
        // the library's function. As of Solidity v0.5.2, this cannot be enforced, though there is a proposal to add
        // this feature: see https://github.com/ethereum/solidity/issues/4637
        uint256 _value; // default: 0
    }

    function current(Counter storage counter) internal view returns (uint256) {
        return counter._value;
    }

    function increment(Counter storage counter) internal {
        unchecked {
            counter._value += 1;
        }
    }

    function decrement(Counter storage counter) internal {
        uint256 value = counter._value;
        require(value > 0, "Counter: decrement overflow");
        unchecked {
            counter._value = value - 1;
        }
    }

    function reset(Counter storage counter) internal {
        counter._value = 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.0;

import "../StringsUpgradeable.sol";

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSAUpgradeable {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS,
        InvalidSignatureV // Deprecated in v4.8
    }

    function _throwError(RecoverError error) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert("ECDSA: invalid signature");
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert("ECDSA: invalid signature length");
        } else if (error == RecoverError.InvalidSignatureS) {
            revert("ECDSA: invalid signature 's' value");
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature` or error string. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            /// @solidity memory-safe-assembly
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength);
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, signature);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address, RecoverError) {
        bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
        uint8 v = uint8((uint256(vs) >> 255) + 27);
        return tryRecover(hash, v, r, s);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     *
     * _Available since v4.2._
     */
    function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, r, vs);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address, RecoverError) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature);
        }

        return (signer, RecoverError.NoError);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, v, r, s);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from a `hash`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32 message) {
        // 32 is the length in bytes of hash,
        // enforced by the type signature above
        /// @solidity memory-safe-assembly
        assembly {
            mstore(0x00, "\x19Ethereum Signed Message:\n32")
            mstore(0x1c, hash)
            message := keccak256(0x00, 0x3c)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from `s`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes memory s) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n", StringsUpgradeable.toString(s.length), s));
    }

    /**
     * @dev Returns an Ethereum Signed Typed Data, created from a
     * `domainSeparator` and a `structHash`. This produces hash corresponding
     * to the one signed with the
     * https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
     * JSON-RPC method as part of EIP-712.
     *
     * See {recover}.
     */
    function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32 data) {
        /// @solidity memory-safe-assembly
        assembly {
            let ptr := mload(0x40)
            mstore(ptr, "\x19\x01")
            mstore(add(ptr, 0x02), domainSeparator)
            mstore(add(ptr, 0x22), structHash)
            data := keccak256(ptr, 0x42)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Data with intended validator, created from a
     * `validator` and `data` according to the version 0 of EIP-191.
     *
     * See {recover}.
     */
    function toDataWithIntendedValidatorHash(address validator, bytes memory data) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19\x00", validator, data));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/cryptography/EIP712.sol)

pragma solidity ^0.8.8;

import "./ECDSAUpgradeable.sol";
import "../../interfaces/IERC5267Upgradeable.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";

/**
 * @dev https://eips.ethereum.org/EIPS/eip-712[EIP 712] is a standard for hashing and signing of typed structured data.
 *
 * The encoding specified in the EIP is very generic, and such a generic implementation in Solidity is not feasible,
 * thus this contract does not implement the encoding itself. Protocols need to implement the type-specific encoding
 * they need in their contracts using a combination of `abi.encode` and `keccak256`.
 *
 * This contract implements the EIP 712 domain separator ({_domainSeparatorV4}) that is used as part of the encoding
 * scheme, and the final step of the encoding to obtain the message digest that is then signed via ECDSA
 * ({_hashTypedDataV4}).
 *
 * The implementation of the domain separator was designed to be as efficient as possible while still properly updating
 * the chain id to protect against replay attacks on an eventual fork of the chain.
 *
 * NOTE: This contract implements the version of the encoding known as "v4", as implemented by the JSON RPC method
 * https://docs.metamask.io/guide/signing-data.html[`eth_signTypedDataV4` in MetaMask].
 *
 * NOTE: In the upgradeable version of this contract, the cached values will correspond to the address, and the domain
 * separator of the implementation contract. This will cause the `_domainSeparatorV4` function to always rebuild the
 * separator from the immutable values, which is cheaper than accessing a cached version in cold storage.
 *
 * _Available since v3.4._
 *
 * @custom:storage-size 52
 */
abstract contract EIP712Upgradeable is Initializable, IERC5267Upgradeable {
    bytes32 private constant _TYPE_HASH =
        keccak256("EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)");

    /// @custom:oz-renamed-from _HASHED_NAME
    bytes32 private _hashedName;
    /// @custom:oz-renamed-from _HASHED_VERSION
    bytes32 private _hashedVersion;

    string private _name;
    string private _version;

    /**
     * @dev Initializes the domain separator and parameter caches.
     *
     * The meaning of `name` and `version` is specified in
     * https://eips.ethereum.org/EIPS/eip-712#definition-of-domainseparator[EIP 712]:
     *
     * - `name`: the user readable name of the signing domain, i.e. the name of the DApp or the protocol.
     * - `version`: the current major version of the signing domain.
     *
     * NOTE: These parameters cannot be changed except through a xref:learn::upgrading-smart-contracts.adoc[smart
     * contract upgrade].
     */
    function __EIP712_init(string memory name, string memory version) internal onlyInitializing {
        __EIP712_init_unchained(name, version);
    }

    function __EIP712_init_unchained(string memory name, string memory version) internal onlyInitializing {
        _name = name;
        _version = version;

        // Reset prior values in storage if upgrading
        _hashedName = 0;
        _hashedVersion = 0;
    }

    /**
     * @dev Returns the domain separator for the current chain.
     */
    function _domainSeparatorV4() internal view returns (bytes32) {
        return _buildDomainSeparator();
    }

    function _buildDomainSeparator() private view returns (bytes32) {
        return keccak256(abi.encode(_TYPE_HASH, _EIP712NameHash(), _EIP712VersionHash(), block.chainid, address(this)));
    }

    /**
     * @dev Given an already https://eips.ethereum.org/EIPS/eip-712#definition-of-hashstruct[hashed struct], this
     * function returns the hash of the fully encoded EIP712 message for this domain.
     *
     * This hash can be used together with {ECDSA-recover} to obtain the signer of a message. For example:
     *
     * ```solidity
     * bytes32 digest = _hashTypedDataV4(keccak256(abi.encode(
     *     keccak256("Mail(address to,string contents)"),
     *     mailTo,
     *     keccak256(bytes(mailContents))
     * )));
     * address signer = ECDSA.recover(digest, signature);
     * ```
     */
    function _hashTypedDataV4(bytes32 structHash) internal view virtual returns (bytes32) {
        return ECDSAUpgradeable.toTypedDataHash(_domainSeparatorV4(), structHash);
    }

    /**
     * @dev See {EIP-5267}.
     *
     * _Available since v4.9._
     */
    function eip712Domain()
        public
        view
        virtual
        override
        returns (
            bytes1 fields,
            string memory name,
            string memory version,
            uint256 chainId,
            address verifyingContract,
            bytes32 salt,
            uint256[] memory extensions
        )
    {
        // If the hashed name and version in storage are non-zero, the contract hasn't been properly initialized
        // and the EIP712 domain is not reliable, as it will be missing name and version.
        require(_hashedName == 0 && _hashedVersion == 0, "EIP712: Uninitialized");

        return (
            hex"0f", // 01111
            _EIP712Name(),
            _EIP712Version(),
            block.chainid,
            address(this),
            bytes32(0),
            new uint256[](0)
        );
    }

    /**
     * @dev The name parameter for the EIP712 domain.
     *
     * NOTE: This function reads from storage by default, but can be redefined to return a constant value if gas costs
     * are a concern.
     */
    function _EIP712Name() internal virtual view returns (string memory) {
        return _name;
    }

    /**
     * @dev The version parameter for the EIP712 domain.
     *
     * NOTE: This function reads from storage by default, but can be redefined to return a constant value if gas costs
     * are a concern.
     */
    function _EIP712Version() internal virtual view returns (string memory) {
        return _version;
    }

    /**
     * @dev The hash of the name parameter for the EIP712 domain.
     *
     * NOTE: In previous versions this function was virtual. In this version you should override `_EIP712Name` instead.
     */
    function _EIP712NameHash() internal view returns (bytes32) {
        string memory name = _EIP712Name();
        if (bytes(name).length > 0) {
            return keccak256(bytes(name));
        } else {
            // If the name is empty, the contract may have been upgraded without initializing the new storage.
            // We return the name hash in storage if non-zero, otherwise we assume the name is empty by design.
            bytes32 hashedName = _hashedName;
            if (hashedName != 0) {
                return hashedName;
            } else {
                return keccak256("");
            }
        }
    }

    /**
     * @dev The hash of the version parameter for the EIP712 domain.
     *
     * NOTE: In previous versions this function was virtual. In this version you should override `_EIP712Version` instead.
     */
    function _EIP712VersionHash() internal view returns (bytes32) {
        string memory version = _EIP712Version();
        if (bytes(version).length > 0) {
            return keccak256(bytes(version));
        } else {
            // If the version is empty, the contract may have been upgraded without initializing the new storage.
            // We return the version hash in storage if non-zero, otherwise we assume the version is empty by design.
            bytes32 hashedVersion = _hashedVersion;
            if (hashedVersion != 0) {
                return hashedVersion;
            } else {
                return keccak256("");
            }
        }
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[48] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165Upgradeable.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165Upgradeable is Initializable, IERC165Upgradeable {
    function __ERC165_init() internal onlyInitializing {
    }

    function __ERC165_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165Upgradeable).interfaceId;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165Upgradeable {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library MathUpgradeable {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMathUpgradeable {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/StorageSlot.sol)
// This file was procedurally generated from scripts/generate/templates/StorageSlot.js.

pragma solidity ^0.8.0;

/**
 * @dev Library for reading and writing primitive types to specific storage slots.
 *
 * Storage slots are often used to avoid storage conflict when dealing with upgradeable contracts.
 * This library helps with reading and writing to such slots without the need for inline assembly.
 *
 * The functions in this library return Slot structs that contain a `value` member that can be used to read or write.
 *
 * Example usage to set ERC1967 implementation slot:
 * ```solidity
 * contract ERC1967 {
 *     bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
 *
 *     function _getImplementation() internal view returns (address) {
 *         return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
 *     }
 *
 *     function _setImplementation(address newImplementation) internal {
 *         require(Address.isContract(newImplementation), "ERC1967: new implementation is not a contract");
 *         StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
 *     }
 * }
 * ```
 *
 * _Available since v4.1 for `address`, `bool`, `bytes32`, `uint256`._
 * _Available since v4.9 for `string`, `bytes`._
 */
library StorageSlotUpgradeable {
    struct AddressSlot {
        address value;
    }

    struct BooleanSlot {
        bool value;
    }

    struct Bytes32Slot {
        bytes32 value;
    }

    struct Uint256Slot {
        uint256 value;
    }

    struct StringSlot {
        string value;
    }

    struct BytesSlot {
        bytes value;
    }

    /**
     * @dev Returns an `AddressSlot` with member `value` located at `slot`.
     */
    function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BooleanSlot` with member `value` located at `slot`.
     */
    function getBooleanSlot(bytes32 slot) internal pure returns (BooleanSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `Bytes32Slot` with member `value` located at `slot`.
     */
    function getBytes32Slot(bytes32 slot) internal pure returns (Bytes32Slot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `Uint256Slot` with member `value` located at `slot`.
     */
    function getUint256Slot(bytes32 slot) internal pure returns (Uint256Slot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` with member `value` located at `slot`.
     */
    function getStringSlot(bytes32 slot) internal pure returns (StringSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` representation of the string storage pointer `store`.
     */
    function getStringSlot(string storage store) internal pure returns (StringSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := store.slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` with member `value` located at `slot`.
     */
    function getBytesSlot(bytes32 slot) internal pure returns (BytesSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` representation of the bytes storage pointer `store`.
     */
    function getBytesSlot(bytes storage store) internal pure returns (BytesSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := store.slot
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/MathUpgradeable.sol";
import "./math/SignedMathUpgradeable.sol";

/**
 * @dev String operations.
 */
library StringsUpgradeable {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = MathUpgradeable.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMathUpgradeable.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, MathUpgradeable.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @title ITermAuction Term Auction interface
interface ITermAuction {
    function auctionCancelledForWithdrawal() external view returns (bool);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermAuction} from "./ITermAuction.sol";
import {ITermRepoServicer} from "./ITermRepoServicer.sol";
import {TermAuctionBid} from "../lib/TermAuctionBid.sol";
import {TermAuctionBidSubmission} from "../lib/TermAuctionBidSubmission.sol";
import {TermAuctionRevealedBid} from "../lib/TermAuctionRevealedBid.sol";
import {IERC20Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";

interface ITermAuctionBidLocker {
    function termRepoId() external view returns (bytes32);

    function termAuctionId() external view returns (bytes32);

    function auctionEndTime() external view returns (uint256);

    function dayCountFractionMantissa() external view returns (uint256);

    function purchaseToken() external view returns (address);

    function collateralTokens(
        IERC20Upgradeable token
    ) external view returns (bool);

    function termAuction() external view returns (ITermAuction);

    function termRepoServicer() external view returns (ITermRepoServicer);

    // ========================================================================
    // = Interface/API ========================================================
    // ========================================================================

    /// @param bid A struct containing details of the bid
    function lockRolloverBid(TermAuctionBid calldata bid) external;

    /// @param bidSubmissions An array of bid submissions
    /// @return A bytes32 array of unique on chain bid ids.
    function lockBids(
        TermAuctionBidSubmission[] calldata bidSubmissions
    ) external returns (bytes32[] memory);

    /// @param bidSubmissions An array of Term Auction bid submissions to borrow an amount of money at rate up to but not exceeding the bid rate
    /// @param referralAddress A user address that referred the submitter of this bid
    /// @return A bytes32 array of unique on chain bid ids.
    function lockBidsWithReferral(
        TermAuctionBidSubmission[] calldata bidSubmissions,
        address referralAddress
    ) external returns (bytes32[] memory);

    /// @param id A bid Id
    /// @return A struct containing details of the locked bid
    function lockedBid(
        bytes32 id
    ) external view returns (TermAuctionBid memory);

    /// @param ids An array of bid ids of the bids to reveal
    /// @param prices An array of the bid prices to reveal
    /// @param nonces An array of nonce values to generate bid price hashes
    function revealBids(
        bytes32[] calldata ids,
        uint256[] calldata prices,
        uint256[] calldata nonces
    ) external;

    /// @notice unlockBids unlocks multiple bids and returns funds to the borrower
    /// @param ids An array of ids to unlock
    function unlockBids(bytes32[] calldata ids) external;

    // ========================================================================
    // = Internal Interface/API ===============================================
    // ========================================================================

    /// @param revealedBids An array of the revealed offer ids
    /// @param expiredRolloverBids An array of the expired rollover bid ids
    /// @param unrevealedBids An array of the unrevealed offer ids
    /// @return An array of TermAuctionRevealedBid structs containing details of the revealed bids
    /// @return An array of TermAuctionBid structs containing details of the unrevealed bids
    function getAllBids(
        bytes32[] calldata revealedBids,
        bytes32[] calldata expiredRolloverBids,
        bytes32[] calldata unrevealedBids
    )
        external
        returns (TermAuctionRevealedBid[] memory, TermAuctionBid[] memory);

    /// @param id A bytes32 bid id
    /// @param bidder The address of the bidder
    /// @param bidCollateralTokens The addresses of the token used as collateral
    /// @param amounts The amounts of collateral tokens to unlock
    function auctionUnlockBid(
        bytes32 id,
        address bidder,
        address[] calldata bidCollateralTokens,
        uint256[] calldata amounts
    ) external;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermAuctionLockerErrors} from "./ITermAuctionLockerErrors.sol";

/// @notice ITermAuctionBidLockerErrors is an interface that defines all errors emitted by the Term Auction Bid Locker.
interface ITermAuctionBidLockerErrors is ITermAuctionLockerErrors {
    error BidAmountTooLow(uint256 amount);
    error BidAlreadyRevealed();
    error BidCountIncorrect(uint256 bidCount);
    error BidNotOwned();
    error BidNotRevealed(bytes32 bidId);
    error BidPriceModified(bytes32 id);
    error BidRevealed(bytes32 bidId);
    error CollateralAmountTooLow();
    error GeneratingExistingBid(bytes32 bidId);
    error InvalidPurchaseToken();
    error InvalidTermRepoServicer();
    error RevealedBidsNotSorted();
    error RolloverBid();

    error MaxBidCountReached();
    error NoCollateralToUnlock();
    error NonExistentBid(bytes32 bidId);
    error NonExpiredRolloverBid(bytes32 bidId);
    error NonRolloverBid(bytes32 id);

    error RolloverBidExpired(bytes32 bidId);
    error RolloverBidInShortfall();
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermAuctionBidLockerEvents is an interface that defines all events emitted by the Term Auction Bid Locker.
interface ITermAuctionBidLockerEvents {
    event TermAuctionBidLockerInitialized(
        bytes32 termRepoId,
        bytes32 termAuctionId,
        address termAuctionBidLocker,
        uint256 auctionStartTime,
        uint256 revealTime,
        uint256 maxBidPrice,
        uint256 minimumTenderAmount,
        uint256 dayCountFractionMantissa
    );

    event BidLocked(
        bytes32 termAuctionId,
        bytes32 id,
        address bidder,
        bytes32 bidPrice,
        uint256 amount,
        address token,
        address[] collateralTokens,
        uint256[] collateralAmounts,
        bool isRollover,
        address rolloverPairOffTermRepoServicer,
        address referralAddress
    );

    event BidRevealed(bytes32 termAuctionId, bytes32 id, uint256 bidPrice);

    event BidUnlocked(bytes32 termAuctionId, bytes32 id);

    event BidInShortfall(bytes32 termAuctionId, bytes32 id);

    event BidLockingPaused(bytes32 termAuctionId, bytes32 termRepoId);

    event BidLockingUnpaused(bytes32 termAuctionId, bytes32 termRepoId);

    event BidUnlockingPaused(bytes32 termAuctionId, bytes32 termRepoId);

    event BidUnlockingUnpaused(bytes32 termAuctionId, bytes32 termRepoId);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @title ITermAuctionErrors defines all errors emitted by the Term Auction
interface ITermAuctionErrors {
    /// Term contracts have already been paired.
    error AlreadyTermContractPaired();

    /// Error emmitted when completing an auction that has already been completed
    error AuctionAlreadyCompleted();

    /// Error emmitted when completing an auction that has been cancelled for withdrawal
    error AuctionCancelledForWithdrawal();

    /// Error emmitted when the auction is not closed, but must be
    error AuctionNotClosed();

    /// Error emitted when the provided clearingOffset is not 0 or 1
    error ClearingOffsetNot0Or1(uint256 clearingOffset);

    /// Complete Auction has been paused.
    error CompleteAuctionPaused();

    /// Invalid Parameters passed into function
    error InvalidParameters(string message);

    /// Error emitted when the maximum binary search depth has been exceeded
    error MaxPriceSearchDepthExceeded(uint256 maxDepth);

    /// Error emitted when there are no bids or offers
    error NoBidsOrOffers();
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @title ITermAuctionEvents defines all events emitted by the TermAuctionContract.
interface ITermAuctionEvents {
    /// Event emitted when a new auction is initialized
    /// @param termRepoId The term ID
    /// @param termAuctionId The term auction Id
    /// @param termAuction auction contract address
    /// @param auctionEndTime The auction end time
    /// @param version The version tag of the smart contract deployed
    event TermAuctionInitialized(
        bytes32 termRepoId,
        bytes32 termAuctionId,
        address termAuction,
        uint256 auctionEndTime,
        string version
    );

    /// Event emitted when a bid is assigned
    /// @param termAuctionId The auction ID
    /// @param id The bid ID
    /// @param amount The amount assigned
    event BidAssigned(bytes32 termAuctionId, bytes32 id, uint256 amount);

    /// Event emitted when an offer is assigned
    /// @param termAuctionId The term ID
    /// @param id The offer ID
    /// @param amount The amount assigned
    event OfferAssigned(bytes32 termAuctionId, bytes32 id, uint256 amount);

    /// Event emitted when an auction is completed
    /// @param termAuctionId The ID of the auction
    /// @param timestamp The timestamp of the auction completion
    /// @param block The block of the auction completion
    /// @param totalAssignedBids The total amount of bids assigned
    /// @param totalAssignedOffers The total amount of offers assigned
    /// @param clearingPrice The clearing price of the auction
    event AuctionCompleted(
        bytes32 termAuctionId,
        uint256 timestamp,
        uint256 block,
        uint256 totalAssignedBids,
        uint256 totalAssignedOffers,
        uint256 clearingPrice
    );

    /// Event emitted when an auction is cancelled.
    /// @param termAuctionId The ID of the auction.
    /// @param nonViableAuction Auction not viable due to bid and offer prices not intersecting
    /// @param auctionCancelledforWithdrawal Auction has been cancelled for manual fund withdrawal
    event AuctionCancelled(
        bytes32 termAuctionId,
        bool nonViableAuction,
        bool auctionCancelledforWithdrawal
    );

    /// Event emitted when an auction is paused.
    /// @param termAuctionId The ID of the auction.
    /// @param termRepoId The ID of the repo.
    event CompleteAuctionPaused(bytes32 termAuctionId, bytes32 termRepoId);

    /// Event emitted when an auction is unpaused.
    /// @param termAuctionId The ID of the auction.
    /// @param termRepoId The ID of the repo.
    event CompleteAuctionUnpaused(bytes32 termAuctionId, bytes32 termRepoId);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermAuctionLockerErrors is an interface that defines all errors emitted by the Term Auction Bid and Offer Lockers.
interface ITermAuctionLockerErrors {
    error AlreadyTermContractPaired();
    error AuctionNotOpen();
    error AuctionNotRevealing();
    error AuctionNotClosed();

    error AuctionStartsAfterReveal(uint256 start, uint256 reveal);
    error AuctionRevealsAfterEnd(uint256 reveal, uint256 end);

    error PurchaseTokenNotApproved(address token);
    error CollateralTokenNotApproved(address token);

    error TenderPriceTooHigh(bytes32 id, uint256 maxPrice);

    error LockingPaused();
    error UnlockingPaused();

    error InvalidSelfReferral();
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {TermAuctionOffer} from "../lib/TermAuctionOffer.sol";
import {TermAuctionOfferSubmission} from "../lib/TermAuctionOfferSubmission.sol";
import {TermAuctionRevealedOffer} from "../lib/TermAuctionRevealedOffer.sol";

interface ITermAuctionOfferLocker {
    function auctionEndTime() external view returns (uint256);

    // ========================================================================
    // = Interface/API ========================================================
    // ========================================================================

    /// @param offerSubmissions An array of offer submissions
    /// @return A bytes32 array of unique on chain offer ids.
    function lockOffers(
        TermAuctionOfferSubmission[] calldata offerSubmissions
    ) external returns (bytes32[] memory);

    /// @param offerSubmissions An array of Term Auction offer submissions to lend an amount of money at rate no lower than the offer rate
    /// @param referralAddress A user address that referred the submitter of this offer
    /// @return A bytes32 array of unique on chain offer ids.
    function lockOffersWithReferral(
        TermAuctionOfferSubmission[] calldata offerSubmissions,
        address referralAddress
    ) external returns (bytes32[] memory);

    /// @param id An offer Id
    /// @return A struct containing the details of the locked offer
    function lockedOffer(
        bytes32 id
    ) external view returns (TermAuctionOffer memory);

    /// @param ids An array offer ids to reveal
    /// @param prices An array of the offer prices to reveal
    /// @param nonces An array of nonce values to generate bid price hashes
    function revealOffers(
        bytes32[] calldata ids,
        uint256[] calldata prices,
        uint256[] calldata nonces
    ) external;

    /// @notice unlockOffers unlocks multiple offers and returns funds to the offeror
    /// @param ids An array of offer ids
    function unlockOffers(bytes32[] calldata ids) external;

    // ========================================================================
    // = Internal Interface/API ===============================================
    // ========================================================================

    /// @param revealedOffers An array of the revealed offer ids
    /// @param unrevealedOffers An array of the unrevealed offer ids
    /// @return An array of TermAuctionRevealedOffer structs containing details of the revealed offers
    /// @return An array of TermAuctionOffer structs containing details of the unrevealed offers
    function getAllOffers(
        bytes32[] calldata revealedOffers,
        bytes32[] calldata unrevealedOffers
    )
        external
        returns (TermAuctionRevealedOffer[] memory, TermAuctionOffer[] memory);

    /// @param id An offer Id
    /// @param offeror The address of the offeror
    /// @param amount The amount to unlock
    function unlockOfferPartial(
        bytes32 id,
        address offeror,
        uint256 amount
    ) external;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermAuctionLockerErrors} from "./ITermAuctionLockerErrors.sol";

/// @notice ITermAuctionOfferLockerErrors is an interface that defines all errors emitted by the Term Auction Offer Locker.
interface ITermAuctionOfferLockerErrors is ITermAuctionLockerErrors {
    error GeneratingExistingOffer(bytes32 offerId);
    error MaxOfferCountReached();
    error NonExistentOffer(bytes32 id);
    error NoOfferToUnlock();
    error OfferAlreadyRevealed();
    error OfferAmountTooLow(uint256 amount);
    error OfferCountIncorrect(uint256 offerCount);
    error OfferNotOwned();
    error OfferNotRevealed(bytes32 id);
    error OfferPriceModified();
    error OfferRevealed(bytes32 id);
    error RevealedOffersNotSorted();
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermAuctionOfferLockerEvents is an interface that defines all events emitted by the Term Auction Offer Locker.
interface ITermAuctionOfferLockerEvents {
    event TermAuctionOfferLockerInitialized(
        bytes32 termRepoId,
        bytes32 termAuctionId,
        address termAuctionOfferLocker,
        uint256 auctionStartTime,
        uint256 revealTime,
        uint256 maxOfferPrice,
        uint256 minimumTenderAmount
    );

    event OfferLocked(
        bytes32 termAuctionId,
        bytes32 id,
        address offeror,
        bytes32 offerPrice,
        uint256 amount,
        address token,
        address referralAddress
    );

    event OfferRevealed(bytes32 termAuctionId, bytes32 id, uint256 offerPrice);

    event OfferUnlocked(bytes32 termAuctionId, bytes32 id);

    event OfferLockingPaused(bytes32 termAuctionId, bytes32 termRepoId);

    event OfferLockingUnpaused(bytes32 termAuctionId, bytes32 termRepoId);

    event OfferUnlockingPaused(bytes32 termAuctionId, bytes32 termRepoId);

    event OfferUnlockingUnpaused(bytes32 termAuctionId, bytes32 termRepoId);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {AuctionMetadata} from "../lib/AuctionMetadata.sol";

/// @notice ITermController is an interface that defines events and functions of the Controller contract.
interface ITermController {
    // ========================================================================
    // = Interface/API ========================================================
    // ========================================================================

    /// @notice External view function which returns contract address of treasury wallet
    function getTreasuryAddress() external view returns (address);

    /// @notice External view function which returns contract address of protocol reserve
    function getProtocolReserveAddress() external view returns (address);

    /// @notice External view function which returns if contract address is a Term Finance contract or not
    /// @param contractAddress input contract address
    function isTermDeployed(
        address contractAddress
    ) external view returns (bool);

    /// @notice Returns history of all completed auctions within a term
    /// @param termRepoId term repo id to look up
    function getTermAuctionResults(bytes32 termRepoId) external view returns (AuctionMetadata[] memory auctionMetadata, uint8 numOfAuctions);

    // ========================================================================
    // = Admin Functions ======================================================
    // ========================================================================

    /// @notice Initializer function to pair a new Term Auction with the controller
    /// @param auction    new auction address
    function pairAuction(address auction) external;

    /// @notice Admin function to update the Term Finance treasury wallet address
    /// @param treasuryWallet    new treasury address
    function updateTreasuryAddress(address treasuryWallet) external;

    /// @notice Admin function to update the Term Finance protocol reserve wallet address
    /// @param protocolReserveAddress    new protocol reserve wallet address
    function updateProtocolReserveAddress(
        address protocolReserveAddress
    ) external;

    /// @notice Admin function to add a new Term Finance contract to Controller
    /// @param termContract    new term contract address
    function markTermDeployed(address termContract) external;

    /// @notice Admin function to remove a contract from Controller
    /// @param termContract    term contract address to remove
    function unmarkTermDeployed(address termContract) external;

    /// @notice View Function to lookup if authedUser is granted mint exposure access
    /// @param authedUser    address to check for mint exposure access
    function verifyMintExposureAccess(
        address authedUser
    ) external view returns (bool);

    
    /// @notice Function for auction to add new auction completion information
    /// @param termId    term Id auction belongs to
    /// @param auctionId auction Id for auction
    /// @param auctionClearingRate auction clearing rate
    function recordAuctionResult(bytes32 termId, bytes32 auctionId, uint256 auctionClearingRate) external;

    
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermAuctionEvents} from "./ITermAuctionEvents.sol";
import {ITermAuctionBidLockerEvents} from "./ITermAuctionBidLockerEvents.sol";
import {ITermAuctionOfferLockerEvents} from "./ITermAuctionOfferLockerEvents.sol";
import {ITermRepoCollateralManagerEvents} from "./ITermRepoCollateralManagerEvents.sol";
import {ITermRepoServicerEvents} from "./ITermRepoServicerEvents.sol";
import {ITermRepoRolloverManagerEvents} from "./ITermRepoRolloverManagerEvents.sol";
import {ITermRepoLockerEvents} from "./ITermRepoLockerEvents.sol";
import {ITermRepoTokenEvents} from "./ITermRepoTokenEvents.sol";
import {ITermEventEmitterEvents} from "./ITermEventEmitterEvents.sol";
import {TermAuctionBid} from "../lib/TermAuctionBid.sol";

interface ITermEventEmitter is
    ITermAuctionEvents,
    ITermAuctionBidLockerEvents,
    ITermAuctionOfferLockerEvents,
    ITermRepoCollateralManagerEvents,
    ITermRepoServicerEvents,
    ITermRepoRolloverManagerEvents,
    ITermRepoLockerEvents,
    ITermRepoTokenEvents,
    ITermEventEmitterEvents
{
    //@param termContract New term contract to pair to event emitter.
    function pairTermContract(address termContract) external;

    // ========================================================================
    // = TermAuction Events ===================================================
    // ========================================================================

    /// @param termRepoId The id of the current Term Repo deployment being initialized
    /// @param termAuctionId The id of the auction being initialized
    /// @param termAuction The address of the auction contract being initialized
    /// @param auctionEndTime The end time of the auction being initialized
    /// @param version The version tag of the smart contract deployed
    function emitTermAuctionInitialized(
        bytes32 termRepoId,
        bytes32 termAuctionId,
        address termAuction,
        uint256 auctionEndTime,
        string calldata version
    ) external;

    /// @param termAuctionId A Term Auction id
    /// @param id A bid id
    /// @param amount The amount assigned to this bid
    function emitBidAssigned(
        bytes32 termAuctionId,
        bytes32 id,
        uint256 amount
    ) external;

    /// @param termAuctionId A Term Auction id
    /// @param id An offer id
    /// @param amount The amount assigned to this offer
    function emitOfferAssigned(
        bytes32 termAuctionId,
        bytes32 id,
        uint256 amount
    ) external;

    /// @param termAuctionId The Term Auction id of auction completed
    /// @param timestamp The timestamp of the current block
    /// @param blockNumber The number of the current block
    /// @param totalAssignedBids The number of assigned bids in the auction
    /// @param totalAssignedOffers The number of assigned offers in the auction
    /// @param clearingPrice The clearing price of the auction
    function emitAuctionCompleted(
        bytes32 termAuctionId,
        uint256 timestamp,
        uint256 blockNumber,
        uint256 totalAssignedBids,
        uint256 totalAssignedOffers,
        uint256 clearingPrice
    ) external;

    /// @param nonViableAuction Auction not viable due to bid and offer prices not intersecting
    /// @param auctionCancelledforWithdrawal Auction has been cancelled for withdrawal
    function emitAuctionCancelled(
        bytes32 termAuctionId,
        bool nonViableAuction,
        bool auctionCancelledforWithdrawal
    ) external;

    /// @param termAuctionId The id of the auction paused
    /// @param termRepoId The Term Repo id associated with auction paused
    function emitCompleteAuctionPaused(
        bytes32 termAuctionId,
        bytes32 termRepoId
    ) external;

    /// @param termAuctionId The id of the auction unpaused
    /// @param termRepoId The Term Repo id associated with auction unpaused
    function emitCompleteAuctionUnpaused(
        bytes32 termAuctionId,
        bytes32 termRepoId
    ) external;

    // ========================================================================
    // = TermAuctionBidLocker Events ==========================================
    // ========================================================================

    /// @param termRepoId The Term Repo id associated with BidLocker initialized
    /// @param termAuctionId The Term Auction id associated with BidLocker initialized
    /// @param termAuctionBidLocker The address of the TermAuctionBidLocker contract being intialized
    /// @param auctionStartTime The time at which auction bids will be accepted for submission
    /// @param revealTime The time at which sealed auction bids can be revealed
    /// @param maxBidPrice The maximum tender price (interest rate) in percentage
    /// @param minimumTenderAmount The minimum amount of borrowed purchase token that will be accepted
    /// @param dayCountFractionMantissa The day count fraction remainder
    function emitTermAuctionBidLockerInitialized(
        bytes32 termRepoId,
        bytes32 termAuctionId,
        address termAuctionBidLocker,
        uint256 auctionStartTime,
        uint256 revealTime,
        uint256 maxBidPrice,
        uint256 minimumTenderAmount,
        uint256 dayCountFractionMantissa
    ) external;

    /// @param termAuctionId A Term Auction id
    /// @param bid A struct containing details of the locked bid
    /// @param referralAddress The address of the referrer. Zero Address if none.
    function emitBidLocked(
        bytes32 termAuctionId,
        TermAuctionBid calldata bid,
        address referralAddress
    ) external;

    /// @param termAuctionId A Term Auction id
    /// @param id The bid id
    /// @param bidPrice The revealed price of the bid
    function emitBidRevealed(
        bytes32 termAuctionId,
        bytes32 id,
        uint256 bidPrice
    ) external;

    /// @param termAuctionId A Term Auction id
    /// @param id A bid id
    function emitBidUnlocked(bytes32 termAuctionId, bytes32 id) external;

    /// @param termAuctionId A Term Auction id
    /// @param id A bid id
    function emitBidInShortfall(bytes32 termAuctionId, bytes32 id) external;

    /// @param termAuctionId The id of Term Auction where bid locking is paused
    /// @param termRepoId The Term Repo id where bid locking is paused
    function emitBidLockingPaused(
        bytes32 termAuctionId,
        bytes32 termRepoId
    ) external;

    /// @param termAuctionId The id of Term Auction where bid locking is unpaused
    /// @param termRepoId The Term Repo id where bid locking is unpaused
    function emitBidLockingUnpaused(
        bytes32 termAuctionId,
        bytes32 termRepoId
    ) external;

    /// @param termAuctionId The id of Term Auction where bid unlocking is paused
    /// @param termRepoId The Term Repo id where bid unlocking is paused
    function emitBidUnlockingPaused(
        bytes32 termAuctionId,
        bytes32 termRepoId
    ) external;

    /// @param termAuctionId The id of Term Auction where bid unlocking is unpaused
    /// @param termRepoId The Term Repo id where bid unlocking is unpaused
    function emitBidUnlockingUnpaused(
        bytes32 termAuctionId,
        bytes32 termRepoId
    ) external;

    // ========================================================================
    // = TermAuctionOfferLocker Events ========================================
    // ========================================================================

    /// @param termRepoId The Term Repo id associated with OfferLocker initialized
    /// @param termAuctionId The Term Auction id associated with OfferLocker initialized
    /// @param termAuctionOfferLocker The address of the TermAuctionOfferLocker contract being intialized
    /// @param auctionStartTime The time at which auction bids will be accepted for submission
    /// @param revealTime The time at which sealed auction bids can be revealed
    function emitTermAuctionOfferLockerInitialized(
        bytes32 termRepoId,
        bytes32 termAuctionId,
        address termAuctionOfferLocker,
        uint256 auctionStartTime,
        uint256 revealTime,
        uint256 maxOfferPrice,
        uint256 minimumTenderAmount
    ) external;

    /// @param termAuctionId A Term Auction id
    /// @param id An offer id
    /// @param offeror The address of the offeror
    /// @param offerPrice The offer price
    /// @param amount The amount of purchase tokens offered
    /// @param purchaseToken The address of the purchase token being offered
    /// @param referralAddress The address of the referrer. Zero Address if none.
    function emitOfferLocked(
        bytes32 termAuctionId,
        bytes32 id,
        address offeror,
        bytes32 offerPrice,
        uint256 amount,
        address purchaseToken,
        address referralAddress
    ) external;

    /// @param termAuctionId A Term Auction id
    /// @param id An offer id
    /// @param offerPrice The offer price revealed
    function emitOfferRevealed(
        bytes32 termAuctionId,
        bytes32 id,
        uint256 offerPrice
    ) external;

    /// @param termAuctionId A Term Auction id
    /// @param id An offer id
    function emitOfferUnlocked(bytes32 termAuctionId, bytes32 id) external;

    /// @param termAuctionId The id of Term Auction where offer locking is paused
    /// @param termRepoId The Term Repo id where offer locking is paused
    function emitOfferLockingPaused(
        bytes32 termAuctionId,
        bytes32 termRepoId
    ) external;

    /// @param termAuctionId The id of Term Auction where offer locking is unpaused
    /// @param termRepoId The Term Repo id where offer locking is unpaused
    function emitOfferLockingUnpaused(
        bytes32 termAuctionId,
        bytes32 termRepoId
    ) external;

    /// @param termAuctionId The id of Term Auction where offer unlocking is paused
    /// @param termRepoId The Term Repo id where offer unlocking is paused
    function emitOfferUnlockingPaused(
        bytes32 termAuctionId,
        bytes32 termRepoId
    ) external;

    /// @param termAuctionId The id of Term Auction where offer unlocking is unpaused
    /// @param termRepoId The Term Repo id where offer unlocking is unpaused
    function emitOfferUnlockingUnpaused(
        bytes32 termAuctionId,
        bytes32 termRepoId
    ) external;

    // ========================================================================
    // = TermRepoCollateralManager Events =========================================
    // ========================================================================

    /// @param termRepoId The Term Repo id associated with collateral manger being initialized
    /// @param termRepoCollateralManager The address of the TermRepoCollateralManager contract being intialized
    /// @param collateralTokens An array containing a list of the addresses of all accepted collateral tokens
    /// @param initialCollateralRatios An array containing the initial collateral ratios for each collateral token
    /// @param maintenanceCollateralRatios An array containing the maintenance collateral ratios for each collateral token
    /// @param liquidatedDamagesSchedule An array containing the liquidated damages applicable to each collateral token
    function emitTermRepoCollateralManagerInitialized(
        bytes32 termRepoId,
        address termRepoCollateralManager,
        address[] calldata collateralTokens,
        uint256[] calldata initialCollateralRatios,
        uint256[] calldata maintenanceCollateralRatios,
        uint256[] calldata liquidatedDamagesSchedule
    ) external;

    /// @param termRepoId The Term Repo id for the Term Repo being reopened
    /// @param termRepoCollateralManager The TermRepoCollateralManager address for the Term Repo being reopened
    /// @param termAuctionBidLocker New TermAuctionBidLocker to be paired for reopening
    function emitPairReopeningBidLocker(
        bytes32 termRepoId,
        address termRepoCollateralManager,
        address termAuctionBidLocker
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param borrower The address of the borrower
    /// @param collateralToken The address of the collateral token locked
    /// @param amount The amount of collateral being locked
    function emitCollateralLocked(
        bytes32 termRepoId,
        address borrower,
        address collateralToken,
        uint256 amount
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param borrower The address of the borrower
    /// @param collateralToken The address of the collateral token locked
    /// @param amount The amount of collateral being unlocked
    function emitCollateralUnlocked(
        bytes32 termRepoId,
        address borrower,
        address collateralToken,
        uint256 amount
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param borrower The address of the borrower
    /// @param liquidator The address of the liquidator
    /// @param closureAmount The amount of repurchase exposure covered
    /// @param collateralToken The address of the collateral tokens liquidated
    /// @param amountLiquidated The amount of collateral tokens liquidated
    function emitLiquidation(
        bytes32 termRepoId,
        address borrower,
        address liquidator,
        uint256 closureAmount,
        address collateralToken,
        uint256 amountLiquidated,
        uint256 protocolSeizureAmount,
        bool defaultLiquidation
    ) external;

    /// @param termRepoId The id of Term Repo where liquidations are paused
    function emitLiquidationPaused(bytes32 termRepoId) external;

    /// @param termRepoId The id of Term Repo where liquidation is unpaused
    function emitLiquidationUnpaused(bytes32 termRepoId) external;

    // ========================================================================
    // = TermRepoServicer Events ===============================================
    // ========================================================================

    /// @param termRepoId The Term Repo id associated with TermRepoServicer being initialized
    /// @param termRepoServicer The address of the TermRepoServicer contract being initialized
    /// @param purchaseToken The address of the purchase token
    /// @param maturityTimestamp The time at which repurchase is due
    /// @param endOfRepurchaseWindow The time at which the repurchase window ends
    /// @param redemptionTimestamp The time when redemption of Term Repo Tokens begins
    /// @param servicingFee percentage share of bid amounts charged to bidder
    /// @param version The version tag of the smart contract deployed
    function emitTermRepoServicerInitialized(
        bytes32 termRepoId,
        address termRepoServicer,
        address purchaseToken,
        uint256 maturityTimestamp,
        uint256 endOfRepurchaseWindow,
        uint256 redemptionTimestamp,
        uint256 servicingFee,
        string calldata version
    ) external;

    /// @param termRepoId The Term Repo id for the Term Repo being reopened
    /// @param termRepoServicer The address of the TermRepoServicer contract for the Term Repo being reopened
    /// @param termAuctionOfferLocker The TermAuctionOfferLocker to be paired for reopening
    /// @param termAuction The address of the TermAuction contract to be paired for reopening
    function emitReopeningOfferLockerPaired(
        bytes32 termRepoId,
        address termRepoServicer,
        address termAuctionOfferLocker,
        address termAuction
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param offeror The address of the offeror
    /// @param amount The offer amount to be locked
    /// @notice This event is not to be confused with OfferLocked by TermOfferLocker
    /// @notice Both will be triggered, this one specifically refers to corresponding action taken by Term Servicer
    function emitOfferLockedByServicer(
        bytes32 termRepoId,
        address offeror,
        uint256 amount
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param offeror The address of the offeror
    /// @param amount The offer amount to be unlocked
    /// @notice This event is not to be confused with OfferUnlocked by TermOfferLocker
    /// @notice Both will be triggered, this one specifically refers to corresponding action taken by Term Servicer
    function emitOfferUnlockedByServicer(
        bytes32 termRepoId,
        address offeror,
        uint256 amount
    ) external;

    /// @param offerId Unique id for offer
    /// @param offeror The address of the offeror
    /// @param purchasePrice The offer amount fulfilled
    /// @param repurchasePrice The repurchase price due to offeror at maturity
    /// @param repoTokensMinted The amount of Term Repo Tokens minted to offeror
    function emitOfferFulfilled(
        bytes32 offerId,
        address offeror,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        uint256 repoTokensMinted
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param redeemer The address of the redeemer
    /// @param redemptionAmount The amount of TermRepoTokens redeemed
    /// @param redemptionHaircut The haircut applied to redemptions (if any) due to unrecoverable repo exposure
    function emitTermRepoTokensRedeemed(
        bytes32 termRepoId,
        address redeemer,
        uint256 redemptionAmount,
        uint256 redemptionHaircut
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param bidder The address of the bidder
    /// @param purchasePrice The bid amount fulfilled in auction
    /// @param repurchasePrice The repurchase price due at maturity
    /// @param servicingFees The fees earned by the protocol
    function emitBidFulfilled(
        bytes32 termRepoId,
        address bidder,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        uint256 servicingFees
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param borrower The address of the borrower
    /// @param purchasePrice The purchase price received from new TermRepo
    /// @param repurchasePrice The new repurchase price due at maturity of new TermRepo
    /// @param servicingFees The fees earned by the protocol
    function emitExposureOpenedOnRolloverNew(
        bytes32 termRepoId,
        address borrower,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        uint256 servicingFees
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param borrower The address of the borrower
    /// @param amountRolled The repurchase exposure balance closed on old Term Repo
    function emitExposureClosedOnRolloverExisting(
        bytes32 termRepoId,
        address borrower,
        uint256 amountRolled
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param borrower The address of the borrower
    /// @param amount The amount submitted for repurchase
    function emitRepurchasePaymentSubmitted(
        bytes32 termRepoId,
        address borrower,
        uint256 amount
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param authedUser User granted mint exposure access
    function emitMintExposureAccessGranted(
        bytes32 termRepoId,
        address authedUser
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param minter The address of the minter
    /// @param netTokensReceived The amount of Term Repo Tokens received by minter net of servicing fees
    /// @param servicingFeeTokens The number of Term Repo Tokens retained by protocol in servicing fees
    /// @param repurchasePrice The repurchase exposure opened by minter against Term Repo Token mint
    function emitMintExposure(
        bytes32 termRepoId,
        address minter,
        uint256 netTokensReceived,
        uint256 servicingFeeTokens,
        uint256 repurchasePrice
    ) external;

    /// @param termRepoId A Term Repo id
    /// @param borrower The address of the borrower
    /// @param closeAmount The amount of repurchase exposure to close
    function emitBurnCollapseExposure(
        bytes32 termRepoId,
        address borrower,
        uint256 closeAmount
    ) external;

    // ========================================================================
    // = TermRepoRolloverManager Events ===========================================
    // ========================================================================

    /// @param termRepoId The Term Repo id associated with TermRepoRolloverManager being initialized
    /// @param rolloverManager The address of the TermRepoRolloverManager contract being initialized
    function emitTermRepoRolloverManagerInitialized(
        bytes32 termRepoId,
        address rolloverManager
    ) external;

    /// @param termRepoId The Term Repo id of existing Term Repo
    /// @param rolloverTermAuctionId The Term Auction Id that rollover bid will be submitted into
    function emitRolloverTermApproved(
        bytes32 termRepoId,
        bytes32 rolloverTermAuctionId
    ) external;

    /// @param termRepoId The Term Repo id of existing Term Repo
    /// @param rolloverTermAuctionId The Term Auction Id whose rollover approval is revoked
    function emitRolloverTermApprovalRevoked(
        bytes32 termRepoId,
        bytes32 rolloverTermAuctionId
    ) external;

    /// @param termRepoId The Term Repo id of existing Term Repo
    /// @param rolloverTermRepoId Term Repo Id of Rollover Term Repo
    /// @param borrower The address of the borrower
    /// @param rolloverAuction The address of the auction being rolled over to
    /// @param rolloverAmount The repurchase amount being rolled over
    /// @param hashedBidPrice The hash of the rollover bid price
    function emitRolloverElection(
        bytes32 termRepoId,
        bytes32 rolloverTermRepoId,
        address borrower,
        address rolloverAuction,
        uint256 rolloverAmount,
        bytes32 hashedBidPrice
    ) external;

    /// @param termRepoId The Term Repo id of existing Term Repo
    /// @param borrower The address of the borrower
    function emitRolloverCancellation(
        bytes32 termRepoId,
        address borrower
    ) external;

    /// @param termRepoId The Term Repo id of existing Term Repo
    /// @param borrower The address of the borrower
    function emitRolloverProcessed(
        bytes32 termRepoId,
        address borrower
    ) external;

    // ========================================================================
    // = TermRepoLocker Events ======================================================
    // ========================================================================

    /// @param termRepoId The Term Repo id associated with TermRepoLocker contract being initialized
    /// @param termRepoLocker The address of the TermRepoLocker contract being initialized
    function emitTermRepoLockerInitialized(
        bytes32 termRepoId,
        address termRepoLocker
    ) external;

    /// @param termRepoId A Term Repo id
    function emitTermRepoLockerTransfersPaused(bytes32 termRepoId) external;

    /// @param termRepoId A Term Repo id
    function emitTermRepoLockerTransfersUnpaused(bytes32 termRepoId) external;

    // ========================================================================
    // = TermRepoToken Events =====================================================
    // ========================================================================

    /// @param termRepoId The Term Repo id associated with the TermRepoToken being initalized
    /// @param termRepoToken The address of the TermRepoToken contract being initialized
    /// @param redemptionRatio The number of purchase tokens redeemable per unit of Term Repo Token at par
    function emitTermRepoTokenInitialized(
        bytes32 termRepoId,
        address termRepoToken,
        uint256 redemptionRatio
    ) external;

    /// @param termRepoId The Term Repo id associated with the TermRepoToken where minting is paused
    function emitTermRepoTokenMintingPaused(bytes32 termRepoId) external;

    /// @param termRepoId The Term Repo id associated with the TermRepoToken where minting is unpaused
    function emitTermRepoTokenMintingUnpaused(bytes32 termRepoId) external;

    /// @param termRepoId The Term Repo id associated with the TermRepoToken where burning is paused
    function emitTermRepoTokenBurningPaused(bytes32 termRepoId) external;

    /// @param termRepoId The Term Repo id associated with the TermRepoToken where burning is unpaused
    function emitTermRepoTokenBurningUnpaused(bytes32 termRepoId) external;

    // ========================================================================
    // = TermEventEmitter Events ==============================================
    // ========================================================================

    /// @param termRepoId The id of the Term Repo being delisted
    function emitDelistTermRepo(bytes32 termRepoId) external;

    /// @param termAuctionId The id of the Term Auction being delisted
    function emitDelistTermAuction(bytes32 termAuctionId) external;

    /// @param proxy address of proxy contract
    /// @param implementation address of new impl contract proxy has been upgraded to
    function emitTermContractUpgraded(
        address proxy,
        address implementation
    ) external;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

interface ITermEventEmitterEvents {
    /// @notice Event emitted when a new Term Repo is delisted on Term Finance
    /// @param termRepoId unique identifier for a Term Repo
    event DelistTermRepo(bytes32 termRepoId);

    /// @notice Event emitted when a new Term Auction is delisted on Term Finance
    /// @param termAuctionId unique identifier for a Term Auction
    event DelistTermAuction(bytes32 termAuctionId);

    /// @notice Event emitted when a Term contract is upgraded to a new implementation
    /// @param proxy address of proxy contract
    /// @param implementation address of new impl contract proxy has been upgraded to
    event TermContractUpgraded(address proxy, address implementation);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ExponentialNoError} from "../lib/ExponentialNoError.sol";

interface ITermPriceOracle {
    /// @notice A function to return current market value given a token address and an amount
    /// @param token The address of the token to query
    /// @param amount The amount tokens to value
    /// @return The current market value of tokens at the specified amount, in USD
    function usdValueOfTokens(
        address token,
        uint256 amount
    ) external view returns (ExponentialNoError.Exp memory);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermPriceOracleErrors defines all errors emitted by the PriceOracle.
interface ITermPriceOracleErrors {
    error GracePeriodNotOver();
    error NoPriceFeed(address tokenAddress);
    error SequencerDownError();
    error ZeroPrice();
    error InvalidPrice();
    error PricesStale();
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermPriceOracleEvents is an interface that defines all events emitted by the Term Price Oracle.
interface ITermPriceOracleEvents {
    /// @notice Event emitted when a new price feed is added or updated to price oracle.
    /// @param token The address of the token fee subscribe
    /// @param tokenPriceAggregator The proxy price aggregator address subscribed
    event SubscribePriceFeed(address token, address tokenPriceAggregator);

    /// @notice Event emitted when a price feed is removed from price oracle.
    /// @param token The address of the token
    event UnsubscribePriceFeed(address token);

    /// @notice Event emitted when a new fallback price feed is added or updated to price oracle.
    /// @param token The address of the token fee subscribe
    /// @param tokenPriceAggregator The proxy price aggregator address subscribed
    event SubscribeFallbackPriceFeed(address token, address tokenPriceAggregator);

    /// @notice Event emitted when a fallback price feed is removed from price oracle.
    /// @param token The address of the token
    event UnsubscribeFallbackPriceFeed(address token);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ExponentialNoError} from "../lib/ExponentialNoError.sol";
import {ITermRepoLocker} from "./ITermRepoLocker.sol";

/// @notice ITermManager represents a contract that manages all
interface ITermRepoCollateralManager {
    // ========================================================================
    // = State Variables  =====================================================
    // ========================================================================

    function termRepoLocker() external view returns (ITermRepoLocker);

    function maintenanceCollateralRatios(
        address
    ) external view returns (uint256);

    function initialCollateralRatios(address) external view returns (uint256);

    function numOfAcceptedCollateralTokens() external view returns (uint8);

    function collateralTokens(uint256 index) external view returns (address);

    function encumberedCollateralRemaining() external view returns (bool);

    // ========================================================================
    // = Auction Functions  ===================================================
    // ========================================================================

    /// @param bidder The bidder's address
    /// @param collateralToken The address of the token to be used as collateral
    /// @param amount The amount of the token to lock
    function auctionLockCollateral(
        address bidder,
        address collateralToken,
        uint256 amount
    ) external;

    /// @param bidder The bidder's address
    /// @param collateralToken The address of the token used as collateral
    /// @param amount The amount of collateral tokens to unlock
    function auctionUnlockCollateral(
        address bidder,
        address collateralToken,
        uint256 amount
    ) external;

    // ========================================================================
    // = Rollover Functions  ==================================================
    // ========================================================================

    /// @param borrower The borrower's address
    /// @param rolloverProportion The proportion of the collateral to be unlocked, equal to the proportion of the collateral repaid
    /// @param rolloverTermRepoLocker The address of the new TermRepoLocker contract to roll into
    /// @return An array representing a list of accepted collateral token addresses
    /// @return An array containing the amount of collateral tokens to pairoff and transfer to new TermRepoLocker to roll into
    function transferRolloverCollateral(
        address borrower,
        uint256 rolloverProportion,
        address rolloverTermRepoLocker
    ) external returns (address[] memory, uint256[] memory);

    /// @param borrower The address of the borrower
    /// @param collateralToken The address of a collateral token
    /// @param amount The amount of collateral tokens to lock
    function acceptRolloverCollateral(
        address borrower,
        address collateralToken,
        uint256 amount
    ) external;

    /// @param rolloverAuction The address of the rollover auction
    function approveRolloverAuction(address rolloverAuction) external;

    // ========================================================================
    // = APIs  ================================================================
    // ========================================================================

    /// @param collateralToken The address of the collateral token to lock
    /// @param amount The amount of collateral token to lock
    function externalLockCollateral(
        address collateralToken,
        uint256 amount
    ) external;

    /// @param collateralToken The address of the collateral token to unlock
    /// @param amount The amount of collateral token to unlock
    function externalUnlockCollateral(
        address collateralToken,
        uint256 amount
    ) external;

    /// @param borrower The address of the borrower
    /// @return The market value of borrower's locked collateral denominated in USD
    function getCollateralMarketValue(
        address borrower
    ) external view returns (uint256);

    // ========================================================================
    // = Margin Maintenance Functions  ========================================
    // ========================================================================

    /// @param borrower The address of the borrower
    function unlockCollateralOnRepurchase(address borrower) external;

    /// @param borrower The address of the borrower
    /// @param collateralTokenAddresses Collateral token addresses
    /// @param collateralTokenAmounts Collateral token amounts
    function journalBidCollateralToCollateralManager(
        address borrower,
        address[] calldata collateralTokenAddresses,
        uint256[] calldata collateralTokenAmounts
    ) external;

    /// @param borrower The address of the borrower
    /// @param collateralToken Collateral token addresse
    /// @param amount Collateral token amount
    function mintOpenExposureLockCollateral(
        address borrower,
        address collateralToken,
        uint256 amount
    ) external;

    /// @param collateralToken The collateral token address of tokens locked
    /// @param amountToLock The amount of collateral tokens to lock
    function calculateMintableExposure(
        address collateralToken,
        uint256 amountToLock
    ) external view returns (ExponentialNoError.Exp memory);

    /// @param borrower The address of the borrower
    /// @param collateralToken The collateral token address to query
    /// @return uint256 The amount of collateralToken locked on behalf of borrower
    function getCollateralBalance(
        address borrower,
        address collateralToken
    ) external view returns (uint256);

    /// @param borrower The address of the borrower
    /// @return An array of collateral token addresses
    /// @return An array collateral token balances locked on behalf of borrower
    function getCollateralBalances(
        address borrower
    ) external view returns (address[] memory, uint256[] memory);

    /// @param borrower The address of the borrower
    /// @param closureAmounts An array specifying the amounts of Term Repo exposure the liquidator proposes to cover in liquidation; an amount is required to be specified for each collateral token
    function batchDefault(
        address borrower,
        uint256[] calldata closureAmounts
    ) external;

    /// @param borrower The address of the borrower
    /// @param closureAmounts An array specifying the amounts of Term Repo exposure the liquidator proposes to cover in liquidation; an amount is required to be specified for each collateral token
    function batchLiquidation(
        address borrower,
        uint256[] calldata closureAmounts
    ) external;

    /// @param borrower The address of the borrower
    /// @param closureRepoTokenAmounts An array specifying the amounts of Term Repo Tokens the liquidator proposes to cover borrower repo exposure in liquidation; an amount is required to be specified for each collateral token
    function batchLiquidationWithRepoToken(
        address borrower,
        uint256[] calldata closureRepoTokenAmounts
    ) external;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermRepoCollateralManagerErrors defines all errors emitted by Term Repo Collateral Manager.
interface ITermRepoCollateralManagerErrors {
    error AlreadyTermContractPaired();
    error BorrowerNotInShortfall();
    error CallerNotBorrower();
    error CollateralBelowMaintenanceRatios(address borrower, address token);
    error CollateralDepositClosed();
    error CollateralTokenNotAllowed(address token);
    error CollateralWithdrawalClosed();
    error DefaultsClosed();
    error InvalidParameters(string message);
    error InsufficientCollateralForLiquidationRepayment(
        address collateralToken
    );
    error InsufficientCollateralForRedemption();
    error ExceedsNetExposureCapOnLiquidation();
    error LiquidationsPaused();
    error RepaymentAmountLargerThanAllowed();
    error SelfLiquidationNotPermitted();
    error ShortfallLiquidationsClosed();
    error TermRepurchaseWindowOpen();
    error TotalRepaymentGreaterThangetBorrowerRepurchaseObligation();
    error UnlockAmountGreaterThanCollateralBalance();
    error ZeroAddressContractPaired();
    error ZeroBorrowerRepurchaseObligation();
    error ZeroCollateralBalance();
    error ZeroLiquidationNotPermitted();
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermRepoCollateralManagerEvents is an interface that defines all events emitted by Term Repo Collateral Manager.
interface ITermRepoCollateralManagerEvents {
    /// @notice Event emitted when a Term Repo Collateral Manager is initialized.
    /// @param termRepoId                  term identifier
    /// @param collateralTokens        addresses of accepted collateral tokens
    /// @param initialCollateralRatios list of initial collateral ratios for each collateral token in the same order as collateral tokens list
    /// @param maintenanceCollateralRatios       list of maintenance ratios for each collateral token in the same order as collateral tokens list
    /// @param liquidatedDamagesSchedule    liquidation discounts for collateral tokens
    event TermRepoCollateralManagerInitialized(
        bytes32 termRepoId,
        address termRepoCollateralManager,
        address[] collateralTokens,
        uint256[] initialCollateralRatios,
        uint256[] maintenanceCollateralRatios,
        uint256[] liquidatedDamagesSchedule
    );

    /// @notice Event emitted when existing Term Repo Locker is reopened to another auction group
    /// @param termRepoId                     term identifier
    /// @param termRepoCollateralManager          address of collateral manager
    /// @param termAuctionBidLocker       address of auction bid locker paired through reopening
    event PairReopeningBidLocker(
        bytes32 termRepoId,
        address termRepoCollateralManager,
        address termAuctionBidLocker
    );

    /// @notice Event emitted when collateral is locked.
    /// @param termRepoId             term identifier
    /// @param borrower           address of borrower who locked collateral
    /// @param collateralToken    address of collateral token
    /// @param amount             amount of collateral token locked
    event CollateralLocked(
        bytes32 termRepoId,
        address borrower,
        address collateralToken,
        uint256 amount
    );

    /// @notice Event emitted when collateral is locked.
    /// @param termRepoId             term identifier
    /// @param borrower           address of borrower who locked collateral
    /// @param collateralToken    address of collateral token
    /// @param amount             amount of collateral token unlocked
    event CollateralUnlocked(
        bytes32 termRepoId,
        address borrower,
        address collateralToken,
        uint256 amount
    );

    /// @notice Event emitted when a liquidation occurs
    /// @param termRepoId                term identifier
    /// @param borrower              address of borrower being liquidated
    /// @param liquidator            address of liquidator
    /// @param closureAmount       amount of loan repaid by liquidator
    /// @param collateralToken       address of collateral token liquidated
    /// @param amountLiquidated      amount of collateral liquidated
    /// @param protocolSeizureAmount amount of collateral liquidated and seized by protocol as fee
    /// @param defaultLiquidation    boolean indicating if liquidation is a default or not
    event Liquidation(
        bytes32 termRepoId,
        address borrower,
        address liquidator,
        uint256 closureAmount,
        address collateralToken,
        uint256 amountLiquidated,
        uint256 protocolSeizureAmount,
        bool defaultLiquidation
    );

    /// @notice Event emitted when a Liquidations are paused for a term
    /// @param termRepoId                     term identifier
    event LiquidationsPaused(bytes32 termRepoId);

    /// @notice Event emitted when a Liquidations are unpaused for a term
    /// @param termRepoId                     term identifier
    event LiquidationsUnpaused(bytes32 termRepoId);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice TermRepoLocker contracts lock collateral and purchase tokens
/// @notice Methods should only be callable from paired TermManager.
interface ITermRepoLocker {
    /// @notice Locks tokens from origin wallet
    /// @notice Reverts if caller doesn't have SERVICER_ROLE
    /// @param originWallet Origin wallet to transfer tokens from
    /// @param token Address of token being transferred
    /// @param amount Amount of tokens to transfer
    function transferTokenFromWallet(
        address originWallet,
        address token,
        uint256 amount
    ) external;

    /// @notice Unlocks tokens to destination wallet
    /// @dev Reverts if caller doesn't have SERVICER_ROLE
    /// @param destinationWallet Destination wallet to unlock tokens to
    /// @param token Address of token being unlocked
    /// @param amount Amount of tokens to unlock
    function transferTokenToWallet(
        address destinationWallet,
        address token,
        uint256 amount
    ) external;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermRepoLockerErrors defines all errors emitted by TermRepoLocker.
interface ITermRepoLockerErrors {
    error AlreadyTermContractPaired();
    error ERC20TransferFailed();
    error TermRepoLockerTransfersPaused();
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermRepoLockerEvents is an interface that defines all events emitted by the TermRepoLocker.
interface ITermRepoLockerEvents {
    /// @notice Event emitted when a TermRepoLocker is initialized.
    /// @param termRepoId term identifier
    /// @param termRepoLocker address of initialized term repo locker
    event TermRepoLockerInitialized(bytes32 termRepoId, address termRepoLocker);

    /// @notice Event emitted transfers for a TermRepoLocker are paused.
    /// @param termRepoId term identifier
    event TermRepoLockerTransfersPaused(bytes32 termRepoId);

    /// @notice Event emitted transfers for a TermRepoLocker are unpaused.
    /// @param termRepoId term identifier
    event TermRepoLockerTransfersUnpaused(bytes32 termRepoId);
}

//SPDX-License-Identifier: Unlicense
pragma solidity ^0.8.18;

import {TermRepoRolloverElection} from "../lib/TermRepoRolloverElection.sol";
import {TermRepoRolloverElectionSubmission} from "../lib/TermRepoRolloverElectionSubmission.sol";

interface ITermRepoRolloverManager {
    // ========================================================================
    // = APIs  ================================================================
    // ========================================================================

    /// @notice An external function that accepted Term Repo rollover instructions
    /// @param termRepoRolloverElectionSubmission A struct containing borrower rollover instructions
    function electRollover(
        TermRepoRolloverElectionSubmission
            calldata termRepoRolloverElectionSubmission
    ) external;

    /// @notice A view function that returns borrower rollover instructions
    /// @param borrower The address of the borrower
    /// @return A struct containing borrower rollover instructions
    function getRolloverInstructions(
        address borrower
    ) external view returns (TermRepoRolloverElection memory);

    /// @notice An external function to cancel previously submitted rollover instructions, if it hasn't been locked into an auction
    function cancelRollover() external;

    // ========================================================================
    // = Fulfiller Functions ================================================
    // ========================================================================

    /// @notice An external function called by repo servicer to to mark rollover as fulfilled
    /// @param borrower The address of the borrower
    function fulfillRollover(address borrower) external;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermRepoRolloverManagerErrors defines all errors emitted by TermRepoRolloverManager.
interface ITermRepoRolloverManagerErrors {
    error AlreadyTermContractPaired();
    error AuctionEndsAfterRepayment();
    error AuctionEndsBeforeMaturity();
    error BorrowerRepurchaseObligationInsufficient();
    error CollateralTokenNotSupported(address invalidCollateralToken);
    error DifferentPurchaseToken(
        address currentPurchaseToken,
        address rolloverPurchaseToken
    );
    error InvalidParameters(string reason);
    error MaturityReached();
    error NoRolloverToCancel();
    error NotTermContract(address invalidAddress);
    error RepurchaseWindowOver();
    error RolloverAddressNotApproved(address invalidAddress);
    error RolloverLockedToAuction();
    error RolloverProcessedToTerm();
    error ZeroBorrowerRepurchaseObligation();
}

//SPDX-License-Identifier: Unlicense
pragma solidity ^0.8.18;

/// @notice ITermRepoCollateralManagerEvents is an interface that defines all events emitted by Term Repo Collateral Manager.
interface ITermRepoRolloverManagerEvents {
    /// @notice Event emitted when a rollover manager is initialized
    /// @param termRepoId A Term Repo id
    /// @param rolloverManager Address of rollover manager
    event TermRepoRolloverManagerInitialized(
        bytes32 termRepoId,
        address rolloverManager
    );

    /// @notice Event emitted when a rollover manager approves a future term as a destination for borrows
    /// @param termRepoId A Term Repo id
    /// @param rolloverTermAuctionId The Term Auction Id that rollover bid will be submitted into
    event RolloverTermApproved(
        bytes32 termRepoId,
        bytes32 rolloverTermAuctionId
    );

    /// @notice Event emitted when a rollover manager revokes approval for a future term as a destination for borrows
    /// @param termRepoId A Term Repo id
    /// @param rolloverTermAuctionId The Term Auction Id that rollover bid will be submitted into
    event RolloverTermApprovalRevoked(
        bytes32 termRepoId,
        bytes32 rolloverTermAuctionId
    );

    /// @notice Event emitted when a borrower elects a rollover contract
    /// @param termRepoId A Term Repo id
    /// @param rolloverTermRepoId Term Repo Id of Rollover Term Repo
    /// @param borrower The address of the borrower
    /// @param rolloverAuction The address of rollover term contract
    /// @param rolloverAmount Amount of purchase currency borrower is rolling over
    /// @param hashedBidPrice The hash of rollover bid price
    event RolloverElection(
        bytes32 termRepoId,
        bytes32 rolloverTermRepoId,
        address borrower,
        address rolloverAuction,
        uint256 rolloverAmount,
        bytes32 hashedBidPrice
    );

    /// @notice Event emitted when a borrower cancels a rollover election
    /// @param termRepoId A Term Repo id
    /// @param borrower The address of the borrower
    event RolloverCancellation(bytes32 termRepoId, address borrower);

    /// @notice Event emitted when a rollover is processed completely
    /// @param termRepoId A Term Repo id
    /// @param borrower The address of borrower
    event RolloverProcessed(bytes32 termRepoId, address borrower);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermRepoCollateralManager} from "./ITermRepoCollateralManager.sol";
import {ITermRepoRolloverManager} from "./ITermRepoRolloverManager.sol";
import {ITermRepoLocker} from "./ITermRepoLocker.sol";

/// @notice ITermRepoServicer represents a contract that manages all
interface ITermRepoServicer {
    // ========================================================================
    // = State Variables  =====================================================
    // ========================================================================

    function endOfRepurchaseWindow() external view returns (uint256);

    function maturityTimestamp() external view returns (uint256);

    function redemptionTimestamp() external view returns (uint256);

    function purchaseToken() external view returns (address);

    function servicingFee() external view returns (uint256);

    function termRepoCollateralManager()
        external
        view
        returns (ITermRepoCollateralManager);

    function termRepoRolloverManager()
        external
        view
        returns (ITermRepoRolloverManager);

    function termRepoLocker() external view returns (ITermRepoLocker);

    // ========================================================================
    // = Auction Functions  ===================================================
    // ========================================================================

    /// @param offeror The address of the offeror
    /// @param amount The amount of purchase tokens to lock
    function lockOfferAmount(address offeror, uint256 amount) external;

    /// @param offeror The address of the offeror
    /// @param amount The amount of purchase tokens to unlocked
    function unlockOfferAmount(address offeror, uint256 amount) external;

    /// @param offeror The address of the offeror
    /// @param purchasePrice The offer amount to fulfill
    /// @param repurchasePrice The repurchase price due to offeror at maturity
    /// @param offerId A unique offer id
    function fulfillOffer(
        address offeror,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        bytes32 offerId
    ) external;

    /// @param redeemer The address of redeemer
    /// @param amountToRedeem The amount of TermRepoTokens to redeem
    function redeemTermRepoTokens(
        address redeemer,
        uint256 amountToRedeem
    ) external;

    /// @dev This method allows MINTER_ROLE to open repurchase price exposure against a TermRepoToken mint of corresponding value outside of a Term Auction to create new supply
    /// @param amount The amount of Term Repo Tokens to mint
    /// @param collateralAmounts An array containing an amount of collateral token for each token in collateral basket
    function mintOpenExposure(
        uint256 amount,
        uint256[] calldata collateralAmounts
    ) external;

    /// @param bidder The address of the bidder
    /// @param purchasePrice The bid amount to fulfill
    /// @param repurchasePrice The repurchase price due at maturity
    /// @param collateralTokens Collateral token addresses
    /// @param collateralAmounts Collateral token amounts
    /// @param dayCountFractionMantissa Actual/360 day count fraction parameter from Term Auction Group
    function fulfillBid(
        address bidder,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        address[] calldata collateralTokens,
        uint256[] calldata collateralAmounts,
        uint256 dayCountFractionMantissa
    ) external;

    // ========================================================================
    // = Rollover Functions  ==================================================
    // ========================================================================

    /// @param termAuction The address of a TermAuction contract to receive autioneer role
    function approveRolloverAuction(address termAuction) external;

    /// @param borrower The address of the borrower rolling into new Term Repo
    /// @param purchasePrice The purchase price received from new TermRepo
    /// @param repurchasePrice The new repurchase price due at maturity of new TermRepo
    /// @param previousTermRepoLocker The address of the old TermRepoLocker contract
    /// @param dayCountFractionMantissa Actual/360 day count fraction parameter from Term Auction Group
    /// @return The net purchase price received in after deducing protocol servicing fees
    function openExposureOnRolloverNew(
        address borrower,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        address previousTermRepoLocker,
        uint256 dayCountFractionMantissa
    ) external returns (uint256);

    /// @param borrower The address of the borrower
    /// @param rolloverSettlementAmount The amount of net proceeds received from new TermRepo to pay down existing repurchase obligation due to old Term Repo
    /// @return A uint256 representing the proportion of total repurchase due to old Term Repo from borrower settled by proceeds from new TermRepo
    function closeExposureOnRolloverExisting(
        address borrower,
        uint256 rolloverSettlementAmount
    ) external returns (uint256);

    // ========================================================================
    // = APIs  ================================================================
    // ========================================================================

    /// @notice The max repurchase amount is the repurchase balance less any amounts earmarked for rollover
    /// @param amount The amount of purchase token to submit for repurchase
    function submitRepurchasePayment(uint256 amount) external;

    /// @param amountToBurn The amount of TermRepoTokens to burn
    function burnCollapseExposure(uint256 amountToBurn) external;

    /// @param borrower The address of the borrower to query
    /// @return The total repurchase price due at maturity for a given borrower
    function getBorrowerRepurchaseObligation(
        address borrower
    ) external view returns (uint256);

    /// @param borrower The address of the borrower
    /// @param liquidator The address of the liquidator
    /// @param amountToCover The amount of repurchase exposure to cover in liquidation
    function liquidatorCoverExposure(
        address borrower,
        address liquidator,
        uint256 amountToCover
    ) external;

    /// @param borrower The address of the borrower
    /// @param liquidator The address of the liquidator
    /// @param amountOfRepoToken The amount of term tokens used to cover in liquidation
    /// @return A uint256 representing purchase value of repo tokens burned
    function liquidatorCoverExposureWithRepoToken(
        address borrower,
        address liquidator,
        uint256 amountOfRepoToken
    ) external returns (uint256);

    /// @return A boolean that represents whether the term repo locker is balanced
    function isTermRepoBalanced() external view returns (bool);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermRepoServicerErrors defines all errors emitted by the Term Repo Servicer.
interface ITermRepoServicerErrors {
    error AfterMaturity();
    error AfterRepurchaseWindow();
    error AlreadyTermContractPaired();
    error CallerNotBorrower();
    error EncumberedCollateralRemaining();
    error InsufficientgetBorrowerRepurchaseObligation();
    error InsufficientCollateral();
    error InsufficientTermRepoTokenBalance();
    error InvalidParameters(string message);
    error LockedBalanceInsufficient();
    error NoMintOpenExposureAccess();
    error NotMaturedYet();
    error RedemptionPeriodNotOpen();
    error RepurchaseAmountTooHigh();
    error ZeroBorrowerRepurchaseObligation();
    error ZeroMaxRepurchase();
    error ZeroTermRepoTokenBalance();
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermRepoServicerEvents is an interface that defines all events emitted by the Term Repo Servicer.
interface ITermRepoServicerEvents {
    /// @notice Event emitted when a Term Loan Manager is initialized.
    /// @param termRepoId A Term Repo id
    /// @param purchaseToken The address of purchase token used for loans and repay
    /// @param maturityTimestamp The timestamp at which term reaches maturity
    /// @param endOfRepurchaseWindow The timestamp at which Term Repo is closed to repurchase
    /// @param redemptionTimestamp The timestamp at which loaners can redeem term repo tokens
    /// @param servicingFee percentage share of bid amounts charged to bidder
    /// @param version The version tag of the smart contract deployed
    event TermRepoServicerInitialized(
        bytes32 termRepoId,
        address termRepoServicer,
        address purchaseToken,
        uint256 maturityTimestamp,
        uint256 endOfRepurchaseWindow,
        uint256 redemptionTimestamp,
        uint256 servicingFee,
        string version
    );

    /// @notice Event emitted when a TermRepoLocker is reopened to another auction group
    /// @param termRepoId A Term Repo id
    /// @param termRepoServicer The address of loan manager
    /// @param termAuctionOfferLocker The address of auction offer locker paired through reopening
    /// @param termAuction The address of auction  paired through reopening
    event ReopeningOfferLockerPaired(
        bytes32 termRepoId,
        address termRepoServicer,
        address termAuctionOfferLocker,
        address termAuction
    );

    /// @notice Event emitted when a loan offer is locked.
    /// @param termRepoId A Term Repo id
    /// @param offeror The address who submitted offer
    /// @param amount The amount of purchase token locked for offer
    event OfferLockedByServicer(
        bytes32 termRepoId,
        address offeror,
        uint256 amount
    );

    /// @notice Event emitted when a loan offer is unlocked.
    /// @param termRepoId A Term Repo id
    /// @param offeror The address who submitted offer
    /// @param amount The amount of purchase token unlocked for offer
    event OfferUnlockedByServicer(
        bytes32 termRepoId,
        address offeror,
        uint256 amount
    );

    /// @notice Event emitted when a loan offer is fulfilled.
    /// @param offerId A unique offer id
    /// @param offeror The address whose offer is fulfilled
    /// @param purchasePrice The purchasePrice of loan offer fulfilled
    /// @param repurchasePrice The repurchasePrice of loan offer fulfilled
    /// @param repoTokensMinted The amount of Term Repo Tokens minted to offeror
    event OfferFulfilled(
        bytes32 offerId,
        address offeror,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        uint256 repoTokensMinted
    );

    /// @notice Event emitted when a term repo token is redeemed.
    /// @param termRepoId A Term Repo id
    /// @param redeemer The address who is redeeming term repo tokens
    /// @param redemptionAmount The amount of loan offer redeemed by term repo tokens
    /// @param redemptionHaircut The haircut applied to redemptions (if any) due to unrecoverable repo exposure
    event TermRepoTokensRedeemed(
        bytes32 termRepoId,
        address redeemer,
        uint256 redemptionAmount,
        uint256 redemptionHaircut
    );

    /// @notice Event emitted when a loan is processed to a borrower
    /// @param termRepoId A Term Repo id
    /// @param bidder The address who is receiving the loan
    /// @param purchasePrice The purchasePrice transferred to borrower
    /// @param repurchasePrice The repurchasePrice owed by borrower at maturity
    /// @param servicingFees The protocol fees paid for loan
    event BidFulfilled(
        bytes32 termRepoId,
        address bidder,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        uint256 servicingFees
    );

    /// @notice Event emitted when mint exposure access is granted
    /// @param termRepoId A Term Repo id
    /// @param authedUser User granted mint exposure access
    event MintExposureAccessGranted(bytes32 termRepoId, address authedUser);

    /// @notice Event emitted when a rollover from a previous loan opens a position in this new term
    /// @param termRepoId A Term Repo id
    /// @param borrower The borrower who has loan position opened in new term
    /// @param purchasePrice The purchasePrice transferred to previous term
    /// @param repurchasePrice The repurchasePrice owed by borrower at maturity
    /// @param servicingFees The protocol fees paid for loan
    event ExposureOpenedOnRolloverNew(
        bytes32 termRepoId,
        address borrower,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        uint256 servicingFees
    );

    /// @notice Event emitted when a rollover from a previous loan opens a position in this new term
    /// @param termRepoId A Term Repo id
    /// @param borrower The borrower who has loan position opened in new term
    /// @param amountRolled The amount of borrower loan collapsed by rollover opening
    event ExposureClosedOnRolloverExisting(
        bytes32 termRepoId,
        address borrower,
        uint256 amountRolled
    );

    /// @notice Event emitted when term repo tokens are minted for a loan
    /// @param termRepoId A Term Repo id
    /// @param minter The address who is opening the loan
    /// @param netTokensReceived The amount of Term Repo Tokens received by minter net of servicing fees
    /// @param servicingFeeTokens The number of Term Repo Tokens retained by protocol in servicing fees
    /// @param repurchasePrice The repurchase exposure opened by minter against Term Repo Token mint
    event TermRepoTokenMint(
        bytes32 termRepoId,
        address minter,
        uint256 netTokensReceived,
        uint256 servicingFeeTokens,
        uint256 repurchasePrice
    );

    /// @notice Event emitted when a loan is collapsed by burning term repo tokens
    /// @param termRepoId A Term Repo id
    /// @param borrower The address who is repaying the loan
    /// @param amountToClose The amount repaid by borrower
    event BurnCollapseExposure(
        bytes32 termRepoId,
        address borrower,
        uint256 amountToClose
    );

    /// @notice Event emitted when a loan is repaid by borrower
    /// @param termRepoId A Term Repo id
    /// @param borrower The address who is repaying the loan
    /// @param repurchaseAmount The amount repaid by borrower
    event RepurchasePaymentSubmitted(
        bytes32 termRepoId,
        address borrower,
        uint256 repurchaseAmount
    );
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {IERC20Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";

interface ITermRepoToken is IERC20Upgradeable {
    // ========================================================================
    // = State Variables ======================================================
    // ========================================================================
    /// @notice The number of purchase tokens redeemable
    function redemptionValue() external view returns (uint256);

    // ========================================================================
    // = Interface/API ========================================================
    // ========================================================================

    /// @notice Calculates the total USD redemption value of all outstanding TermRepoTokens
    /// @return totalRedemptionValue Total redemption value of TermRepoTokens in USD
    function totalRedemptionValue() external view returns (uint256);

    /// @notice Burns TermRepoTokens held by an account
    /// @notice Reverts if caller does not have BURNER_ROLE
    /// @param account Address of account holding TermRepoTokens to burn
    /// @param amount Amount of TermRepoTokens to burn without decimal factor
    function burn(address account, uint256 amount) external;

    /// @notice Burns TermRepoTokens held by an account and returns purchase redemption value of tokens burned
    /// @notice Reverts if caller does not have BURNER_ROLE
    /// @param account Address of account holding TermRepoTokens to burn
    /// @param amount Amount of TermRepoTokens to burn without decimal factor
    /// @return totalRedemptionValue Total redemption value of TermRepoTokens burned
    function burnAndReturnValue(
        address account,
        uint256 amount
    ) external returns (uint256);

    /// @notice Mints TermRepoTokens in an amount equal to caller specified target redemption amount
    /// @notice The redemptionValue is the amount of purchase tokens redeemable per unit of TermRepoToken
    /// @notice Reverts if caller does not have MINTER_ROLE
    /// @param account Address of account to mint TermRepoTokens to
    /// @param redemptionAmount The target redemption amount to mint in TermRepoTokens
    function mintRedemptionValue(
        address account,
        uint256 redemptionAmount
    ) external returns (uint256);

    /// @notice Mints an exact amount of TermRepoTokens to an account
    /// @notice Reverts if caller does not have MINTER_ROLE
    /// @param account Theaddress of account to mint TermRepoTokens
    /// @param numTokens         exact number of term repo tokens to mint
    function mintTokens(
        address account,
        uint256 numTokens
    ) external returns (uint256);

    /// @notice Decrements the mintExposureCap
    /// @notice Reverts if caller does not have MINTER_ROLE
    /// @param supplyMinted Number of Tokens Minted
    function decrementMintExposureCap(uint256 supplyMinted) external;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermRepoTokenErrors defines all errors emitted by Term Repo Token.
interface ITermRepoTokenErrors {
    error AlreadyTermContractPaired();
    error TermRepoTokenMintingPaused();
    error TermRepoTokenBurningPaused();
    error MintExposureCapExceeded();
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @notice ITermRepoTokenEvents is an interface that defines all events emitted by the Term Repo Token
interface ITermRepoTokenEvents {
    /// @notice Event emitted when a Term Repo Servicer is initialized.
    /// @param termRepoId term identifier
    /// @param termRepoToken   address of initialized term repo token
    /// @param redemptionRatio The number of purchase tokens redeemable per unit of Term Repo Token at par
    event TermRepoTokenInitialized(
        bytes32 termRepoId,
        address termRepoToken,
        uint256 redemptionRatio
    );

    /// @notice Event emitted when a Term Repo Token Minting is Paused
    /// @param termRepoId A Term Repo id
    event TermRepoTokenMintingPaused(bytes32 termRepoId);

    /// @notice Event emitted when a Term Repo Token Minting is Unpaused
    /// @param termRepoId A Term Repo id
    event TermRepoTokenMintingUnpaused(bytes32 termRepoId);

    /// @notice Event emitted when a Term Repo Token Burning is Paused
    /// @param termRepoId A Term Repo id
    event TermRepoTokenBurningPaused(bytes32 termRepoId);

    /// @notice Event emitted when a Term Repo Token Burning is Unpaused
    /// @param termRepoId A Term Repo id
    event TermRepoTokenBurningUnpaused(bytes32 termRepoId);
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

struct AuctionMetadata {
    bytes32 termAuctionId;
    uint256 auctionClearingRate;
    uint256 auctionClearingBlockTimestamp;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @dev Collateral info for price oracle
struct Collateral {
    address tokenAddress;
    uint256 initialCollateralRatio;
    uint256 maintenanceRatio;
    uint256 liquidatedDamage;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @dev TermAuctionOffer represents an offer to lend an specific amount of tokens at a specific interest rate (or better)
struct CompleteAuctionInput {
    bytes32[] revealedBidSubmissions;
    bytes32[] expiredRolloverBids;
    bytes32[] unrevealedBidSubmissions;
    bytes32[] revealedOfferSubmissions;
    bytes32[] unrevealedOfferSubmissions;
}

// SPDX-License-Identifier: BSD-3-Clause
pragma solidity ^0.8.18;

// solhint-disable

/**
 * @title Exponential module for storing fixed-precision decimals
 * @author Compound
 * @notice Exp is a struct which stores decimals with a fixed precision of 18 decimal places.
 *         Thus, if we wanted to store the 5.1, mantissa would store 5.1e18. That is:
 *         `Exp({mantissa: 5100000000000000000})`.
 */
contract ExponentialNoError {
    uint256 constant expScale = 1e18;
    uint256 constant doubleScale = 1e36;

    struct Exp {
        uint256 mantissa;
    }

    struct Double {
        uint256 mantissa;
    }

    /**
     * @dev Truncates the given exp to a whole number value.
     *      For example, truncate(Exp{mantissa: 15 * expScale}) = 15
     */
    function truncate(Exp memory exp) internal pure returns (uint256) {
        // Note: We are not using careful math here as we're performing a division that cannot fail
        return exp.mantissa / expScale;
    }

    /**
     * @dev Multiply an Exp by a scalar, then truncate to return an unsigned integer.
     */
    function mul_ScalarTruncate(
        Exp memory a,
        uint256 scalar
    ) internal pure returns (uint256) {
        Exp memory product = mul_(a, scalar);
        return truncate(product);
    }

    /**
     * @dev Multiply an Exp by a scalar, truncate, then add an to an unsigned integer, returning an unsigned integer.
     */
    function mul_ScalarTruncateAddUInt(
        Exp memory a,
        uint256 scalar,
        uint256 addend
    ) internal pure returns (uint256) {
        Exp memory product = mul_(a, scalar);
        return add_(truncate(product), addend);
    }

    /**
     * @dev Checks if first Exp is less than second Exp.
     */
    function lessThanExp(
        Exp memory left,
        Exp memory right
    ) internal pure returns (bool) {
        return left.mantissa < right.mantissa;
    }

    /**
     * @dev Checks if left Exp <= right Exp.
     */
    function lessThanOrEqualExp(
        Exp memory left,
        Exp memory right
    ) internal pure returns (bool) {
        return left.mantissa <= right.mantissa;
    }

    /**
     * @dev Checks if left Exp > right Exp.
     */
    function greaterThanExp(
        Exp memory left,
        Exp memory right
    ) internal pure returns (bool) {
        return left.mantissa > right.mantissa;
    }

    /**
     * @dev returns true if Exp is exactly zero
     */
    function isZeroExp(Exp memory value) internal pure returns (bool) {
        return value.mantissa == 0;
    }

    function safe224(
        uint256 n,
        string memory errorMessage
    ) internal pure returns (uint224) {
        require(n < 2 ** 224, errorMessage);
        return uint224(n);
    }

    function safe32(
        uint256 n,
        string memory errorMessage
    ) internal pure returns (uint32) {
        require(n < 2 ** 32, errorMessage);
        return uint32(n);
    }

    function add_(
        Exp memory a,
        Exp memory b
    ) internal pure returns (Exp memory) {
        return Exp({mantissa: add_(a.mantissa, b.mantissa)});
    }

    function add_(
        Double memory a,
        Double memory b
    ) internal pure returns (Double memory) {
        return Double({mantissa: add_(a.mantissa, b.mantissa)});
    }

    function add_(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    function sub_(
        Exp memory a,
        Exp memory b
    ) internal pure returns (Exp memory) {
        return Exp({mantissa: sub_(a.mantissa, b.mantissa)});
    }

    function sub_(
        Double memory a,
        Double memory b
    ) internal pure returns (Double memory) {
        return Double({mantissa: sub_(a.mantissa, b.mantissa)});
    }

    function sub_(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    function mul_(
        Exp memory a,
        Exp memory b
    ) internal pure returns (Exp memory) {
        return Exp({mantissa: mul_(a.mantissa, b.mantissa) / expScale});
    }

    function mul_(Exp memory a, uint256 b) internal pure returns (Exp memory) {
        return Exp({mantissa: mul_(a.mantissa, b)});
    }

    function mul_(uint256 a, Exp memory b) internal pure returns (uint256) {
        return mul_(a, b.mantissa) / expScale;
    }

    function mul_(
        Double memory a,
        Double memory b
    ) internal pure returns (Double memory) {
        return Double({mantissa: mul_(a.mantissa, b.mantissa) / doubleScale});
    }

    function mul_(
        Double memory a,
        uint256 b
    ) internal pure returns (Double memory) {
        return Double({mantissa: mul_(a.mantissa, b)});
    }

    function mul_(uint256 a, Double memory b) internal pure returns (uint256) {
        return mul_(a, b.mantissa) / doubleScale;
    }

    function mul_(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    function div_(
        Exp memory a,
        Exp memory b
    ) internal pure returns (Exp memory) {
        return Exp({mantissa: div_(mul_(a.mantissa, expScale), b.mantissa)});
    }

    function div_(Exp memory a, uint256 b) internal pure returns (Exp memory) {
        return Exp({mantissa: div_(a.mantissa, b)});
    }

    function div_(uint256 a, Exp memory b) internal pure returns (uint256) {
        return div_(mul_(a, expScale), b.mantissa);
    }

    function div_(
        Double memory a,
        Double memory b
    ) internal pure returns (Double memory) {
        return
            Double({mantissa: div_(mul_(a.mantissa, doubleScale), b.mantissa)});
    }

    function div_(
        Double memory a,
        uint256 b
    ) internal pure returns (Double memory) {
        return Double({mantissa: div_(a.mantissa, b)});
    }

    function div_(uint256 a, Double memory b) internal pure returns (uint256) {
        return div_(mul_(a, doubleScale), b.mantissa);
    }

    function div_(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    function fraction(
        uint256 a,
        uint256 b
    ) internal pure returns (Double memory) {
        return Double({mantissa: div_(mul_(a, doubleScale), b)});
    }
}

// solhint-enable

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @dev TermAuctionBid represents a bid to borrow a specific amount of tokens at a specific interest rate (or better)
struct TermAuctionBid {
    /// @dev Unique identifier for this bid
    bytes32 id;
    /// @dev The address of the bidder
    address bidder;
    /// @dev Hash of the offered price as a percentage of the initial loaned amount vs amount returned at maturity. This stores 9 decimal places
    bytes32 bidPriceHash;
    /// @dev Revealed bid price; this is only a valid value if isRevealed is true; this stores 18 decimal places
    uint256 bidPriceRevealed;
    /// @dev The maximum amount of purchase tokens that can be borrowed
    uint256 amount;
    /// @dev The amount of collateral tokens initially locked
    uint256[] collateralAmounts;
    /// @dev The address of the ERC20 purchase token
    address purchaseToken;
    /// @dev The addresses of the collateral ERC20 tokens in the bid
    address[] collateralTokens;
    /// @dev A boolean indicating if bid was submitted as rollover from previous term
    bool isRollover;
    /// @dev The address of term repo servicer whose bid is being rolled over
    address rolloverPairOffTermRepoServicer;
    /// @dev A boolean that is true if bid has been revealed
    bool isRevealed;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @dev TermAuctionBidSubmission represents a bid submission to borrow an amount of money for a specific interest rate
struct TermAuctionBidSubmission {
    /// @dev For an existing bid this is the unique onchain identifier for this bid. For a new bid this is a randomized input that will be used to generate the unique onchain identifier.
    bytes32 id;
    /// @dev The address of the bidder
    address bidder;
    /// @dev Hash of the offered price as a percentage of the initial loaned amount vs amount returned at maturity. This stores 9 decimal places
    bytes32 bidPriceHash;
    /// @dev The maximum amount of purchase tokens that can be borrowed
    uint256 amount;
    /// @dev The amount of collateral tokens initially locked
    uint256[] collateralAmounts;
    /// @dev The address of the ERC20 purchase token
    address purchaseToken;
    /// @dev The addresses of the collateral ERC20 tokens in the bid
    address[] collateralTokens;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermAuctionBidLocker} from "../interfaces/ITermAuctionBidLocker.sol";
import {ITermAuctionOfferLocker} from "../interfaces/ITermAuctionOfferLocker.sol";
import {TermAuction} from "../TermAuction.sol";

/// @dev TermMaturityPeriod represents the contracts in a maturity period. This does not inlude auctions
struct TermAuctionGroup {
    /// @dev The address of the term auction contract
    TermAuction auction;
    /// @dev The address of the collateral manager
    ITermAuctionBidLocker termAuctionBidLocker;
    /// @dev The address of the term repo locker
    ITermAuctionOfferLocker termAuctionOfferLocker;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @dev TermAuctionOffer represents an offer to offeror an amount of money for a specific interest rate
struct TermAuctionOffer {
    /// @dev Unique identifier for this bid
    bytes32 id;
    /// @dev The address of the offeror
    address offeror;
    /// @dev Hash of the offered price as a percentage of the initial loaned amount vs amount returned at maturity. This stores 9 decimal places
    bytes32 offerPriceHash;
    /// @dev Revealed offer price. This is not valid unless isRevealed is true. This stores 18 decimal places
    uint256 offerPriceRevealed;
    /// @dev The maximum amount of purchase tokens that can be lent
    uint256 amount;
    /// @dev The address of the ERC20 purchase token
    address purchaseToken;
    /// @dev Is offer price revealed
    bool isRevealed;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @dev TermAuctionOfferSubmission represents an offer submission to offeror an amount of money for a specific interest rate
struct TermAuctionOfferSubmission {
    /// @dev For an existing offer this is the unique onchain identifier for this offer. For a new offer this is a randomized input that will be used to generate the unique onchain identifier.
    bytes32 id;
    /// @dev The address of the offeror
    address offeror;
    /// @dev Hash of the offered price as a percentage of the initial loaned amount vs amount returned at maturity. This stores 9 decimal places
    bytes32 offerPriceHash;
    /// @dev The maximum amount of purchase tokens that can be lent
    uint256 amount;
    /// @dev The address of the ERC20 purchase token
    address purchaseToken;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @dev TermAuctionBid represents a bid to borrow an amount of money for a specific interest rate
struct TermAuctionRevealedBid {
    /// @dev Unique identifier for this bid
    bytes32 id;
    /// @dev The address of the bidder
    address bidder;
    /// @dev The offered price as a percentage of the initial loaned amount vs amount returned at maturity. This stores 9 decimal places
    uint256 bidPriceRevealed;
    /// @dev The maximum amount of TermRepoTokens borrowed. This stores 18 decimal places
    uint256 amount;
    /// @dev The amount of collateral tokens initially locked
    uint256[] collateralAmounts;
    /// @dev The purchase token address
    address purchaseToken;
    /// @dev The collateral token address
    address[] collateralTokens;
    /// @dev A boolean indicating whether bid is submitted as rollover from previous term
    bool isRollover;
    /// @dev The address of term repo servicer whose bid is being rolled over
    address rolloverPairOffTermRepoServicer;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @dev TermAuctionBid represents an offer to offeror an amount of money for a specific interest rate
struct TermAuctionRevealedOffer {
    /// @dev Unique identifier for this bid
    bytes32 id;
    /// @dev The address of the offeror
    address offeror;
    /// @dev The offered price as a percentage of the initial loaned amount vs amount returned at maturity. This stores 9 decimal places
    uint256 offerPriceRevealed;
    /// @dev The maximum amount of purchase tokens offered
    uint256 amount;
    /// @dev The address of the lent ERC20 token
    address purchaseToken;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {TermAuction} from "../TermAuction.sol";
import {TermAuctionBidLocker} from "../TermAuctionBidLocker.sol";
import {TermAuctionOfferLocker} from "../TermAuctionOfferLocker.sol";
import {TermRepoCollateralManager} from "../TermRepoCollateralManager.sol";
import {TermRepoLocker} from "../TermRepoLocker.sol";
import {TermRepoRolloverManager} from "../TermRepoRolloverManager.sol";
import {TermRepoServicer} from "../TermRepoServicer.sol";
import {TermRepoToken} from "../TermRepoToken.sol";

struct TermContractGroup {
    TermRepoLocker termRepoLocker;
    TermRepoServicer termRepoServicer;
    TermRepoCollateralManager termRepoCollateralManager;
    TermRepoRolloverManager rolloverManager;
    TermRepoToken termRepoToken;
    TermAuctionOfferLocker termAuctionOfferLocker;
    TermAuctionBidLocker termAuctionBidLocker;
    TermAuction auction;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {AggregatorV3Interface} from "@chainlink/contracts/src/v0.8/shared/interfaces/AggregatorV3Interface.sol";


/// @dev TermPriceFeedConfig represents the price feed contracts and the 
struct TermPriceFeedConfig {
    /// @dev The price feed aggregator
    AggregatorV3Interface priceFeed;
    /// @dev Price Feed oracle refresh rate before determined to be stale
    uint256 refreshRateThreshold;
}

//SPDX-License-Identifier: Unlicense
pragma solidity ^0.8.18;

/// @dev TermRepoRolloverElection represents an election to rollover a borrow into a future term
struct TermRepoRolloverElection {
    /// @dev The address of the term auction bidlocker that loan is being rolled into
    address rolloverAuctionBidLocker;
    /// @dev The amount of loan being rolled over
    uint256 rolloverAmount;
    /// @dev The hashed value of the rollover bid price to place in the rollover auction
    bytes32 rolloverBidPriceHash;
    /// @dev A boolean testing whether rollover has been successfully processsed: false if bid fails to lock or is not successful in rollover auction
    bool processed;
}

//SPDX-License-Identifier: Unlicense
pragma solidity ^0.8.18;

/// @dev TermRepoRolloverElectionSubmission represents a user submission for a rollover election to a future term
struct TermRepoRolloverElectionSubmission {
    /// @dev The address of the term auction bidlocker that loan is being rolled into
    address rolloverAuctionBidLocker;
    /// @dev The amount of loan being rolled over
    uint256 rolloverAmount;
    ///@dev The hashed value of the rollover bid price to place in the rollover auction
    bytes32 rolloverBidPriceHash;
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @dev TermRepoTokenConfig represents key metadata associated with a Term Repo Token
struct TermRepoTokenConfig {
    /// @dev The date and time at which the Term Repo associated with this Term Repo Token comes due
    uint256 redemptionTimestamp;
    /// @dev The purchase token in which this Term Repo Token is denominated and is redeemable for
    address purchaseToken;

    //@dev termRepoServicer paired with this repo token
    address termRepoServicer;

    //@dev termRepoCollateralManager paired with this repo token
    address termRepoCollateralManager;
    
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

/// @author TermLabs
/// @title Versionable contract
/// @notice This contract adds a version string that can be queried to all contracts that inherit from it.
/// @dev The version returned is replaced during the build process.
contract Versionable {
    /// @dev This function returns the version of the contract.
    function version() external view returns (string memory) {
        return "0.9.0";
    }
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermAuctionBidLocker} from "./interfaces/ITermAuctionBidLocker.sol";
import {ITermAuctionErrors} from "./interfaces/ITermAuctionErrors.sol";
import {ITermAuctionOfferLocker} from "./interfaces/ITermAuctionOfferLocker.sol";
import {ITermController} from "./interfaces/ITermController.sol";
import {ITermEventEmitter} from "./interfaces/ITermEventEmitter.sol";
import {ITermRepoCollateralManager} from "./interfaces/ITermRepoCollateralManager.sol";
import {ITermRepoRolloverManager} from "./interfaces/ITermRepoRolloverManager.sol";
import {ITermRepoServicer} from "./interfaces/ITermRepoServicer.sol";
import {CompleteAuctionInput} from "./lib/CompleteAuctionInput.sol";
import {ExponentialNoError} from "./lib/ExponentialNoError.sol";
import {TermAuctionBid} from "./lib/TermAuctionBid.sol";
import {TermAuctionOffer} from "./lib/TermAuctionOffer.sol";
import {TermAuctionRevealedBid} from "./lib/TermAuctionRevealedBid.sol";
import {TermAuctionRevealedOffer} from "./lib/TermAuctionRevealedOffer.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {IERC20MetadataUpgradeable} from "@openzeppelin/contracts-upgradeable/interfaces/IERC20MetadataUpgradeable.sol";
import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {ReentrancyGuardUpgradeable} from "@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol";
import {Versionable} from "./lib/Versionable.sol";

/// @author TermLabs
/// @title Term Auction
/// @notice This contract calculates a clearing price in a blind double auction and manages auction clearing and settlement
/// @dev This contract belongs to the Term Auction group of contracts and is specific to a Term Repo deployment
contract TermAuction is
    ITermAuctionErrors,
    UUPSUpgradeable,
    AccessControlUpgradeable,
    ReentrancyGuardUpgradeable,
    ExponentialNoError,
    Versionable
{
    // ========================================================================
    // = Structs  =============================================================
    // ========================================================================
    /// State used during the `calculateClearingPrice` function
    /// @dev Used to reduce the number of stack variables
    struct ClearingPriceState {
        // Variables describing current loop iteration
        uint256 offerPrice; // p^o_i
        uint256 offerIndex; // idxo(p^o_i)
        uint256 bidIndex; // idxb(p^o_i)
        uint256 cumSumOffers; // cso(p^o_i)
        uint256 cumSumBids; // csb(p^o_i)
        uint256 maxClearingVolume; // maxcv_i
        // Variables describing next loop iteration
        uint256 nextOfferIndex;
        uint256 nextBidIndex;
        uint256 nextCumSumOffers;
        uint256 nextCumSumBids;
        uint256 nextOfferPrice;
        uint256 nextMaxClearingVolume;
        // Auxiliary variables
        bool minCumSumCorrection; // Minimisation correction indicator
        uint256 nextBidPrice; // Next bid price in minimisation
        // Principal quantities of interest
        uint256 clearingPrice; // p_c
    }

    // ========================================================================
    // = Constants  ===========================================================
    // ========================================================================
    uint256 public constant THREESIXTY_DAYCOUNT_SECONDS = 360 days;

    // ========================================================================
    // = Access Roles  ========================================================
    // ========================================================================
    bytes32 public constant ADMIN_ROLE = keccak256("ADMIN_ROLE");
    bytes32 public constant DEVOPS_ROLE = keccak256("DEVOPS_ROLE");
    bytes32 public constant INITIALIZER_ROLE = keccak256("INITIALIZER_ROLE");

    // ========================================================================
    // = State Variables  =====================================================
    // ========================================================================

    // Auction configuration.
    bytes32 public termRepoId;
    bytes32 public termAuctionId;
    uint256 public auctionEndTime;
    uint256 public dayCountFractionMantissa;
    ITermRepoServicer public termRepoServicer;
    ITermAuctionBidLocker public termAuctionBidLocker;
    ITermAuctionOfferLocker public termAuctionOfferLocker;
    IERC20MetadataUpgradeable public purchaseToken;
    ITermEventEmitter internal emitter;
    ITermController public controller;

    // Completed auction state
    uint256 public clearingPrice;
    uint256 public clearingPricePostProcessingOffset;
    bool public auctionCompleted;
    bool public auctionCancelledForWithdrawal;
    bool public completeAuctionPaused;
    bool internal termContractPaired;

    // ========================================================================
    // = Modifiers  ===========================================================
    // ========================================================================

    /// @notice This only runs if the auction is closed (after auction end time)
    /// @dev This uses the block timestamp to determine if the auction is closed
    modifier onlyWhileAuctionClosed() {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp <= auctionEndTime) {
            revert AuctionNotClosed();
        }
        _;
    }

    modifier whenCompleteAuctionNotPaused() {
        if (completeAuctionPaused) {
            revert CompleteAuctionPaused();
        }
        _;
    }

    modifier notTermContractPaired() {
        if (termContractPaired) {
            revert AlreadyTermContractPaired();
        }
        termContractPaired = true;
        _;
    }

    // ========================================================================
    // = Deploy (https://docs.openzeppelin.com/contracts/4.x/upgradeable) =
    // ========================================================================

    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor() {
        _disableInitializers();
    }

    /// Initializes the contract
    /// @dev See: https://docs.openzeppelin.com/contracts/4.x/upgradeable
    function initialize(
        string calldata termRepoId_,
        string calldata auctionId_,
        uint256 auctionEndTime_,
        uint256 termStart_,
        uint256 redemptionTimestamp_,
        IERC20MetadataUpgradeable purchaseToken_,
        address termAuctionInitializer_,
        uint256 clearingPricePostProcessingOffset_
    ) external initializer {
        UUPSUpgradeable.__UUPSUpgradeable_init();
        AccessControlUpgradeable.__AccessControl_init();
        ReentrancyGuardUpgradeable.__ReentrancyGuard_init();

        _grantRole(INITIALIZER_ROLE, termAuctionInitializer_);

        termRepoId = keccak256(abi.encodePacked(termRepoId_));
        termAuctionId = keccak256(abi.encodePacked(auctionId_));

        auctionEndTime = auctionEndTime_;
        dayCountFractionMantissa =
            ((redemptionTimestamp_ - termStart_) * expScale) /
            THREESIXTY_DAYCOUNT_SECONDS;
        purchaseToken = purchaseToken_;
        auctionCompleted = false;
        termContractPaired = false;
        auctionCancelledForWithdrawal = false;
        clearingPricePostProcessingOffset = clearingPricePostProcessingOffset_;
    }

    function pairTermContracts(
        ITermEventEmitter emitter_,
        ITermController controller_,
        ITermRepoServicer termRepoServicer_,
        ITermAuctionBidLocker termAuctionBidLocker_,
        ITermAuctionOfferLocker termAuctionOfferLocker_,
        address devopsMultisigAddress_,
        address adminWallet_,
        string calldata version_
    ) external onlyRole(INITIALIZER_ROLE) notTermContractPaired {
        emitter = emitter_;
        controller = controller_;

        termRepoServicer = termRepoServicer_;
        termAuctionBidLocker = termAuctionBidLocker_;
        termAuctionOfferLocker = termAuctionOfferLocker_;

        _grantRole(DEVOPS_ROLE, devopsMultisigAddress_);
        _grantRole(ADMIN_ROLE, adminWallet_);

        emitter.emitTermAuctionInitialized(
            termRepoId,
            termAuctionId,
            address(this),
            auctionEndTime,
            version_
        );
    }

    // ========================================================================
    // = Interface/API ========================================================
    // ========================================================================

    /// @notice Calculates an auction's clearing price, assigns bids/offers, and returns unassigned funds
    /// @param completeAuctionInput A struct containing all revealed and unrevealed bids and offers and expired rollover bids
    function completeAuction(
        CompleteAuctionInput calldata completeAuctionInput
    ) external onlyWhileAuctionClosed whenCompleteAuctionNotPaused {
        if (auctionCompleted) {
            revert AuctionAlreadyCompleted();
        }
        if (auctionCancelledForWithdrawal) {
            revert AuctionCancelledForWithdrawal();
        }
        auctionCompleted = true;

        // Sort bids/offers by price. Orders right on the price
        // edge will be partially filled.
        if (!hasRole(ADMIN_ROLE, msg.sender)) {
            if (
                completeAuctionInput.unrevealedBidSubmissions.length > 0 ||
                completeAuctionInput.unrevealedOfferSubmissions.length > 0
            ) {
                revert InvalidParameters(
                    "All tender prices must be revealed for auction to be complete"
                );
            }
        }

        (
            TermAuctionRevealedBid[] memory sortedBids,
            TermAuctionBid[] memory unrevealedBids
        ) = termAuctionBidLocker.getAllBids(
                completeAuctionInput.revealedBidSubmissions,
                completeAuctionInput.expiredRolloverBids,
                completeAuctionInput.unrevealedBidSubmissions
            );
        (
            TermAuctionRevealedOffer[] memory sortedOffers,
            TermAuctionOffer[] memory unrevealedOffers
        ) = termAuctionOfferLocker.getAllOffers(
                completeAuctionInput.revealedOfferSubmissions,
                completeAuctionInput.unrevealedOfferSubmissions
            );

        // Calculate a clearing price only if both bids and offers exist and market intersects
        if (
            sortedBids.length > 0 &&
            sortedOffers.length > 0 &&
            sortedBids[sortedBids.length - 1].bidPriceRevealed >=
            sortedOffers[0].offerPriceRevealed
        ) {
            (
                ,
                // uint256 clearingPrice_
                uint256 maxAssignable
            ) = _calculateAndStoreClearingPrice(sortedBids, sortedOffers);

            uint256 purchaseTokenDecimals = purchaseToken.decimals();

            // Process revealed bids/offers
            uint256 totalAssignedBids = _assignBids(
                sortedBids,
                maxAssignable,
                purchaseTokenDecimals
            );
            uint256 totalAssignedOffers = _assignOffers(
                sortedOffers,
                maxAssignable,
                purchaseTokenDecimals
            );

            emitter.emitAuctionCompleted(
                termAuctionId, // solhint-disable-next-line not-rely-on-time
                block.timestamp,
                block.number,
                totalAssignedBids,
                totalAssignedOffers,
                clearingPrice
            );

            controller.recordAuctionResult(termRepoId, termAuctionId, clearingPrice);
        } else {
            // Return sorted bid funds.
            for (uint256 i = 0; i < sortedBids.length; ++i) {
                if (sortedBids[i].isRollover) {
                    _markRolloverAsProcessed(
                        sortedBids[i].rolloverPairOffTermRepoServicer,
                        sortedBids[i].bidder
                    );
                } else {
                    termAuctionBidLocker.auctionUnlockBid(
                        sortedBids[i].id,
                        sortedBids[i].bidder,
                        sortedBids[i].collateralTokens,
                        sortedBids[i].collateralAmounts
                    );
                }
            }
            // Return sorted offer funds.
            for (uint256 i = 0; i < sortedOffers.length; ++i) {
                termAuctionOfferLocker.unlockOfferPartial(
                    sortedOffers[i].id,
                    sortedOffers[i].offeror,
                    sortedOffers[i].amount
                );
            }

            if (
                sortedBids.length > 0 &&
                sortedOffers.length > 0 &&
                sortedBids[sortedBids.length - 1].bidPriceRevealed <
                sortedOffers[0].offerPriceRevealed
            ) {
                emitter.emitAuctionCancelled(termAuctionId, true, false);
            } else {
                emitter.emitAuctionCancelled(termAuctionId, false, false);
            }
        }

        // Return unrevealed bid funds.
        for (uint256 i = 0; i < unrevealedBids.length; ++i) {
            if (unrevealedBids[i].isRollover) {
                _markRolloverAsProcessed(
                    unrevealedBids[i].rolloverPairOffTermRepoServicer,
                    unrevealedBids[i].bidder
                );
            } else {
                termAuctionBidLocker.auctionUnlockBid(
                    unrevealedBids[i].id,
                    unrevealedBids[i].bidder,
                    unrevealedBids[i].collateralTokens,
                    unrevealedBids[i].collateralAmounts
                );
            }
        }
        // Return unrevealed offer funds.
        for (uint256 i = 0; i < unrevealedOffers.length; ++i) {
            termAuctionOfferLocker.unlockOfferPartial(
                unrevealedOffers[i].id,
                unrevealedOffers[i].offeror,
                unrevealedOffers[i].amount
            );
        }

        assert(termRepoServicer.isTermRepoBalanced());
    }

    // ========================================================================
    // = Admin ================================================================
    // ========================================================================

    /// @notice Cancels an auction and returns all funds to bidders and fulfillBiders
    /// @param completeAuctionInput A struct containing all revealed and unrevealed bids and offers and expired rollover bids
    function cancelAuction(
        CompleteAuctionInput calldata completeAuctionInput
    ) public onlyWhileAuctionClosed onlyRole(ADMIN_ROLE) {
        // Sort bids/offers by price. Orders right on the price
        // edge will be partially filled.
        (
            TermAuctionRevealedBid[] memory sortedBids,
            TermAuctionBid[] memory unrevealedBids
        ) = termAuctionBidLocker.getAllBids(
                completeAuctionInput.revealedBidSubmissions,
                completeAuctionInput.expiredRolloverBids,
                completeAuctionInput.unrevealedBidSubmissions
            );
        (
            TermAuctionRevealedOffer[] memory sortedOffers,
            TermAuctionOffer[] memory unrevealedOffers
        ) = termAuctionOfferLocker.getAllOffers(
                completeAuctionInput.revealedOfferSubmissions,
                completeAuctionInput.unrevealedOfferSubmissions
            );

        // Return revealed bid funds.
        uint256 i = 0;
        for (i = 0; i < sortedBids.length; ++i) {
            if (sortedBids[i].isRollover) {
                _markRolloverAsProcessed(
                    sortedBids[i].rolloverPairOffTermRepoServicer,
                    sortedBids[i].bidder
                );
            } else {
                termAuctionBidLocker.auctionUnlockBid(
                    sortedBids[i].id,
                    sortedBids[i].bidder,
                    sortedBids[i].collateralTokens,
                    sortedBids[i].collateralAmounts
                );
            }
        }
        // Return revealed offer funds.
        for (i = 0; i < sortedOffers.length; ++i) {
            termAuctionOfferLocker.unlockOfferPartial(
                sortedOffers[i].id,
                sortedOffers[i].offeror,
                sortedOffers[i].amount
            );
        }
        // Return unrevealed bid funds.
        for (i = 0; i < unrevealedBids.length; ++i) {
            if (unrevealedBids[i].isRollover) {
                _markRolloverAsProcessed(
                    unrevealedBids[i].rolloverPairOffTermRepoServicer,
                    unrevealedBids[i].bidder
                );
            } else {
                termAuctionBidLocker.auctionUnlockBid(
                    unrevealedBids[i].id,
                    unrevealedBids[i].bidder,
                    unrevealedBids[i].collateralTokens,
                    unrevealedBids[i].collateralAmounts
                );
            }
        }
        // Return unrevealed offer funds.
        for (i = 0; i < unrevealedOffers.length; ++i) {
            termAuctionOfferLocker.unlockOfferPartial(
                unrevealedOffers[i].id,
                unrevealedOffers[i].offeror,
                unrevealedOffers[i].amount
            );
        }

        emitter.emitAuctionCancelled(termAuctionId, false, false);

        assert(termRepoServicer.isTermRepoBalanced());
    }

    /// @notice Cancels an auction and sets auctionCancelledForWithdrawal to true to open unlocking tenders
    function cancelAuctionForWithdrawal(
        address[] calldata rolloverBorrowers,
        address[] calldata rolloverPairOffTermRepoServicer
    ) public onlyWhileAuctionClosed onlyRole(ADMIN_ROLE) {
        for (uint256 i = 0; i < rolloverBorrowers.length; ++i) {
            _markRolloverAsProcessed(
                rolloverPairOffTermRepoServicer[i],
                rolloverBorrowers[i]
            );
        }

        auctionCancelledForWithdrawal = true;
        emitter.emitAuctionCancelled(
            termAuctionId,
            false,
            auctionCancelledForWithdrawal
        );
    }

    // ========================================================================
    // = Helpers ==============================================================
    // ========================================================================
    function _increaseCumSumBids(
        TermAuctionRevealedBid[] memory sortedBids,
        uint256 startIndex,
        uint256 previousCumSumBids,
        uint256 currentPrice
    ) internal pure returns (uint256, uint256) {
        uint256 cumsumBids = previousCumSumBids;
        uint256 i;

        for (
            i = startIndex;
            sortedBids[i].bidPriceRevealed >= currentPrice;
            --i
        ) {
            cumsumBids += sortedBids[i].amount;
            if (i == 0) break;
        }
        return (
            cumsumBids,
            sortedBids[i].bidPriceRevealed < currentPrice ? i + 1 : i
        );
    }

    function _decreaseCumSumBids(
        TermAuctionRevealedBid[] memory sortedBids,
        uint256 startIndex,
        uint256 previousCumSumBids,
        uint256 currentPrice
    ) internal pure returns (uint256, uint256) {
        uint256 cumsumBids = previousCumSumBids;
        uint256 i;

        for (
            i = startIndex;
            i < sortedBids.length &&
                sortedBids[i].bidPriceRevealed < currentPrice;
            i++
        ) cumsumBids -= sortedBids[i].amount;

        return (cumsumBids, i);
    }

    /// Returns the min of two `uint256` values
    /// @param a The first value to compare
    /// @param b The second value to compare
    /// @return The min of the two values
    function _minUint256(uint256 a, uint256 b) internal pure returns (uint256) {
        if (a >= b) {
            return b;
        } else {
            return a;
        }
    }

    /// Calculates the intersection between bid/offer schedules to arrive at a clearing price
    /// @dev Imagine a graph with price along the X-axis and cumsum(bid/offerAmount*price) along the Y-axis. This function finds the point where the supply line crosses the demand line using binary search
    /// @param sortedBids A sorted array of bids used to arrive at a demand schedule
    /// @param sortedOffers A sorted array of offers used to arrive at a supply schedule
    /// @param clearingOffset The offset to apply to the marginal bid and offer indexes when calculating the final clearing price
    /// @return clearingPrice The price at which Term Auction will be cleared
    function _calculateClearingPrice(
        TermAuctionRevealedBid[] memory sortedBids,
        TermAuctionRevealedOffer[] memory sortedOffers,
        uint256 clearingOffset
    ) internal pure returns (uint256, uint256) {
        if (clearingOffset != 1 && clearingOffset != 0) {
            revert ClearingOffsetNot0Or1(clearingOffset);
        }

        // Local function variables are kept in memory
        ClearingPriceState memory state = ClearingPriceState({
            offerPrice: sortedOffers[0].offerPriceRevealed, // p^o_i
            offerIndex: 1, // idxo(offerPrice)
            cumSumOffers: sortedOffers[0].amount, // cso(offerPrice)
            bidIndex: sortedBids.length,
            cumSumBids: 0,
            maxClearingVolume: 0,
            nextOfferIndex: 0,
            nextBidIndex: 0,
            nextCumSumOffers: 0,
            nextCumSumBids: 0,
            nextOfferPrice: 0,
            nextMaxClearingVolume: 0,
            minCumSumCorrection: false,
            nextBidPrice: 0,
            clearingPrice: 0
        });

        // Calculate bidIndex = idxb(offerPrice) and cumSumBids = csb(offerPrice)
        (state.cumSumBids, state.bidIndex) = _increaseCumSumBids(
            sortedBids,
            state.bidIndex - 1,
            0,
            state.offerPrice
        );

        // Calculate initial maximal clearing volume
        state.maxClearingVolume = _minUint256(
            state.cumSumBids,
            state.cumSumOffers
        );

        // Calculate the pre-clearance price: maximise the clearing volume
        while (
            state.offerIndex < sortedOffers.length &&
            state.bidIndex < sortedBids.length
        ) {
            // Initialise the next iteration of the relevant variables
            state.nextOfferIndex = state.offerIndex;
            state.nextBidIndex = state.bidIndex;
            state.nextCumSumOffers = state.cumSumOffers;
            state.nextCumSumBids = state.cumSumBids;
            state.nextOfferPrice = sortedOffers[state.offerIndex]
                .offerPriceRevealed;

            // Obtain next offer index, increase cumulative sum
            while (
                state.nextOfferIndex < sortedOffers.length &&
                sortedOffers[state.nextOfferIndex].offerPriceRevealed ==
                state.nextOfferPrice
            )
                state.nextCumSumOffers += sortedOffers[state.nextOfferIndex++]
                    .amount;

            // Obtain next bid index, decrease cumulative sum
            (state.nextCumSumBids, state.nextBidIndex) = _decreaseCumSumBids(
                sortedBids,
                state.nextBidIndex,
                state.nextCumSumBids,
                state.nextOfferPrice
            );

            state.nextMaxClearingVolume = _minUint256(
                state.nextCumSumBids,
                state.nextCumSumOffers
            );
            if (state.nextMaxClearingVolume > state.maxClearingVolume) {
                state.offerIndex = state.nextOfferIndex;
                state.bidIndex = state.nextBidIndex;
                state.cumSumOffers = state.nextCumSumOffers;
                state.cumSumBids = state.nextCumSumBids;
                state.offerPrice = state.nextOfferPrice;
                state.maxClearingVolume = state.nextMaxClearingVolume;
            } else {
                break;
            }
        }

        // Get next offer price: first offer price higher than the pre-clearance price
        state.nextOfferPrice = (state.offerIndex < sortedOffers.length)
            ? sortedOffers[state.offerIndex].offerPriceRevealed
            : type(uint256).max;

        // Minimise css by minimising csb as long as bid price is smaller than next offer price
        while (state.bidIndex < sortedBids.length) {
            state.nextBidIndex = state.bidIndex;
            state.nextBidPrice = sortedBids[state.bidIndex].bidPriceRevealed;
            state.nextCumSumBids = state.cumSumBids;
            if (state.nextBidPrice < state.nextOfferPrice) {
                while (
                    state.nextBidIndex < sortedBids.length &&
                    sortedBids[state.nextBidIndex].bidPriceRevealed ==
                    state.nextBidPrice
                ) {
                    state.nextCumSumBids -= sortedBids[state.nextBidIndex++]
                        .amount;
                }
                if (state.nextCumSumBids >= state.cumSumOffers) {
                    state.minCumSumCorrection = true;
                    state.cumSumBids = state.nextCumSumBids;
                    state.bidIndex = state.nextBidIndex;
                } else {
                    break;
                }
            } else {
                break;
            }
        }

        // Calculate clearing price: bid price if minimum correction was made and offer price otherwise
        if (state.minCumSumCorrection)
            state.clearingPrice = (state.bidIndex == sortedBids.length)
                ? sortedBids[state.bidIndex - 1].bidPriceRevealed
                : sortedBids[state.bidIndex].bidPriceRevealed;
        else state.clearingPrice = state.offerPrice;

        // The main loop positions `offerIndex` at the first index greater than the price.
        // It needs to be shifted back to get the last index smaller than or equal to the price.
        state.offerIndex--;

        // If non-zero clearing offset, find the offset tender prices and then average them to find the final clearing price.
        if (clearingOffset == 1) {
            uint256 nextOfferPriceIndex = state.offerIndex;
            while (
                nextOfferPriceIndex > 0 &&
                sortedOffers[nextOfferPriceIndex].offerPriceRevealed ==
                sortedOffers[state.offerIndex].offerPriceRevealed
            ) {
                nextOfferPriceIndex -= 1;
            }

            uint256 nextBidPriceIndex = state.bidIndex;

            // In the case that there is no clear, bid index is past end of array, so decrement it to last element.
            if (state.bidIndex == sortedBids.length) {
                nextBidPriceIndex -= 1;
            }

            while (
                nextBidPriceIndex < sortedBids.length - 1 &&
                sortedBids[nextBidPriceIndex].bidPriceRevealed ==
                sortedBids[state.bidIndex].bidPriceRevealed
            ) {
                nextBidPriceIndex += 1;
            }

            state.clearingPrice =
                (sortedOffers[nextOfferPriceIndex].offerPriceRevealed +
                    sortedBids[nextBidPriceIndex].bidPriceRevealed) /
                2;
        } else {
            // In the case that there is no clear, bid index is past end of array, so decrement it to last element.
            if (state.bidIndex == sortedBids.length) {
                state.bidIndex -= 1;
            }
            state.clearingPrice =
                (sortedOffers[state.offerIndex].offerPriceRevealed +
                    sortedBids[state.bidIndex].bidPriceRevealed) /
                2;
        }

        //update state.cumSumOffers
        if (
            sortedOffers[state.offerIndex].offerPriceRevealed <=
            state.clearingPrice
        ) {
            state.offerIndex++;
            while (
                state.offerIndex < sortedOffers.length &&
                sortedOffers[state.offerIndex].offerPriceRevealed <=
                state.clearingPrice
            ) {
                state.cumSumOffers += sortedOffers[state.offerIndex].amount;
                state.offerIndex++;
            }
        } else {
            while (
                sortedOffers[state.offerIndex].offerPriceRevealed >
                state.clearingPrice
            ) {
                state.cumSumOffers -= sortedOffers[state.offerIndex].amount;
                if (state.offerIndex == 0) break;
                state.offerIndex--;
            }
        }

        //update state.cumSumBids
        if (
            state.bidIndex < sortedBids.length &&
            sortedBids[state.bidIndex].bidPriceRevealed < state.clearingPrice
        ) {
            (state.cumSumBids, state.bidIndex) = _decreaseCumSumBids(
                sortedBids,
                state.bidIndex,
                state.cumSumBids,
                state.clearingPrice
            );
        } else if (state.bidIndex > 0) {
            (state.cumSumBids, state.bidIndex) = _increaseCumSumBids(
                sortedBids,
                state.bidIndex - 1,
                state.cumSumBids,
                state.clearingPrice
            );
        }

        return (
            state.clearingPrice,
            _minUint256(state.cumSumBids, state.cumSumOffers)
        );
    }

    /// Finds the index of the first bid with a bidPrice of `price` and calculate the cumsum of the bid amounts up to that index
    /// @param price The price to search for
    /// @param sortedBids An array of sorted bids to search
    /// @param startIndex The index to start searching from
    /// @return i The index of the first bid with a bidPrice of `price`
    /// @return totalAmount The cumsum of the bid amounts up to return index i
    function _findFirstIndexForPrice(
        uint256 price,
        TermAuctionRevealedBid[] memory sortedBids,
        uint256 startIndex
    ) internal pure returns (uint256 i, uint256 totalAmount) {
        i = startIndex;
        totalAmount = sortedBids[i].amount;
        while (true) {
            if (i == 0 || sortedBids[i - 1].bidPriceRevealed != price) {
                break;
            }
            totalAmount += sortedBids[i - 1].amount;
            --i;
        }
        return (i, totalAmount);
    }

    /// Finds the index of the last offer with a offerPrice of `price` and calculate the cumsum of the offer amounts up to that index
    /// @param price The price to search for
    /// @param sortedOffers An array of offers to search
    /// @param startIndex The index to start searching from
    /// @return i The index of the last offer with a offerPrice of `price`
    /// @return totalAmount The cumsum of the offer amounts up to return index i
    function _findLastIndexForPrice(
        uint256 price,
        TermAuctionRevealedOffer[] memory sortedOffers,
        uint256 startIndex
    ) internal pure returns (uint256 i, uint256 totalAmount) {
        i = startIndex;
        totalAmount = sortedOffers[i].amount;
        while (i < (sortedOffers.length - 1)) {
            if (sortedOffers[i + 1].offerPriceRevealed != price) {
                break;
            }
            totalAmount += sortedOffers[i + 1].amount;
            ++i;
        }
        return (i, totalAmount);
    }

    /// Fully assigns a bid
    /// @param bid The bid to assign
    /// @return The amount that was assigned
    function _fullyAssignBid(
        TermAuctionRevealedBid memory bid
    ) internal nonReentrant returns (uint256) {
        uint256 repurchaseAmount = _calculateRepurchasePrice(bid.amount);

        if (!bid.isRollover) {
            termRepoServicer.fulfillBid(
                bid.bidder,
                bid.amount,
                repurchaseAmount,
                bid.collateralTokens,
                bid.collateralAmounts,
                dayCountFractionMantissa
            );
        } else {
            _assignRolloverBid(
                bid.bidder,
                bid.amount,
                repurchaseAmount,
                bid.rolloverPairOffTermRepoServicer
            );
        }

        emitter.emitBidAssigned(termAuctionId, bid.id, bid.amount);

        return bid.amount;
    }

    /// Fully assigns an offer
    /// @param offer The offer to assign
    /// @return The amount that was assigned
    function _fullyAssignOffer(
        TermAuctionRevealedOffer memory offer
    ) internal nonReentrant returns (uint256) {
        uint256 repurchaseAmount = _calculateRepurchasePrice(offer.amount);

        termRepoServicer.fulfillOffer(
            offer.offeror,
            offer.amount,
            repurchaseAmount,
            offer.id
        );

        emitter.emitOfferAssigned(termAuctionId, offer.id, offer.amount);

        return offer.amount;
    }

    /// Partially assigns a bid
    /// @param bid The bid to assign
    /// @param assignedAmount The amount to assign
    /// @return The amount that was assigned
    function _partiallyAssignBid(
        TermAuctionRevealedBid memory bid,
        uint256 assignedAmount
    ) internal nonReentrant returns (uint256) {
        uint256 repurchaseAmount = _calculateRepurchasePrice(assignedAmount);

        if (!bid.isRollover) {
            termRepoServicer.fulfillBid(
                bid.bidder,
                assignedAmount,
                repurchaseAmount,
                bid.collateralTokens,
                bid.collateralAmounts,
                dayCountFractionMantissa
            );
        } else {
            _assignRolloverBid(
                bid.bidder,
                assignedAmount,
                repurchaseAmount,
                bid.rolloverPairOffTermRepoServicer
            );
        }

        emitter.emitBidAssigned(termAuctionId, bid.id, assignedAmount);

        return assignedAmount;
    }

    /// Partially assigns an offer
    /// @param offer The offer to assign
    /// @param assignedAmount The amount to assign
    /// @return The amount that was assigned
    function _partiallyAssignOffer(
        TermAuctionRevealedOffer memory offer,
        uint256 assignedAmount
    ) internal nonReentrant returns (uint256) {
        uint256 repurchaseAmount = _calculateRepurchasePrice(assignedAmount);

        termRepoServicer.fulfillOffer(
            offer.offeror,
            assignedAmount,
            repurchaseAmount,
            offer.id
        );

        // Unlock remaining.
        termAuctionOfferLocker.unlockOfferPartial(
            offer.id,
            offer.offeror,
            offer.amount - assignedAmount
        );

        emitter.emitOfferAssigned(termAuctionId, offer.id, assignedAmount);

        return assignedAmount;
    }

    function _assignRolloverBid(
        address borrower,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        address rolloverPairOffTermRepoServicer
    ) internal {
        ITermRepoServicer previousTermRepoServicer = ITermRepoServicer(
            rolloverPairOffTermRepoServicer
        );
        uint256 rolloverPaymentToCollapseBorrower = termRepoServicer
            .openExposureOnRolloverNew(
                borrower,
                purchasePrice,
                repurchasePrice,
                address(previousTermRepoServicer.termRepoLocker()),
                dayCountFractionMantissa
            );
        uint256 proportionPreviousLoanPaid = previousTermRepoServicer
            .closeExposureOnRolloverExisting(
                borrower,
                rolloverPaymentToCollapseBorrower
            );
        ITermRepoCollateralManager previousTermRepoCollateralManager = ITermRepoCollateralManager(
                previousTermRepoServicer.termRepoCollateralManager()
            );
        (
            address[] memory collateralTypes,
            uint256[] memory collateralAmounts
        ) = previousTermRepoCollateralManager.transferRolloverCollateral(
                borrower,
                proportionPreviousLoanPaid,
                address(termRepoServicer.termRepoLocker())
            );

        ITermRepoCollateralManager currentTermRepoCollateralManager = termRepoServicer
                .termRepoCollateralManager();

        for (uint256 i = 0; i < collateralTypes.length; ++i) {
            if (collateralAmounts[i] > 0) {
                currentTermRepoCollateralManager.acceptRolloverCollateral(
                    borrower,
                    collateralTypes[i],
                    collateralAmounts[i]
                );
            }
        }
    }

    function _markRolloverAsProcessed(
        address rolloverPairOffTermRepoServicer,
        address borrower
    ) internal {
        ITermRepoServicer termRepoServicer_ = ITermRepoServicer(
            rolloverPairOffTermRepoServicer
        );
        ITermRepoRolloverManager rolloverManager = termRepoServicer_
            .termRepoRolloverManager();
        rolloverManager.fulfillRollover(borrower);
    }

    /// Assigns bids up to `maxAssignable`
    /// @dev This method allocates pro-rata across an the marginal price group (pro-rata on the margin) and attempts to prevent residuals from accumulating to a single bid
    /// @param sortedBids An array of sorted bids to process
    /// @param maxAssignable The maximum bid amount that can be assigned across all bidders
    /// @param purchaseTokenDecimals The number of decimals of the purchase token
    /// @return The total amount assigned
    function _assignBids(
        TermAuctionRevealedBid[] memory sortedBids,
        uint256 maxAssignable,
        uint256 purchaseTokenDecimals
    ) internal returns (uint256) {
        // Process revealed bids.
        uint256 totalAssignedBids = 0;
        uint256 innerIndex = 0;
        uint256 i = 0;
        for (uint256 j = sortedBids.length; j > 0; --j) {
            i = j - 1;

            // First, find the sub-range that contains the current price.
            (uint256 k, uint256 priceGroupAmount) = _findFirstIndexForPrice(
                sortedBids[i].bidPriceRevealed,
                sortedBids,
                i
            );
            // NOTE: priceGroupAmount gets changed later on in this function and is used as the "remaining" priceGroupAmount during partial assignment.

            if (
                sortedBids[i].bidPriceRevealed >= clearingPrice &&
                totalAssignedBids < maxAssignable &&
                priceGroupAmount <= (maxAssignable - totalAssignedBids)
            ) {
                // Full assignment for entire price group.

                innerIndex = 0;
                for (; (i - innerIndex) >= k; ++innerIndex) {
                    // NOTE: This loop is actually decrementing!
                    totalAssignedBids += _fullyAssignBid(
                        sortedBids[i - innerIndex]
                    );

                    if (i == innerIndex) {
                        ++innerIndex;
                        break;
                    }
                }
                if (innerIndex > 0) {
                    j -= (innerIndex - 1);
                }
            } else if (
                sortedBids[i].bidPriceRevealed >= clearingPrice &&
                totalAssignedBids < maxAssignable
            ) {
                // Partial assignment for entire price group.

                innerIndex = 0;
                for (; (i - innerIndex) >= k; ++innerIndex) {
                    if ((i - innerIndex) == k) {
                        // Last iteration of loop. Assign remaining amount left to assign.
                        totalAssignedBids += _partiallyAssignBid(
                            sortedBids[i - innerIndex],
                            maxAssignable - totalAssignedBids
                        );
                        priceGroupAmount -= maxAssignable - totalAssignedBids;
                    } else {
                        // Assign an amount based upon the partial assignment ratio.

                        uint256 bidAmount = sortedBids[i - innerIndex].amount;
                        Exp memory partialAssignmentRatio = div_(
                            Exp({
                                mantissa: (maxAssignable - totalAssignedBids) *
                                    10 ** (18 - purchaseTokenDecimals)
                            }),
                            Exp({
                                mantissa: priceGroupAmount *
                                    10 ** (18 - purchaseTokenDecimals)
                            })
                        );
                        uint256 assignedAmount = mul_(
                            partialAssignmentRatio,
                            Exp({
                                mantissa: bidAmount *
                                    10 ** (18 - purchaseTokenDecimals)
                            })
                        ).mantissa / 10 ** (18 - purchaseTokenDecimals);

                        totalAssignedBids += _partiallyAssignBid(
                            sortedBids[i - innerIndex],
                            assignedAmount
                        );
                        priceGroupAmount -= sortedBids[i - innerIndex].amount;
                    }

                    if (i == innerIndex) {
                        ++innerIndex;
                        break;
                    }
                }
                if (innerIndex > 0) {
                    j -= (innerIndex - 1);
                }
            } else {
                // No assignment.
                if (sortedBids[i].isRollover) {
                    _markRolloverAsProcessed(
                        sortedBids[i].rolloverPairOffTermRepoServicer,
                        sortedBids[i].bidder
                    );
                } else {
                    termAuctionBidLocker.auctionUnlockBid(
                        sortedBids[i].id,
                        sortedBids[i].bidder,
                        sortedBids[i].collateralTokens,
                        sortedBids[i].collateralAmounts
                    );
                }
            }
        }

        return totalAssignedBids;
    }

    /// Assigns offers up to `maxAssignable`
    /// @dev This method allocates pro-rata across an the marginal price group (pro-rata on the margin) and attempts to prevent residuals from accumulating to a single offer
    /// @param sortedOffers An array of sorted offers to process
    /// @param maxAssignable The maximum offer amount that can be assigned across all offers
    /// @param purchaseTokenDecimals The number of decimals of the purchase token
    /// @return The total amount assigned
    function _assignOffers(
        TermAuctionRevealedOffer[] memory sortedOffers,
        uint256 maxAssignable,
        uint256 purchaseTokenDecimals
    ) internal returns (uint256) {
        // Process revealed offers.
        uint256 totalAssignedOffers = 0;
        uint256 innerIndex = 0;
        uint256 i = 0;
        for (i = 0; i < sortedOffers.length; ++i) {
            // First, find the sub-range that contains the current price.
            (uint256 k, uint256 priceGroupAmount) = _findLastIndexForPrice(
                sortedOffers[i].offerPriceRevealed,
                sortedOffers,
                i
            );
            // NOTE: priceGroupAmount gets changed later on in this function and is used as the "remaining" priceGroupAmount during partial assignment.

            if (
                sortedOffers[i].offerPriceRevealed <= clearingPrice &&
                totalAssignedOffers < maxAssignable &&
                priceGroupAmount <= (maxAssignable - totalAssignedOffers)
            ) {
                // Full assignment.
                innerIndex = 0;
                for (; (innerIndex + i) <= k; ++innerIndex) {
                    totalAssignedOffers += _fullyAssignOffer(
                        sortedOffers[innerIndex + i]
                    );
                }
                if (innerIndex > 0) {
                    i += innerIndex - 1;
                }
            } else if (
                sortedOffers[i].offerPriceRevealed <= clearingPrice &&
                totalAssignedOffers < maxAssignable
            ) {
                // Partial assignment.
                innerIndex = 0;
                for (; (innerIndex + i) <= k; innerIndex++) {
                    if ((innerIndex + i) == k) {
                        // Last iteration of loop. Assign remaining amount left to assign.
                        totalAssignedOffers += _partiallyAssignOffer(
                            sortedOffers[innerIndex + i],
                            maxAssignable - totalAssignedOffers
                        );
                        priceGroupAmount -= maxAssignable - totalAssignedOffers;
                    } else {
                        // Assign an amount based upon the partial assignment ratio.

                        uint256 offerAmount = sortedOffers[innerIndex + i]
                            .amount;
                        Exp memory partialAssignmentRatio = div_(
                            Exp({
                                mantissa: (maxAssignable -
                                    totalAssignedOffers) *
                                    10 ** (18 - purchaseTokenDecimals)
                            }),
                            Exp({
                                mantissa: priceGroupAmount *
                                    10 ** (18 - purchaseTokenDecimals)
                            })
                        );
                        uint256 assignedAmount = (innerIndex + i) != k
                            ? mul_(
                                partialAssignmentRatio,
                                Exp({
                                    mantissa: offerAmount *
                                        10 ** (18 - purchaseTokenDecimals)
                                })
                            ).mantissa / 10 ** (18 - purchaseTokenDecimals)
                            : maxAssignable - totalAssignedOffers;

                        totalAssignedOffers += _partiallyAssignOffer(
                            sortedOffers[innerIndex + i],
                            assignedAmount
                        );
                        priceGroupAmount -= sortedOffers[innerIndex + i].amount;
                    }
                }
                if (innerIndex > 0) {
                    i += innerIndex - 1;
                }
            } else {
                // No assignment.

                // Return purchase tokens to offeror.
                termAuctionOfferLocker.unlockOfferPartial(
                    sortedOffers[i].id,
                    sortedOffers[i].offeror,
                    sortedOffers[i].amount
                );
            }
        }

        return totalAssignedOffers;
    }

    /// Calculates repurchase price given a purchase price (equivalent to principal plus interest)
    /// @param purchasePrice The purchase price
    /// @return The repurchase price obtained by applying the clearing rate on an Actual/360 day-count convention
    function _calculateRepurchasePrice(
        uint256 purchasePrice
    ) internal view returns (uint256) {
        Exp memory repurchaseFactor = add_(
            Exp({mantissa: expScale}),
            mul_(
                Exp({mantissa: dayCountFractionMantissa}),
                Exp({mantissa: clearingPrice})
            )
        );

        return
            truncate(
                mul_(
                    Exp({mantissa: purchasePrice * expScale}),
                    repurchaseFactor
                )
            );
    }

    function _calculateAndStoreClearingPrice(
        TermAuctionRevealedBid[] memory sortedBids,
        TermAuctionRevealedOffer[] memory sortedOffers
    ) internal nonReentrant returns (uint256, uint256) {
        (
            uint256 clearingPrice_,
            uint256 maxAssignable
        ) = _calculateClearingPrice(
                sortedBids,
                sortedOffers,
                clearingPricePostProcessingOffset
            );

        clearingPrice = clearingPrice_;

        return (clearingPrice_, maxAssignable);
    }

    // ========================================================================
    // = Pausable =============================================================
    // ========================================================================

    /// @dev This function pauses the TermAuction contract preventing public state changes
    /// @dev See {Pausable-_pause}.
    function pauseCompleteAuction() external onlyRole(ADMIN_ROLE) {
        completeAuctionPaused = true;
        emitter.emitCompleteAuctionPaused(termAuctionId, termRepoId);
    }

    /// Unpuses the TermAuction contract allowing public state changes
    /// @dev See {Pausable-_unpause}.
    function unpauseCompleteAuction() external onlyRole(ADMIN_ROLE) {
        completeAuctionPaused = false;
        emitter.emitCompleteAuctionUnpaused(termAuctionId, termRepoId);
    }

    ///@dev required override by the OpenZeppelin UUPS module
    ///@param impl new impl address for proxy upgrade
    function _authorizeUpgrade(
        address impl
    ) internal override onlyRole(DEVOPS_ROLE) {
        emitter.emitTermContractUpgraded(address(this), impl);
    }
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermAuction} from "./interfaces/ITermAuction.sol";
import {ITermAuctionBidLocker} from "./interfaces/ITermAuctionBidLocker.sol";
import {ITermAuctionBidLockerErrors} from "./interfaces/ITermAuctionBidLockerErrors.sol";
import {ITermEventEmitter} from "./interfaces/ITermEventEmitter.sol";
import {ITermPriceOracle} from "./interfaces/ITermPriceOracle.sol";
import {ITermRepoCollateralManager} from "./interfaces/ITermRepoCollateralManager.sol";
import {ITermRepoServicer} from "./interfaces/ITermRepoServicer.sol";
import {ExponentialNoError} from "./lib/ExponentialNoError.sol";
import {TermAuctionBid} from "./lib/TermAuctionBid.sol";
import {TermAuctionBidSubmission} from "./lib/TermAuctionBidSubmission.sol";
import {TermAuctionRevealedBid} from "./lib/TermAuctionRevealedBid.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {ReentrancyGuardUpgradeable} from "@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol";
import {IERC20Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import {Versionable} from "./lib/Versionable.sol";

/// @author TermLabs
/// @title Term Bid Locker
/// @notice This contract handles and proceesses Term Auction bid submissions
/// @dev This contract belongs to the Term Auction group of contracts and is specific to a Term Repo deployment
contract TermAuctionBidLocker is
    ITermAuctionBidLocker,
    ITermAuctionBidLockerErrors,
    UUPSUpgradeable,
    AccessControlUpgradeable,
    ExponentialNoError,
    ReentrancyGuardUpgradeable,
    Versionable
{
    // ========================================================================
    // = Constants  ===========================================================
    // ========================================================================

    uint256 public constant MAX_BID_PRICE = 10000e16; // 10,000%

    uint256 public constant MAX_BID_COUNT = 150;

    uint256 public constant THREESIXTY_DAYCOUNT_SECONDS = 360 days;

    // ========================================================================
    // = Access Roles  ========================================================
    // ========================================================================
    bytes32 public constant ADMIN_ROLE = keccak256("ADMIN_ROLE");
    bytes32 public constant AUCTIONEER_ROLE = keccak256("AUCTIONEER_ROLE");
    bytes32 public constant DEVOPS_ROLE = keccak256("DEVOPS_ROLE");
    bytes32 public constant INITIALIZER_ROLE = keccak256("INITIALIZER_ROLE");
    bytes32 public constant ROLLOVER_MANAGER = keccak256("ROLLOVER_MANAGER");

    // ========================================================================
    // = State Variables  =====================================================
    // ========================================================================

    // Auction configuration.
    bytes32 public termRepoId;
    bytes32 public termAuctionId;
    uint256 public auctionStartTime;
    uint256 public revealTime;
    uint256 public auctionEndTime;
    uint256 public minimumTenderAmount;
    uint256 public dayCountFractionMantissa;
    address public purchaseToken;
    mapping(IERC20Upgradeable => bool) public collateralTokens;
    ITermRepoCollateralManager public termRepoCollateralManager;
    ITermRepoServicer public termRepoServicer;
    ITermPriceOracle internal termPriceOracle;
    ITermEventEmitter internal emitter;
    ITermAuction public termAuction;

    // Auction in-progress state
    mapping(bytes32 => TermAuctionBid) internal bids;
    uint256 public bidCount;
    bool internal termContractPaired;
    bool public lockingPaused;
    bool public unlockingPaused;

    // ========================================================================
    // = Modifiers  ===========================================================
    // ========================================================================
    modifier onlyWhileAuctionOpen() {
        if (
            // solhint-disable-next-line not-rely-on-time
            block.timestamp > revealTime || block.timestamp < auctionStartTime
        ) {
            revert AuctionNotOpen();
        }
        _;
    }
    modifier onlyWhileAuctionRevealing() {
        if (
            // solhint-disable-next-line not-rely-on-time
            block.timestamp < revealTime
        ) {
            revert AuctionNotRevealing();
        }
        _;
    }

    modifier onlyBidder(address bidder, address authedUser) {
        if (authedUser != bidder) {
            revert BidNotOwned();
        }
        _;
    }

    modifier whenLockingNotPaused() {
        if (lockingPaused) {
            revert LockingPaused();
        }
        _;
    }

    modifier whenUnlockingNotPaused() {
        if (unlockingPaused) {
            revert UnlockingPaused();
        }
        _;
    }

    modifier notTermContractPaired() {
        if (termContractPaired) {
            revert AlreadyTermContractPaired();
        }
        termContractPaired = true;
        _;
    }

    // ========================================================================
    // = Deploy (https://docs.openzeppelin.com/contracts/4.x/upgradeable) =====
    // ========================================================================

    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor() {
        _disableInitializers();
    }

    function initialize(
        string calldata termRepoId_,
        string calldata auctionId_,
        uint256 auctionStartTime_,
        uint256 revealTime_,
        uint256 auctionEndTime_,
        uint256 redemptionTimestamp_,
        uint256 minimumTenderAmount_,
        address purchaseToken_,
        IERC20Upgradeable[] memory collateralTokens_,
        address termInitializer_
    ) external initializer {
        UUPSUpgradeable.__UUPSUpgradeable_init();
        AccessControlUpgradeable.__AccessControl_init();
        ReentrancyGuardUpgradeable.__ReentrancyGuard_init();

        _grantRole(INITIALIZER_ROLE, termInitializer_);

        termRepoId = keccak256(abi.encodePacked(termRepoId_));
        termAuctionId = keccak256(abi.encodePacked(auctionId_));

        if (auctionStartTime_ > revealTime_) {
            revert AuctionStartsAfterReveal(auctionStartTime_, revealTime_);
        }

        auctionStartTime = auctionStartTime_;
        revealTime = revealTime_;
        auctionEndTime = auctionEndTime_;
        minimumTenderAmount = minimumTenderAmount_;
        dayCountFractionMantissa =
            ((redemptionTimestamp_ - auctionEndTime_) * expScale) /
            THREESIXTY_DAYCOUNT_SECONDS;
        purchaseToken = purchaseToken_;
        for (uint8 i = 0; i < collateralTokens_.length; ++i) {
            collateralTokens[collateralTokens_[i]] = true;
        }

        bidCount = 0;
        termContractPaired = false;
    }

    function pairTermContracts(
        address termAuction_,
        ITermRepoServicer termRepoServicer_,
        ITermEventEmitter emitter_,
        ITermRepoCollateralManager termRepoCollateralManager_,
        ITermPriceOracle termPriceOracle_,
        address devopsMultisig_,
        address adminWallet_
    ) external onlyRole(INITIALIZER_ROLE) notTermContractPaired {
        if (address(termRepoServicer_) == address(0)) {
            revert InvalidTermRepoServicer();
        }
        termRepoServicer = termRepoServicer_;
        termAuction = ITermAuction(termAuction_);
        _grantRole(AUCTIONEER_ROLE, termAuction_);
        _grantRole(DEVOPS_ROLE, devopsMultisig_);
        _grantRole(ADMIN_ROLE, adminWallet_);

        emitter = emitter_;

        termRepoCollateralManager = termRepoCollateralManager_;
        termPriceOracle = termPriceOracle_;

        emitter.emitTermAuctionBidLockerInitialized(
            termRepoId,
            termAuctionId,
            address(this),
            auctionStartTime,
            revealTime,
            MAX_BID_PRICE,
            minimumTenderAmount,
            dayCountFractionMantissa
        );
    }

    /// @param rolloverManager The address of the TermRepoRolloverManager contract
    function pairRolloverManager(
        address rolloverManager
    ) external onlyRole(ADMIN_ROLE) {
        _grantRole(ROLLOVER_MANAGER, rolloverManager);
    }

    // ========================================================================
    // = Interface/API ========================================================
    // ========================================================================

    /// @param bidSubmissions An array of Term Auction bid submissions to borrow an amount of money at rate up to but not exceeding the bid rate
    /// @param referralAddress A user address that referred the submitter of this bid
    /// @return A bytes32 array of unique on chain bid ids.
    function lockBidsWithReferral(
        TermAuctionBidSubmission[] calldata bidSubmissions,
        address referralAddress
    )
        external
        onlyWhileAuctionOpen
        whenLockingNotPaused
        nonReentrant
        returns (bytes32[] memory)
    {
        if (msg.sender == referralAddress) {
            revert InvalidSelfReferral();
        }

        bytes32[] memory bidIds = new bytes32[](bidSubmissions.length);

        for (uint256 i = 0; i < bidSubmissions.length; ++i) {
            TermAuctionBid storage bid = _lock(bidSubmissions[i], msg.sender);
            bidIds[i] = bid.id;
            emitter.emitBidLocked(termAuctionId, bid, referralAddress);
        }
        return bidIds;
    }

    /// @param bid A struct containing details of the bid
    function lockRolloverBid(
        TermAuctionBid calldata bid
    ) external whenLockingNotPaused onlyRole(ROLLOVER_MANAGER) nonReentrant {
        if (
            // solhint-disable-next-line not-rely-on-time
            block.timestamp > revealTime
        ) {
            revert AuctionNotOpen();
        }

        if (bid.amount == 0) {
            if (bids[bid.id].amount == 0) {
                revert NonExistentBid(bid.id);
            }

            delete bids[bid.id];
            bidCount -= 1;
            emitter.emitBidUnlocked(termAuctionId, bid.id);
        } else {
            _lockRolloverBid(bid);
        }
    }

    /// @param bidSubmissions An array of bid submissions
    /// @return A bytes32 array of unique on chain bid ids.
    function lockBids(
        TermAuctionBidSubmission[] calldata bidSubmissions
    )
        external
        onlyWhileAuctionOpen
        whenLockingNotPaused
        nonReentrant
        returns (bytes32[] memory)
    {
        bytes32[] memory bidIds = new bytes32[](bidSubmissions.length);
        for (uint256 i = 0; i < bidSubmissions.length; ++i) {
            TermAuctionBid storage bid = _lock(bidSubmissions[i], msg.sender);
            bidIds[i] = bid.id;
            emitter.emitBidLocked(termAuctionId, bid, address(0));
        }
        return bidIds;
    }

    /// @param id A bid Id
    /// @return A struct containing details of the locked bid
    function lockedBid(
        bytes32 id
    ) external view returns (TermAuctionBid memory) {
        return bids[id];
    }

    /// @param ids An array of bid ids of the bids to reveal
    /// @param prices An array of the bid prices to reveal
    /// @param nonces An array of nonce values to generate bid price hashes
    function revealBids(
        bytes32[] calldata ids,
        uint256[] calldata prices,
        uint256[] calldata nonces
    ) external onlyWhileAuctionRevealing {
        for (uint256 i = 0; i < ids.length; ++i) {
            _revealBid(ids[i], prices[i], nonces[i]);
        }
    }

    /// @notice unlockBids unlocks multiple bids and returns funds to the bidder
    /// @param ids An array of ids to unlock
    function unlockBids(
        bytes32[] calldata ids
    ) external whenUnlockingNotPaused nonReentrant {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp < auctionStartTime) {
            revert AuctionNotOpen();
        }
        // solhint-disable-next-line not-rely-on-time
        if (
            block.timestamp > revealTime &&
            !termAuction.auctionCancelledForWithdrawal()
        ) {
            revert AuctionNotOpen();
        }

        for (uint256 i = 0; i < ids.length; ++i) {
            _unlock(
                ids[i],
                msg.sender,
                bids[ids[i]].collateralTokens,
                bids[ids[i]].collateralAmounts
            );
        }
    }

    // ========================================================================
    // = Auction Interface/API ===============================================
    // ========================================================================

    /// @param revealedBids An array of the revealed offer ids
    /// @param expiredRolloverBids An array of the expired rollover bid ids
    /// @param unrevealedBids An array of the unrevealed offer ids
    /// @return An array of TermAuctionRevealedBid structs containing details of the revealed bids
    /// @return An array of TermAuctionBid structs containing details of the unrevealed bids
    function getAllBids(
        bytes32[] calldata revealedBids,
        bytes32[] calldata expiredRolloverBids,
        bytes32[] calldata unrevealedBids
    )
        external
        onlyRole(AUCTIONEER_ROLE)
        returns (TermAuctionRevealedBid[] memory, TermAuctionBid[] memory)
    {
        return _getAllBids(revealedBids, expiredRolloverBids, unrevealedBids);
    }

    /// @param id A bytes32 bid id
    /// @param bidder The address of the bidder
    /// @param bidCollateralTokens The addresses of the token used as collateral
    /// @param amounts The amounts of collateral tokens to unlock
    function auctionUnlockBid(
        bytes32 id,
        address bidder,
        address[] calldata bidCollateralTokens,
        uint256[] calldata amounts
    ) external onlyRole(AUCTIONEER_ROLE) {
        if (bids[id].isRollover) {
            revert RolloverBid();
        }

        emitter.emitBidUnlocked(termAuctionId, id);

        for (uint256 i = 0; i < bidCollateralTokens.length; ++i) {
            // 0 amount is a default for unlocking entire bid
            termRepoCollateralManager.auctionUnlockCollateral(
                bidder,
                bidCollateralTokens[i],
                amounts[i]
            );
        }
    }

    // ========================================================================
    // = Helpers ==============================================================
    // ========================================================================

    function _lock(
        TermAuctionBidSubmission memory bidSubmission,
        address authedUser
    )
        internal
        onlyBidder(bidSubmission.bidder, authedUser)
        returns (TermAuctionBid storage)
    {
        if (bidCount >= MAX_BID_COUNT) {
            revert MaxBidCountReached();
        }
        bool bidExists = bids[bidSubmission.id].amount != 0;
        bytes32 bidId;
        if (bidExists) {
            if (bids[bidSubmission.id].bidder != bidSubmission.bidder) {
                revert BidNotOwned();
            }
            bidId = bidSubmission.id;
        } else {
            bidId = _generateBidId(bidSubmission.id, authedUser);
        }
        if (purchaseToken != bidSubmission.purchaseToken) {
            revert PurchaseTokenNotApproved(bidSubmission.purchaseToken);
        }
        for (uint256 i = 0; i < bidSubmission.collateralTokens.length; ++i) {
            if (
                !collateralTokens[
                    IERC20Upgradeable(bidSubmission.collateralTokens[i])
                ]
            ) {
                revert CollateralTokenNotApproved(
                    bidSubmission.collateralTokens[i]
                );
            }
        }
        if (bidSubmission.amount < minimumTenderAmount) {
            revert BidAmountTooLow(bidSubmission.amount);
        }
        if (
            /// @dev check to see if bid has enough collateral to meet initial ratio for purchase price
            _isInInitialCollateralShortFall(
                bidSubmission.amount,
                bidSubmission.collateralTokens,
                bidSubmission.collateralAmounts
            )
        ) {
            revert CollateralAmountTooLow();
        }

        uint256 oldCollateralAmount;

        for (uint256 i = 0; i < bidSubmission.collateralTokens.length; ++i) {
            // Calculate the amount of collateral tokens to lock/unlock.
            if (bidExists) {
                oldCollateralAmount = bids[bidId].collateralAmounts[i];
                if (oldCollateralAmount < bidSubmission.collateralAmounts[i]) {
                    termRepoCollateralManager.auctionLockCollateral(
                        bidSubmission.bidder,
                        address(bidSubmission.collateralTokens[i]),
                        bidSubmission.collateralAmounts[i] - oldCollateralAmount
                    );
                } else if (
                    oldCollateralAmount > bidSubmission.collateralAmounts[i]
                ) {
                    termRepoCollateralManager.auctionUnlockCollateral(
                        bidSubmission.bidder,
                        address(bidSubmission.collateralTokens[i]),
                        oldCollateralAmount - bidSubmission.collateralAmounts[i]
                    );
                }
            } else {
                termRepoCollateralManager.auctionLockCollateral(
                    bidSubmission.bidder,
                    address(bidSubmission.collateralTokens[i]),
                    bidSubmission.collateralAmounts[i]
                );
            }
        }

        // slither-disable-start reentrancy-no-eth
        bids[bidId] = TermAuctionBid({
            id: bidId,
            bidder: bidSubmission.bidder,
            bidPriceRevealed: 0,
            bidPriceHash: bidSubmission.bidPriceHash,
            amount: bidSubmission.amount,
            collateralAmounts: bidSubmission.collateralAmounts,
            purchaseToken: bidSubmission.purchaseToken,
            collateralTokens: bidSubmission.collateralTokens,
            isRollover: false,
            rolloverPairOffTermRepoServicer: address(0),
            isRevealed: false
        });
        // slither-disable-end reentrancy-no-eth

        if (!bidExists) {
            bidCount += 1;
        }

        return bids[bidId];
    }

    function _lockRolloverBid(TermAuctionBid memory bid) internal {
        // reject rollover bid if auction is full
        if (bidCount >= MAX_BID_COUNT) {
            revert MaxBidCountReached();
        }

        if (!bid.isRollover) {
            revert NonRolloverBid(bid.id);
        }

        if (bid.amount < minimumTenderAmount) {
            revert BidAmountTooLow(bid.amount);
        }

        bool bidExists = bids[bid.id].amount != 0;

        if (purchaseToken != bid.purchaseToken) {
            revert InvalidPurchaseToken();
        }

        // Store bid in auction contract.
        bids[bid.id] = bid;
        if (!bidExists) {
            bidCount += 1;
        }

        emitter.emitBidLocked(termAuctionId, bid, address(0));
    }

    function _unlock(
        bytes32 id,
        address bidder,
        address[] storage bidCollateralTokens,
        uint256[] storage amounts
    ) internal {
        if (bids[id].amount == 0) {
            revert NonExistentBid(id);
        }

        if (bidder != bids[id].bidder) {
            revert BidNotOwned();
        }

        if (bids[id].isRollover) {
            revert RolloverBid();
        }

        for (uint256 i = 0; i < bidCollateralTokens.length; ++i) {
            // 0 amount is a default for unlocking entire bid
            termRepoCollateralManager.auctionUnlockCollateral(
                bidder,
                bidCollateralTokens[i],
                amounts[i]
            );
        }

        // Remove bid from auction contract.
        delete bids[id];
        bidCount -= 1;

        emitter.emitBidUnlocked(termAuctionId, id);
    }

    function _revealBid(bytes32 id, uint256 price, uint256 nonce) internal {
        // Check that price hasn't been modified/revealed.
        if (keccak256(abi.encode(price, nonce)) != bids[id].bidPriceHash) {
            revert BidPriceModified(id);
        }
        if (price > MAX_BID_PRICE) {
            revert TenderPriceTooHigh(id, MAX_BID_PRICE);
        }
        bids[id].bidPriceRevealed = price;
        bids[id].isRevealed = true;

        emitter.emitBidRevealed(termAuctionId, id, price);
    }

    /// @param revealedBids An array of the revealed offer ids
    /// @param expiredRolloverBids An array of the expired rollover bid ids
    /// @param unrevealedBids An array of the unrevealed offer ids
    /// @return An array of TermAuctionRevealedBid structs containing details of the revealed bids
    /// @return An array of TermAuctionBid structs containing details of the unrevealed bids
    function _getAllBids(
        bytes32[] calldata revealedBids,
        bytes32[] calldata expiredRolloverBids,
        bytes32[] calldata unrevealedBids
    )
        internal
        returns (TermAuctionRevealedBid[] memory, TermAuctionBid[] memory)
    {
        if (
            revealedBids.length +
                expiredRolloverBids.length +
                unrevealedBids.length !=
            bidCount
        ) {
            revert BidCountIncorrect(bidCount);
        }

        uint256 i;

        for (i = 0; i < expiredRolloverBids.length; ++i) {
            TermAuctionBid storage expiredRolloverBid = bids[
                expiredRolloverBids[i]
            ];
            if (expiredRolloverBid.amount == 0) {
                revert NonExistentBid(expiredRolloverBids[i]);
            }
            if (!expiredRolloverBid.isRollover) {
                revert NonRolloverBid(expiredRolloverBids[i]);
            }
            ITermRepoServicer pairOffServicer = ITermRepoServicer(
                expiredRolloverBid.rolloverPairOffTermRepoServicer
            );
            // NOTE: Include bid for assignment only if term repurchase window hasn't expired.
            // solhint-disable-next-line not-rely-on-time
            if (block.timestamp > pairOffServicer.endOfRepurchaseWindow()) {
                _processBidForAuction(expiredRolloverBid.id);
            } else {
                revert NonExpiredRolloverBid(expiredRolloverBid.id);
            }
        }

        TermAuctionBid[] memory revealedBidsInShortfall;
        uint256 auctionBidCount;
        uint256 unlockBidCount;
        uint256 revealedBidsInShortfallCount;

        (
            revealedBidsInShortfall,
            auctionBidCount,
            unlockBidCount,
            revealedBidsInShortfallCount
        ) = _processRevealedBidsForValidity(
            revealedBids,
            unrevealedBids.length
        );

        TermAuctionRevealedBid[]
            memory bidsForAuction = _fillRevealedBidsForAuctionClearing(
                revealedBids,
                auctionBidCount
            );
        TermAuctionBid[] memory bidsForUnlocking = new TermAuctionBid[](
            unlockBidCount
        );

        // Add unrevealed bids to bid array for unlocking
        uint256 bidsForUnlockingCounter = 0;
        for (i = 0; i < unrevealedBids.length; ++i) {
            TermAuctionBid storage unrevealedBid = bids[unrevealedBids[i]];
            if (unrevealedBid.amount == 0) {
                revert NonExistentBid(unrevealedBids[i]);
            }
            if (unrevealedBid.isRevealed) {
                revert BidRevealed(unrevealedBids[i]);
            }
            bidsForUnlocking[bidsForUnlockingCounter] = unrevealedBid;
            ++bidsForUnlockingCounter;
            _processBidForAuction(unrevealedBid.id);
        }

        for (i = 0; i < revealedBidsInShortfallCount; ++i) {
            bidsForUnlocking[bidsForUnlockingCounter] = revealedBidsInShortfall[
                i
            ];
            ++bidsForUnlockingCounter;
        }

        assert(bidCount == 0);

        return (bidsForAuction, bidsForUnlocking);
    }

    /// @param bid The TermAuctionBid to convert to TermAuctionRevealedBid
    /// @dev This does not check the hash of the revealed bid price
    function _truncateBidStruct(
        TermAuctionBid memory bid
    ) internal pure returns (TermAuctionRevealedBid memory revealed) {
        return
            TermAuctionRevealedBid({
                id: bid.id,
                bidder: bid.bidder,
                bidPriceRevealed: bid.bidPriceRevealed,
                amount: bid.amount,
                collateralAmounts: bid.collateralAmounts,
                purchaseToken: bid.purchaseToken,
                collateralTokens: bid.collateralTokens,
                isRollover: bid.isRollover,
                rolloverPairOffTermRepoServicer: bid
                    .rolloverPairOffTermRepoServicer
            });
    }

    function _processRevealedBidsForValidity(
        bytes32[] calldata revealedBids,
        uint256 unrevealedBidCount
    ) internal returns (TermAuctionBid[] memory, uint256, uint256, uint256) {
        uint256 auctionBidCount = revealedBids.length;
        uint256 unlockBidCount = unrevealedBidCount;

        TermAuctionBid[] memory revealedBidsInShortFall = new TermAuctionBid[](
            auctionBidCount
        );

        uint256 revealedBidsInShortFallCounter = 0;
        uint256 previousBidPrice = 0;

        for (uint256 i = 0; i < revealedBids.length; ++i) {
            TermAuctionBid storage revealedBid = bids[revealedBids[i]];
            if (revealedBid.amount == 0) {
                revert NonExistentBid(revealedBids[i]);
            }
            if (previousBidPrice > revealedBid.bidPriceRevealed) {
                revert RevealedBidsNotSorted();
            } else {
                previousBidPrice = revealedBid.bidPriceRevealed;
            }
            if (revealedBid.isRollover) {
                ITermRepoServicer pairOffServicer = ITermRepoServicer(
                    revealedBid.rolloverPairOffTermRepoServicer
                );
                // NOTE: Include bid for assignment only if term repurchase window hasn't expired.
                if (
                    // solhint-disable-next-line not-rely-on-time
                    block.timestamp > pairOffServicer.endOfRepurchaseWindow()
                ) {
                    revert RolloverBidExpired(revealedBid.id);
                }

                if (!_isRolloverStillValid(revealedBid, pairOffServicer)) {
                    ++unlockBidCount;
                    revealedBidsInShortFall[
                        revealedBidsInShortFallCounter
                    ] = revealedBid;
                    ++revealedBidsInShortFallCounter;
                    --auctionBidCount;
                    _processBidForAuction(revealedBid.id);
                    continue;
                }
            } else {
                if (!revealedBid.isRevealed) {
                    revert BidNotRevealed(revealedBid.id);
                }
            }

            // If bid is in shortfall, mark for unlocking if not a rollover
            if (
                _isInMaintenanceCollateralShortFall(
                    revealedBid.amount,
                    revealedBid.bidPriceRevealed,
                    revealedBid.collateralTokens,
                    revealedBid.collateralAmounts
                )
            ) {
                emitter.emitBidInShortfall(termAuctionId, revealedBid.id);

                ++unlockBidCount;
                revealedBidsInShortFall[
                    revealedBidsInShortFallCounter
                ] = revealedBid;
                ++revealedBidsInShortFallCounter;
                --auctionBidCount;
                _processBidForAuction(revealedBid.id);
            }
        }
        return (
            revealedBidsInShortFall,
            auctionBidCount,
            unlockBidCount,
            revealedBidsInShortFallCounter
        );
    }

    function _isRolloverStillValid(
        TermAuctionBid storage revealedBid,
        ITermRepoServicer pairOffServicer
    ) internal returns (bool) {
        uint256 borrowerRepurchaseObligation = pairOffServicer
            .getBorrowerRepurchaseObligation(revealedBid.bidder);

        if (borrowerRepurchaseObligation == 0) {
            return false;
        }

        uint256 servicingFeeProRatedMantissa = mul_(
            Exp({mantissa: dayCountFractionMantissa}),
            Exp({mantissa: termRepoServicer.servicingFee()})
        ).mantissa;

        uint256 maxRolloverAmount = truncate(
            div_(
                Exp({mantissa: borrowerRepurchaseObligation * expScale}),
                Exp({mantissa: expScale - servicingFeeProRatedMantissa})
            )
        );
        if (maxRolloverAmount < revealedBid.amount) {
            revealedBid.amount = maxRolloverAmount;
        }

        ///@dev get proportional collateral amount to collateralize rollover

        uint256 proportionMantissa = (revealedBid.amount * expScale) /
            maxRolloverAmount;

        ITermRepoCollateralManager pairOffCollateralManager = pairOffServicer
            .termRepoCollateralManager();

        (
            address[] memory pairOffCollateralTokens,
            uint256[] memory collateralAmounts
        ) = pairOffCollateralManager.getCollateralBalances(revealedBid.bidder);

        uint256 collateralAmount;

        for (uint256 i = 0; i < pairOffCollateralTokens.length; ++i) {
            collateralAmount = mul_ScalarTruncate(
                Exp({mantissa: proportionMantissa}),
                collateralAmounts[i]
            );
            if (collateralAmount != revealedBid.collateralAmounts[i]) {
                revealedBid.collateralAmounts[i] = collateralAmount;
            }
        }
        emitter.emitBidLocked(termAuctionId, revealedBid, address(0));

        return true;
    }

    function _isInInitialCollateralShortFall(
        uint256 bidAmount,
        address[] memory collateralTokens_,
        uint256[] memory collateralAmounts
    ) internal view returns (bool) {
        Exp memory bidAmountUSDValue = termPriceOracle.usdValueOfTokens(
            purchaseToken,
            bidAmount
        );
        Exp memory haircutUSDTotalCollateralValue = Exp({mantissa: 0});
        for (uint256 i = 0; i < collateralTokens_.length; ++i) {
            address collateralToken = collateralTokens_[i];
            uint256 initialCollateralRatio = termRepoCollateralManager
                .initialCollateralRatios(collateralToken);
            if (collateralAmounts[i] == 0) {
                continue;
            }
            Exp memory additionalHairCutUSDCollateralValue = div_(
                termPriceOracle.usdValueOfTokens(
                    collateralToken,
                    collateralAmounts[i]
                ),
                Exp({mantissa: initialCollateralRatio})
            );
            haircutUSDTotalCollateralValue = add_(
                additionalHairCutUSDCollateralValue,
                haircutUSDTotalCollateralValue
            );
        }
        if (lessThanExp(haircutUSDTotalCollateralValue, bidAmountUSDValue)) {
            return true;
        }
        return false;
    }

    function _isInMaintenanceCollateralShortFall(
        uint256 bidAmount,
        uint256 bidPrice,
        address[] memory collateralTokens_,
        uint256[] memory collateralAmounts
    ) internal view returns (bool) {
        uint256 repurchasePrice;
        if (bidPrice == 0) {
            repurchasePrice = bidAmount;
        } else {
            Exp memory repurchaseFactor = add_(
                Exp({mantissa: expScale}),
                mul_(
                    Exp({mantissa: dayCountFractionMantissa}),
                    Exp({mantissa: bidPrice})
                )
            );

            repurchasePrice = truncate(
                mul_(Exp({mantissa: bidAmount * expScale}), repurchaseFactor)
            );
        }

        Exp memory repurchasePriceUSDValue = termPriceOracle.usdValueOfTokens(
            purchaseToken,
            repurchasePrice
        );
        Exp memory haircutUSDTotalCollateralValue = Exp({mantissa: 0});
        for (uint256 i = 0; i < collateralTokens_.length; ++i) {
            address collateralToken = collateralTokens_[i];
            uint256 maintenanceCollateralRatio = termRepoCollateralManager
                .maintenanceCollateralRatios(collateralToken);
            if (collateralAmounts[i] == 0) {
                continue;
            }
            Exp memory additionalHairCutUSDCollateralValue = div_(
                termPriceOracle.usdValueOfTokens(
                    collateralToken,
                    collateralAmounts[i]
                ),
                Exp({mantissa: maintenanceCollateralRatio})
            );
            haircutUSDTotalCollateralValue = add_(
                additionalHairCutUSDCollateralValue,
                haircutUSDTotalCollateralValue
            );
        }
        if (
            lessThanExp(haircutUSDTotalCollateralValue, repurchasePriceUSDValue)
        ) {
            return true;
        }
        return false;
    }

    function _fillRevealedBidsForAuctionClearing(
        bytes32[] calldata revealedBids,
        uint256 auctionBidCount
    ) internal returns (TermAuctionRevealedBid[] memory) {
        TermAuctionRevealedBid[]
            memory bidsForAuction = new TermAuctionRevealedBid[](
                auctionBidCount
            );

        // fill auction bids array
        uint256 bidsForAuctionCounter = 0;
        for (uint256 i = 0; i < revealedBids.length; ++i) {
            TermAuctionBid storage revealedBid = bids[revealedBids[i]];

            if (revealedBid.amount == 0) {
                continue;
            }

            bidsForAuction[bidsForAuctionCounter] = _truncateBidStruct(
                revealedBid
            );

            bidsForAuctionCounter++;
            _processBidForAuction(revealedBid.id);
        }
        return bidsForAuction;
    }

    function _generateBidId(
        bytes32 id,
        address user
    ) internal view returns (bytes32) {
        bytes32 generatedId = keccak256(
            abi.encodePacked(id, user, address(this))
        );
        if (bids[generatedId].amount != 0) {
            revert GeneratingExistingBid(generatedId);
        }
        return generatedId;
    }

    function _processBidForAuction(bytes32 id) internal {
        delete bids[id];
        bidCount -= 1;
    }

    // ========================================================================
    // = Pausable =============================================================
    // ========================================================================

    function pauseLocking() external onlyRole(ADMIN_ROLE) {
        lockingPaused = true;
        emitter.emitBidLockingPaused(termAuctionId, termRepoId);
    }

    function unpauseLocking() external onlyRole(ADMIN_ROLE) {
        lockingPaused = false;
        emitter.emitBidLockingUnpaused(termAuctionId, termRepoId);
    }

    function pauseUnlocking() external onlyRole(ADMIN_ROLE) {
        unlockingPaused = true;
        emitter.emitBidUnlockingPaused(termAuctionId, termRepoId);
    }

    function unpauseUnlocking() external onlyRole(ADMIN_ROLE) {
        unlockingPaused = false;
        emitter.emitBidUnlockingUnpaused(termAuctionId, termRepoId);
    }

    ///@dev required override by the OpenZeppelin UUPS module
    ///@param impl new impl address for proxy upgrade
    function _authorizeUpgrade(
        address impl
    ) internal override onlyRole(DEVOPS_ROLE) {
        emitter.emitTermContractUpgraded(address(this), impl);
    }
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermAuction} from "./interfaces/ITermAuction.sol";
import {ITermAuctionOfferLocker} from "./interfaces/ITermAuctionOfferLocker.sol";
import {ITermAuctionOfferLockerErrors} from "./interfaces/ITermAuctionOfferLockerErrors.sol";
import {ITermEventEmitter} from "./interfaces/ITermEventEmitter.sol";
import {ITermRepoServicer} from "./interfaces/ITermRepoServicer.sol";
import {TermAuctionOffer} from "./lib/TermAuctionOffer.sol";
import {TermAuctionOfferSubmission} from "./lib/TermAuctionOfferSubmission.sol";
import {TermAuctionRevealedOffer} from "./lib/TermAuctionRevealedOffer.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {ReentrancyGuardUpgradeable} from "@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol";
import {IERC20Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import {Versionable} from "./lib/Versionable.sol";

/// @author TermLabs
/// @title Term Offer Locker
/// @notice This contract handles and proceesses Term Auction offer submissions
/// @dev This contract belongs to the Term Auction group of contracts and is specific to a Term Repo deployment
contract TermAuctionOfferLocker is
    ITermAuctionOfferLocker,
    ITermAuctionOfferLockerErrors,
    UUPSUpgradeable,
    AccessControlUpgradeable,
    ReentrancyGuardUpgradeable,
    Versionable
{
    // ========================================================================
    // = Constants  ===========================================================
    // ========================================================================

    uint256 public constant MAX_OFFER_PRICE = 10000e16; // 10,000%

    uint256 public constant MAX_OFFER_COUNT = 150;

    // ========================================================================
    // = Access Roles  ========================================================
    // ========================================================================
    bytes32 public constant ADMIN_ROLE = keccak256("ADMIN_ROLE");
    bytes32 public constant AUCTIONEER_ROLE = keccak256("AUCTIONEER_ROLE");
    bytes32 public constant DEVOPS_ROLE = keccak256("DEVOPS_ROLE");
    bytes32 public constant INITIALIZER_ROLE = keccak256("INITIALIZER_ROLE");

    // ========================================================================
    // = State Variables  =====================================================
    // ========================================================================

    // Auction configuration.
    bytes32 public termRepoId;
    bytes32 public termAuctionId;
    uint256 public auctionStartTime;
    uint256 public revealTime;
    uint256 public auctionEndTime;
    uint256 public minimumTenderAmount;
    IERC20Upgradeable public purchaseToken;
    mapping(IERC20Upgradeable => bool) public collateralTokens;
    ITermRepoServicer public termRepoServicer;
    ITermEventEmitter internal emitter;
    ITermAuction internal termAuction;

    // Auction in-progress state
    mapping(bytes32 => TermAuctionOffer) internal offers;
    uint256 public offerCount;
    bool internal termContractPaired;
    bool public lockingPaused;
    bool public unlockingPaused;

    // ========================================================================
    // = Modifiers  ===========================================================
    // ========================================================================

    modifier onlyWhileAuctionOpen() {
        if (
            // solhint-disable-next-line not-rely-on-time
            block.timestamp > revealTime || block.timestamp < auctionStartTime
        ) {
            revert AuctionNotOpen();
        }
        _;
    }
    modifier onlyWhileAuctionRevealing() {
        if (
            // solhint-disable-next-line not-rely-on-time
            block.timestamp < revealTime
        ) {
            revert AuctionNotRevealing();
        }
        _;
    }

    modifier onlyOfferor(address offeror, address authedUser) {
        if (authedUser != offeror) {
            revert OfferNotOwned();
        }
        _;
    }
    modifier onlyExistingOffer(bytes32 id) {
        if (offers[id].amount == 0) {
            revert NonExistentOffer(id);
        }
        _;
    }
    modifier whenLockingNotPaused() {
        if (lockingPaused) {
            revert LockingPaused();
        }
        _;
    }
    modifier whenUnlockingNotPaused() {
        if (unlockingPaused) {
            revert UnlockingPaused();
        }
        _;
    }

    modifier notTermContractPaired() {
        if (termContractPaired) {
            revert AlreadyTermContractPaired();
        }
        termContractPaired = true;
        _;
    }

    // ========================================================================
    // = Deploy (https://docs.openzeppelin.com/contracts/4.x/upgradeable) =====
    // ========================================================================

    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor() {
        _disableInitializers();
    }

    function initialize(
        string calldata termRepoId_,
        string calldata auctionId_,
        uint256 auctionStartTime_,
        uint256 revealTime_,
        uint256 auctionEndTime_,
        uint256 minimumTenderAmount_,
        IERC20Upgradeable purchaseToken_,
        IERC20Upgradeable[] memory collateralTokens_,
        address termInitializer_
    ) external initializer {
        UUPSUpgradeable.__UUPSUpgradeable_init();
        AccessControlUpgradeable.__AccessControl_init();
        ReentrancyGuardUpgradeable.__ReentrancyGuard_init();

        _grantRole(INITIALIZER_ROLE, termInitializer_);

        if (auctionStartTime_ > revealTime_) {
            revert AuctionStartsAfterReveal(auctionStartTime_, revealTime_);
        }

        termRepoId = keccak256(abi.encodePacked(termRepoId_));
        termAuctionId = keccak256(abi.encodePacked(auctionId_));

        auctionStartTime = auctionStartTime_;
        revealTime = revealTime_;
        auctionEndTime = auctionEndTime_;
        minimumTenderAmount = minimumTenderAmount_;
        purchaseToken = purchaseToken_;
        address[] memory collateralTokenAddresses = new address[](
            collateralTokens_.length
        );
        for (uint8 i = 0; i < collateralTokens_.length; ++i) {
            collateralTokens[collateralTokens_[i]] = true;
            collateralTokenAddresses[i] = address(collateralTokens_[i]);
        }

        offerCount = 0;
        termContractPaired = false;
    }

    function pairTermContracts(
        address termAuction_,
        ITermEventEmitter emitter_,
        ITermRepoServicer termRepoServicer_,
        address devopsMultisig_,
        address adminWallet_
    ) external onlyRole(INITIALIZER_ROLE) notTermContractPaired {
        termAuction = ITermAuction(termAuction_);
        _setupRole(AUCTIONEER_ROLE, termAuction_);
        _grantRole(DEVOPS_ROLE, devopsMultisig_);
        _grantRole(ADMIN_ROLE, adminWallet_);

        emitter = emitter_;

        termRepoServicer = termRepoServicer_;

        emitter.emitTermAuctionOfferLockerInitialized(
            termRepoId,
            termAuctionId,
            address(this),
            auctionStartTime,
            revealTime,
            MAX_OFFER_PRICE,
            minimumTenderAmount
        );
    }

    // ========================================================================
    // = Interface/API ========================================================
    // ========================================================================

    /// @param offerSubmissions An array of Term Auction offer submissions to lend an amount of money at rate no lower than the offer rate
    /// @param referralAddress A user address that referred the submitter of this offer
    /// @return A bytes32 array of unique on chain offer ids.
    function lockOffersWithReferral(
        TermAuctionOfferSubmission[] calldata offerSubmissions,
        address referralAddress
    )
        external
        onlyWhileAuctionOpen
        whenLockingNotPaused
        nonReentrant
        returns (bytes32[] memory)
    {
        if (msg.sender == referralAddress) {
            revert InvalidSelfReferral();
        }

        bytes32[] memory offerIds = new bytes32[](offerSubmissions.length);

        for (uint256 i = 0; i < offerSubmissions.length; ++i) {
            TermAuctionOffer storage offer = _lock(
                offerSubmissions[i],
                msg.sender
            );
            offerIds[i] = offer.id;
            emitter.emitOfferLocked(
                termAuctionId,
                offer.id,
                offer.offeror,
                offer.offerPriceHash,
                offer.amount,
                offer.purchaseToken,
                referralAddress
            );
        }
        return offerIds;
    }

    /// @param offerSubmissions An array of offer submissions
    /// @return A bytes32 array of unique on chain offer ids.
    function lockOffers(
        TermAuctionOfferSubmission[] memory offerSubmissions
    )
        external
        onlyWhileAuctionOpen
        whenLockingNotPaused
        nonReentrant
        returns (bytes32[] memory)
    {
        bytes32[] memory offerIds = new bytes32[](offerSubmissions.length);
        for (uint256 i = 0; i < offerSubmissions.length; ++i) {
            TermAuctionOffer storage offer = _lock(
                offerSubmissions[i],
                msg.sender
            );
            offerIds[i] = offer.id;
            emitter.emitOfferLocked(
                termAuctionId,
                offer.id,
                offer.offeror,
                offer.offerPriceHash,
                offer.amount,
                offer.purchaseToken,
                address(0)
            );
        }
        return offerIds;
    }

    /// @param id An offer Id
    /// @return A struct containing the details of the locked offer
    function lockedOffer(
        bytes32 id
    ) external view returns (TermAuctionOffer memory) {
        return offers[id];
    }

    /// @param ids An array offer ids to reveal
    /// @param prices An array of the offer prices to reveal
    /// @param nonces An array of nonce values to generate bid price hashes
    function revealOffers(
        bytes32[] calldata ids,
        uint256[] calldata prices,
        uint256[] calldata nonces
    ) external onlyWhileAuctionRevealing {
        for (uint256 i = 0; i < ids.length; ++i) {
            _revealOffer(ids[i], prices[i], nonces[i]);
        }
    }

    /// @notice unlockOffers unlocks multiple offers and returns funds to the offeror
    /// @param ids An array of offer ids
    function unlockOffers(
        bytes32[] calldata ids
    ) external whenUnlockingNotPaused nonReentrant {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp < auctionStartTime) {
            revert AuctionNotOpen();
        }
        // solhint-disable-next-line not-rely-on-time
        if (
            block.timestamp > revealTime &&
            !termAuction.auctionCancelledForWithdrawal()
        ) {
            revert AuctionNotOpen();
        }

        for (uint256 i = 0; i < ids.length; ++i) {
            if (offers[ids[i]].amount == 0) {
                revert NonExistentOffer(ids[i]);
            }
            if (msg.sender != offers[ids[i]].offeror) {
                revert OfferNotOwned();
            }
            _unlock(ids[i], msg.sender);
        }
    }

    // =========================================================================
    // = Auction Interface/API =================================================
    // =========================================================================

    /// @param revealedOffers An array of the revealed offer ids
    /// @param unrevealedOffers An array of the unrevealed offer ids
    /// @return An array of TermAuctionRevealedOffer structs containing details of the revealed offers
    /// @return An array of TermAuctionOffer structs containing details of the unrevealed offers
    function getAllOffers(
        bytes32[] calldata revealedOffers,
        bytes32[] calldata unrevealedOffers
    )
        external
        onlyRole(AUCTIONEER_ROLE)
        returns (TermAuctionRevealedOffer[] memory, TermAuctionOffer[] memory)
    {
        if (revealedOffers.length + unrevealedOffers.length != offerCount) {
            revert OfferCountIncorrect(offerCount);
        }

        TermAuctionRevealedOffer[]
            memory offersForAuction = new TermAuctionRevealedOffer[](
                revealedOffers.length
            );
        TermAuctionOffer[] memory unrevealed = new TermAuctionOffer[](
            unrevealedOffers.length
        );

        uint256 j = 0;
        uint256 previousOfferPrice = 0;
        for (uint256 i = 0; i < revealedOffers.length; ++i) {
            TermAuctionOffer storage revealedOffer = offers[revealedOffers[i]];
            if (revealedOffer.amount == 0) {
                revert NonExistentOffer(revealedOffers[i]);
            }
            if (!revealedOffer.isRevealed) {
                revert OfferNotRevealed(revealedOffer.id);
            }
            if (previousOfferPrice > revealedOffer.offerPriceRevealed) {
                revert RevealedOffersNotSorted();
            } else {
                previousOfferPrice = revealedOffer.offerPriceRevealed;
            }

            offersForAuction[j] = _truncateOfferStruct(
                revealedOffer,
                revealedOffer.offerPriceRevealed
            );
            j++;
            _processOfferForAuction(revealedOffer.id);
        }
        uint256 k = 0;
        for (uint256 i = 0; i < unrevealedOffers.length; ++i) {
            TermAuctionOffer storage unrevealedOffer = offers[
                unrevealedOffers[i]
            ];
            if (unrevealedOffer.amount == 0) {
                revert NonExistentOffer(unrevealedOffers[i]);
            }
            if (unrevealedOffer.isRevealed) {
                revert OfferRevealed(unrevealedOffers[i]);
            }
            unrevealed[k] = unrevealedOffer;
            ++k;
            _processOfferForAuction(unrevealedOffer.id);
        }

        assert(offerCount == 0);

        return (offersForAuction, unrevealed);
    }

    /// @param id An offer Id
    /// @param offeror Address of the offeror
    /// @param amount The amount of purchase tokens to unlock
    function unlockOfferPartial(
        bytes32 id,
        address offeror,
        uint256 amount
    ) public onlyRole(AUCTIONEER_ROLE) {
        termRepoServicer.unlockOfferAmount(offeror, amount);
        emitter.emitOfferUnlocked(termAuctionId, id);
    }

    // ========================================================================
    // = Helpers ==============================================================
    // ========================================================================

    function _lock(
        TermAuctionOfferSubmission memory offerSubmission,
        address authedUser
    )
        internal
        onlyOfferor(offerSubmission.offeror, authedUser)
        returns (TermAuctionOffer storage)
    {
        if (offerCount >= MAX_OFFER_COUNT) {
            revert MaxOfferCountReached();
        }
        bool offerExists = offers[offerSubmission.id].amount != 0;
        bytes32 offerId;
        if (offerExists) {
            if (offers[offerSubmission.id].offeror != offerSubmission.offeror) {
                revert OfferNotOwned();
            }
            offerId = offerSubmission.id;
        } else {
            offerId = _generateOfferId(offerSubmission.id, authedUser);
        }
        if (address(purchaseToken) != offerSubmission.purchaseToken) {
            revert PurchaseTokenNotApproved(offerSubmission.purchaseToken);
        }
        if (offerSubmission.amount < minimumTenderAmount) {
            revert OfferAmountTooLow(offerSubmission.amount);
        }

        uint256 oldLockedAmount = offers[offerId].amount;

        // Store offer in auction contract.
        offers[offerId] = TermAuctionOffer({
            id: offerId,
            offeror: offerSubmission.offeror,
            offerPriceRevealed: 0,
            offerPriceHash: offerSubmission.offerPriceHash,
            amount: offerSubmission.amount,
            purchaseToken: offerSubmission.purchaseToken,
            isRevealed: false
        });
        if (!offerExists) {
            offerCount += 1;
        }

        // Calculate the amount of purchase tokens to lock.
        if (oldLockedAmount < offerSubmission.amount) {
            termRepoServicer.lockOfferAmount(
                offerSubmission.offeror,
                offerSubmission.amount - oldLockedAmount
            );
        } else if (oldLockedAmount > offerSubmission.amount) {
            termRepoServicer.unlockOfferAmount(
                offerSubmission.offeror,
                oldLockedAmount - offerSubmission.amount
            );
        }

        return offers[offerId];
    }

    function _unlock(bytes32 id, address offeror) internal {
        uint256 amountToUnlock = offers[id].amount;

        delete offers[id];
        offerCount -= 1;

        emitter.emitOfferUnlocked(termAuctionId, id);

        termRepoServicer.unlockOfferAmount(offeror, amountToUnlock);
    }

    /// @dev Will revert if either the price does not match the offer price or is greater than the max offer price
    /// @param id An offer Id
    /// @param price The price of the offer to reveal
    /// @param nonce The user provided nonce value to generate the bid price hash
    function _revealOffer(bytes32 id, uint256 price, uint256 nonce) internal {
        // Check that price hasn't been modified/revealed.
        if (keccak256(abi.encode(price, nonce)) != offers[id].offerPriceHash) {
            revert OfferPriceModified();
        }
        if (price > MAX_OFFER_PRICE) {
            revert TenderPriceTooHigh(id, MAX_OFFER_PRICE);
        }

        offers[id].offerPriceRevealed = price;
        offers[id].isRevealed = true;

        emitter.emitOfferRevealed(termAuctionId, id, price);
    }

    function _generateOfferId(
        bytes32 id,
        address user
    ) internal view returns (bytes32) {
        bytes32 generatedId = keccak256(
            abi.encodePacked(id, user, address(this))
        );
        if (offers[generatedId].amount != 0) {
            revert GeneratingExistingOffer(generatedId);
        }
        return generatedId;
    }

    function _processOfferForAuction(bytes32 id) internal {
        delete offers[id];
        offerCount -= 1;
    }

    /// @param hidden TermAuctionOffer to convert to TermAuctionRevealedOffer
    /// @param price The revealed price of the offer
    /// @dev This does not check the hash of the revealed offer price
    function _truncateOfferStruct(
        TermAuctionOffer memory hidden,
        uint256 price
    ) internal pure returns (TermAuctionRevealedOffer memory revealed) {
        return
            TermAuctionRevealedOffer({
                id: hidden.id,
                offeror: hidden.offeror,
                offerPriceRevealed: price,
                amount: hidden.amount,
                purchaseToken: hidden.purchaseToken
            });
    }

    // ========================================================================
    // = Pausable =============================================================
    // ========================================================================

    function pauseLocking() external onlyRole(ADMIN_ROLE) {
        lockingPaused = true;
        emitter.emitOfferLockingPaused(termAuctionId, termRepoId);
    }

    function unpauseLocking() external onlyRole(ADMIN_ROLE) {
        lockingPaused = false;
        emitter.emitOfferLockingUnpaused(termAuctionId, termRepoId);
    }

    function pauseUnlocking() external onlyRole(ADMIN_ROLE) {
        unlockingPaused = true;
        emitter.emitOfferUnlockingPaused(termAuctionId, termRepoId);
    }

    function unpauseUnlocking() external onlyRole(ADMIN_ROLE) {
        unlockingPaused = false;
        emitter.emitOfferUnlockingUnpaused(termAuctionId, termRepoId);
    }

    ///@dev required override by the OpenZeppelin UUPS module
    ///@param impl new impl address for proxy upgrade
    function _authorizeUpgrade(
        address impl
    ) internal override onlyRole(DEVOPS_ROLE) {
        emitter.emitTermContractUpgraded(address(this), impl);
    }
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermPriceOracle} from "./interfaces/ITermPriceOracle.sol";
import {ITermPriceOracleErrors} from "./interfaces/ITermPriceOracleErrors.sol";
import {ITermPriceOracleEvents} from "./interfaces/ITermPriceOracleEvents.sol";
import {ITermEventEmitter} from "./interfaces/ITermEventEmitter.sol";
import {Collateral} from "./lib/Collateral.sol";
import {ExponentialNoError} from "./lib/ExponentialNoError.sol";
import {TermPriceFeedConfig} from "./lib/TermPriceFeedConfig.sol";
import {AggregatorV3Interface} from "@chainlink/contracts/src/v0.8/shared/interfaces/AggregatorV3Interface.sol";
import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {IERC20MetadataUpgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/extensions/IERC20MetadataUpgradeable.sol";
import {Versionable} from "./lib/Versionable.sol";

/// @author TermLabs
/// @title Term Price Consumer V3
/// @notice This contract is a centralized price oracle contract that feeds pricing data to all Term Repos
/// @dev This contract operates at the protocol level and governs all instances of a Term Repo
contract TermPriceConsumerV3 is
    ITermPriceOracle,
    ITermPriceOracleErrors,
    ITermPriceOracleEvents,
    Initializable,
    UUPSUpgradeable,
    AccessControlUpgradeable,
    ExponentialNoError,
    Versionable
{
    // ========================================================================
    // = Access Role  ======================================================
    // ========================================================================

    bytes32 public constant DEVOPS_ROLE = keccak256("DEVOPS_ROLE");

    mapping(address => TermPriceFeedConfig) internal priceFeeds;
    mapping(address => TermPriceFeedConfig) internal fallbackPriceFeeds;


    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor() {
        _disableInitializers();
    }

    /// @notice Intializes with an array of token addresses, followed with an array of Chainlink aggregator addresses
    /// @notice https://docs.chain.link/docs/ethereum-addresses/
    function initialize(
        address devopsWallet_
    ) external initializer {
        UUPSUpgradeable.__UUPSUpgradeable_init();
        AccessControlUpgradeable.__AccessControl_init();

        _grantRole(DEVOPS_ROLE, devopsWallet_);
    }

    /// @param token The address of the token to add a price feed for
    /// @param tokenPriceAggregator The price aggregator address for token to be added
    /// @param tokenPriceAggregatorRefreshRateThreshold Refresh threshold in seconds for primary price feed updates beyond which price is stale
    /// @param fallbackPriceAggregator The fallback  price aggregator address for token to be added
    /// @param fallbackPriceAggregatorRefreshRateThreshold Refresh threshold for fallback price feed updates beyond which price is stale

    function addNewTokenPriceFeedAndFallbackPriceFeed(
        address token,
        address tokenPriceAggregator,
        uint256 tokenPriceAggregatorRefreshRateThreshold,
        address fallbackPriceAggregator,
        uint256 fallbackPriceAggregatorRefreshRateThreshold
    ) external onlyRole(DEVOPS_ROLE) {
        _addNewTokenPriceFeed(token, tokenPriceAggregator, tokenPriceAggregatorRefreshRateThreshold);
        _addNewTokenFallbackPriceFeed(token, fallbackPriceAggregator, fallbackPriceAggregatorRefreshRateThreshold);
    }

    /// @param token The address of the token to add a price feed for
    /// @param tokenPriceAggregator The proxy price aggregator address for token to be added
    /// @param refreshRateThreshold Refresh threshold in seconds for primary price feed updates beyond which price is stale

    function addNewTokenPriceFeed(
        address token,
        address tokenPriceAggregator,
        uint256 refreshRateThreshold
    ) external onlyRole(DEVOPS_ROLE) {
        _addNewTokenPriceFeed(token, tokenPriceAggregator, refreshRateThreshold);
    }

    /// @param token The address of the token to add a price feed for
    /// @param tokenPriceAggregator The proxy price aggregator address for token to be added
    /// @param refreshRateThreshold Refresh threshold in seconds for fallback price feed updates beyond which price is stale
    function addNewTokenFallbackPriceFeed(
        address token,
        address tokenPriceAggregator,
        uint256 refreshRateThreshold
    ) external onlyRole(DEVOPS_ROLE) {
        _addNewTokenFallbackPriceFeed(token, tokenPriceAggregator, refreshRateThreshold);
    }

    /// @param token The address of the token whose price feed needs to be removed
    function removeTokenPriceFeed(
        address token
    ) external onlyRole(DEVOPS_ROLE) {
        delete priceFeeds[token];
        emit UnsubscribePriceFeed(token);
    }

    /// @param token The address of the token whose price feed needs to be removed
    function removeFallbackTokenPriceFeed(
        address token
    ) external onlyRole(DEVOPS_ROLE) {
        delete fallbackPriceFeeds[token];
        emit UnsubscribeFallbackPriceFeed(token);
    }

    /// @notice A function to return current market value given a token address and an amount
    /// @param token The address of the token to query
    /// @param amount The amount tokens to value
    /// @return The current market value of tokens at the specified amount, in USD
    function usdValueOfTokens(
        address token,
        uint256 amount
    ) external view returns (Exp memory) {
        if (address(priceFeeds[token].priceFeed) == address(0)) {
            revert NoPriceFeed(token);
        }
        int256 latestPriceInt;
        uint8 priceDecimals;
        (latestPriceInt, priceDecimals) = _getLatestPrice(token);
        uint256 latestPrice = uint256(latestPriceInt);

        IERC20MetadataUpgradeable tokenInstance = IERC20MetadataUpgradeable(
            token
        );
        uint8 tokenDecimals = tokenInstance.decimals();

        return
            mul_(
                Exp({mantissa: (amount * expScale) / 10 ** tokenDecimals}),
                Exp({mantissa: (latestPrice * expScale) / 10 ** priceDecimals})
            );
    }

    /// @param token The address of the token to add a price feed for
    /// @param tokenPriceAggregator The proxy price aggregator address for token to be added
    /// @param refreshRateThreshold Refresh threshold in seconds for primary price feed updates beyond which price is stale

    function _addNewTokenPriceFeed(
        address token,
        address tokenPriceAggregator,
        uint256 refreshRateThreshold
    ) internal {
        require(tokenPriceAggregator != address(0), "Primary Price feed cannot be zero address");
        AggregatorV3Interface priceFeed = AggregatorV3Interface(tokenPriceAggregator);

         (
            ,
            // uint80 roundID
            int256 price, // uint startedAt // //uint timeStamp// //uint80 answeredInRound//
            ,
            uint256 lastUpdatedTimestamp,

        ) = priceFeed.latestRoundData();

        if (price <= 0) {
            revert InvalidPrice();
        }
        TermPriceFeedConfig memory priceFeedConfig = TermPriceFeedConfig({
            priceFeed: AggregatorV3Interface(tokenPriceAggregator),
            refreshRateThreshold: refreshRateThreshold
        });
        priceFeeds[token] = priceFeedConfig;
        emit SubscribePriceFeed(token, tokenPriceAggregator);
    }

    /// @param token The address of the token to add a price feed for
    /// @param tokenPriceAggregator The proxy price aggregator address for token to be added
    /// @param refreshRateThreshold Refresh threshold in seconds for fallback price feed updates beyond which price is stale
    function _addNewTokenFallbackPriceFeed(
        address token,
        address tokenPriceAggregator,
        uint256 refreshRateThreshold
    ) internal {
        require(tokenPriceAggregator != address(0), "Fallback Price feed cannot be zero address");
        AggregatorV3Interface priceFeed = AggregatorV3Interface(tokenPriceAggregator);

         (
            ,
            // uint80 roundID
            int256 price, // uint startedAt // //uint timeStamp// //uint80 answeredInRound//
            ,
            uint256 lastUpdatedTimestamp,

        ) = priceFeed.latestRoundData();

        if (price <= 0) {
            revert InvalidPrice();
        }
        
        TermPriceFeedConfig memory priceFeedConfig = TermPriceFeedConfig({
            priceFeed: AggregatorV3Interface(tokenPriceAggregator),
            refreshRateThreshold: refreshRateThreshold
        });
        fallbackPriceFeeds[token] = priceFeedConfig;
        emit SubscribeFallbackPriceFeed(token, tokenPriceAggregator);
    }
    

    /// @return The latest price from price aggregator and the decimals in the price
    function _getLatestPrice(address token) internal view returns (int256, uint8) {

        (
            ,
            // uint80 roundID
            int256 price, // uint startedAt // //uint timeStamp// //uint80 answeredInRound//
            ,
            uint256 lastUpdatedTimestamp,

        ) = priceFeeds[token].priceFeed.latestRoundData();

        AggregatorV3Interface fallbackPriceFeed = fallbackPriceFeeds[token].priceFeed;

        
        if (address(fallbackPriceFeed) == address(0)) {
            if (price <= 0) {
                revert InvalidPrice();
            } else if (priceFeeds[token].refreshRateThreshold == 0 || ( block.timestamp - lastUpdatedTimestamp) <=  priceFeeds[token].refreshRateThreshold) {
                return (price, priceFeeds[token].priceFeed.decimals()); // Use primary price feed if there is no fallback price feed and update within refresh rate.
            }  else {
                revert PricesStale(); // Price is stale if outside of refresh rate.
            }
        }
        if (address(fallbackPriceFeed) != address(0)) {
            if (price > 0 && ( block.timestamp - lastUpdatedTimestamp) <=   priceFeeds[token].refreshRateThreshold) {
                return (price, priceFeeds[token].priceFeed.decimals()); // Return primary price feed if it is not stale
            }

            (
            ,
            int256 fallbackPrice,
            ,
            uint256 fallbackLastUpdatedTimestamp,

            ) = fallbackPriceFeed.latestRoundData();
            
            if (fallbackPrice <= 0) {
                revert InvalidPrice();
            } else if (fallbackPriceFeeds[token].refreshRateThreshold == 0 || ( block.timestamp - fallbackLastUpdatedTimestamp) <=   fallbackPriceFeeds[token].refreshRateThreshold) {
                return (fallbackPrice, fallbackPriceFeed.decimals()); // Use fallback price feed if primary price feed unavailable
            } 
            else {
                revert PricesStale();
            }
        }
    }

    // ========================================================================
    // = Upgrades =============================================================
    // ========================================================================

    // solhint-disable no-empty-blocks
    /// @dev required override by the OpenZeppelin UUPS module
    function _authorizeUpgrade(
        address
    ) internal view override onlyRole(DEVOPS_ROLE) {}
    // solhint-enable no-empty-blocks
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermController} from "./interfaces/ITermController.sol";
import {ITermEventEmitter} from "./interfaces/ITermEventEmitter.sol";
import {ITermRepoCollateralManager} from "./interfaces/ITermRepoCollateralManager.sol";
import {ITermRepoCollateralManagerErrors} from "./interfaces/ITermRepoCollateralManagerErrors.sol";
import {ITermRepoLocker} from "./interfaces/ITermRepoLocker.sol";
import {ITermRepoServicer} from "./interfaces/ITermRepoServicer.sol";
import {ITermPriceOracle} from "./interfaces/ITermPriceOracle.sol";
import {Collateral} from "./lib/Collateral.sol";
import {ExponentialNoError} from "./lib/ExponentialNoError.sol";
import {TermAuctionGroup} from "./lib/TermAuctionGroup.sol";
import {TermPriceConsumerV3} from "./TermPriceConsumerV3.sol";
import {TermRepoLocker} from "./TermRepoLocker.sol";
import {TermRepoServicer} from "./TermRepoServicer.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {IERC20MetadataUpgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/extensions/IERC20MetadataUpgradeable.sol";
import {Versionable} from "./lib/Versionable.sol";

/// @author TermLabs
/// @title Term Repo Collateral Manager
/// @notice This contract enforces margin maintenance rules for adding/withdrawing, repurchasing and liquidating collateral
/// @dev This contract belongs to the Term Servicer group of contracts and is specific to a Term Repo deployment
contract TermRepoCollateralManager is
    ITermRepoCollateralManager,
    ITermRepoCollateralManagerErrors,
    Initializable,
    UUPSUpgradeable,
    AccessControlUpgradeable,
    ExponentialNoError,
    Versionable
{
    // ========================================================================
    // = Access Role  =========================================================
    // ========================================================================

    bytes32 public constant ADMIN_ROLE = keccak256("ADMIN_ROLE");
    bytes32 public constant AUCTION_LOCKER = keccak256("AUCTION_LOCKER");
    bytes32 public constant DEVOPS_ROLE = keccak256("DEVOPS_ROLE");
    bytes32 public constant INITIALIZER_ROLE = keccak256("INITIALIZER_ROLE");
    bytes32 public constant SERVICER_ROLE = keccak256("SERVICER_ROLE");
    bytes32 public constant ROLLOVER_MANAGER = keccak256("ROLLOVER_MANAGER");
    bytes32 public constant ROLLOVER_TARGET_AUCTIONEER_ROLE =
        keccak256("ROLLOVER_TARGET_AUCTIONEER_ROLE");

    // ========================================================================
    // = State Variables  =====================================================
    // ========================================================================

    // Term Identifier
    bytes32 public termRepoId;

    // Boolean indicating if liquidations are paused
    bool public liquidationsPaused;

    // Boolean indicating if term contracts paired
    bool internal termContractPaired;

    // Number of Collateral Tokens Accepted By Term
    uint8 public numOfAcceptedCollateralTokens;

    // De minimis margin threshold triggering full liquidation
    uint256 public deMinimisMarginThreshold;

    // Collateral Seizures Share for Protocol in Liquidations
    uint256 public liquidatedDamagesDueToProtocol;

    //Max percentage collateralization of repurchase after liquidation
    uint256 public netExposureCapOnLiquidation;

    // Repo servicer within same term
    ITermRepoServicer internal termRepoServicer;

    // token used for purchase/loans
    address public purchaseToken;

    // consumer for Chainlink price feeds
    ITermPriceOracle internal termPriceOracle;

    // TermRepoLocker for term funds
    ITermRepoLocker public termRepoLocker;

    // Term Controller contract
    ITermController internal termController;

    // Term Event Emitter contract
    ITermEventEmitter internal emitter;

    //list of acceptable collateral token addresses
    address[] public collateralTokens;

    // mapping of encumbered collateral balances
    mapping(address => uint256) internal encumberedCollateralBalances;

    // maintenance collateral ratios applicable to accepted collateral token basket
    mapping(address => uint256) public maintenanceCollateralRatios;

    // initial collateral ratios applicable to accepted collateral token basket
    mapping(address => uint256) public initialCollateralRatios;

    // liquidated damages schedule applicable to collateral token basket
    mapping(address => uint256) public liquidatedDamages;

    // Locked Collateral Balance Ledger
    // For each wallet address, keep ledger of collateral balances of different token addresses
    mapping(address => mapping(address => uint256))
        internal lockedCollateralLedger;

    // ========================================================================
    // = Modifiers  ===========================================================
    // ========================================================================

    modifier isCollateralTokenAccepted(address token) {
        if (!_isAcceptedCollateralToken(token)) {
            revert CollateralTokenNotAllowed(token);
        }
        _;
    }

    modifier whileLiquidationsNotPaused() {
        if (liquidationsPaused) {
            revert LiquidationsPaused();
        }
        _;
    }

    modifier notTermContractPaired() {
        if (termContractPaired) {
            revert AlreadyTermContractPaired();
        }
        termContractPaired = true;
        _;
    }

    // ========================================================================
    // = Deploy  ==============================================================
    // ========================================================================

    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor() {
        _disableInitializers();
    }

    function initialize(
        string calldata termRepoId_,
        uint256 liquidatedDamagesDueToProtocol_,
        uint256 netExposureCapOnLiquidation_,
        uint256 deMinimisMarginThreshold_,
        address purchaseToken_,
        Collateral[] calldata collateralTokens_,
        ITermEventEmitter emitter_,
        address termInitializer_
    ) external initializer {
        UUPSUpgradeable.__UUPSUpgradeable_init();
        AccessControlUpgradeable.__AccessControl_init();

        termRepoId = keccak256(abi.encodePacked(termRepoId_));

        liquidationsPaused = false;

        // slither-disable-start reentrancy-no-eth events-maths
        liquidatedDamagesDueToProtocol = liquidatedDamagesDueToProtocol_;

        netExposureCapOnLiquidation = netExposureCapOnLiquidation_;
        deMinimisMarginThreshold = deMinimisMarginThreshold_;
        // slither-disable-end reentrancy-no-eth events-maths

        require(purchaseToken_ != address(0), "Zero address purchase token");
        purchaseToken = purchaseToken_;

        numOfAcceptedCollateralTokens = uint8(collateralTokens_.length);
        collateralTokens = new address[](collateralTokens_.length);

        for (uint256 i = 0; i < collateralTokens_.length; ++i) {
            collateralTokens[i] = collateralTokens_[i].tokenAddress;
            maintenanceCollateralRatios[
                collateralTokens_[i].tokenAddress
            ] = collateralTokens_[i].maintenanceRatio;
            initialCollateralRatios[
                collateralTokens_[i].tokenAddress
            ] = collateralTokens_[i].initialCollateralRatio;

            require(
                collateralTokens_[i].liquidatedDamage != 0,
                "Liquidated damage is zero"
            );
            liquidatedDamages[
                collateralTokens_[i].tokenAddress
            ] = collateralTokens_[i].liquidatedDamage;

            termContractPaired = false;
        }

        emitter = emitter_;

        _grantRole(INITIALIZER_ROLE, termInitializer_);
    }

    function pairTermContracts(
        address termRepoLocker_,
        address termRepoServicer_,
        address termAuctionBidLocker_,
        address termAuction_,
        address termController_,
        address termPriceOracle_,
        address termRepoRolloverManager_,
        address devopsMultisig_,
        address adminWallet_
    ) external onlyRole(INITIALIZER_ROLE) notTermContractPaired {
        termRepoLocker = TermRepoLocker(termRepoLocker_);
        termRepoServicer = TermRepoServicer(termRepoServicer_);
        termPriceOracle = TermPriceConsumerV3(termPriceOracle_);
        termController = ITermController(termController_);

        _grantRole(AUCTION_LOCKER, termAuctionBidLocker_);
        _grantRole(AUCTION_LOCKER, termAuction_);
        _grantRole(AUCTION_LOCKER, termRepoServicer_);
        _grantRole(SERVICER_ROLE, termRepoServicer_);
        _grantRole(ROLLOVER_MANAGER, termRepoRolloverManager_);
        _grantRole(DEVOPS_ROLE, devopsMultisig_);
        _grantRole(ADMIN_ROLE, adminWallet_);

        uint256[] memory maintenanceRatioList = new uint256[](
            collateralTokens.length
        );
        uint256[] memory initialCollateralRatioList = new uint256[](
            collateralTokens.length
        );
        uint256[] memory liquidatedDamagesList = new uint256[](
            collateralTokens.length
        );
        for (uint256 i = 0; i < collateralTokens.length; ++i) {
            maintenanceRatioList[i] = maintenanceCollateralRatios[
                collateralTokens[i]
            ];

            initialCollateralRatioList[i] = initialCollateralRatios[
                collateralTokens[i]
            ];

            liquidatedDamagesList[i] = liquidatedDamages[collateralTokens[i]];
        }

        emitter.emitTermRepoCollateralManagerInitialized(
            termRepoId,
            address(this),
            collateralTokens,
            initialCollateralRatioList,
            maintenanceRatioList,
            liquidatedDamagesList
        );
    }

    // ========================================================================
    // = APIs  ================================================================
    // ========================================================================

    /// @param collateralToken The address of the collateral token to lock
    /// @param amount The amount of collateral token to lock
    function externalLockCollateral(
        address collateralToken,
        uint256 amount
    ) external isCollateralTokenAccepted(collateralToken) {
        address borrower = msg.sender;

        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp > termRepoServicer.endOfRepurchaseWindow()) {
            revert CollateralDepositClosed();
        }

        if (termRepoServicer.getBorrowerRepurchaseObligation(borrower) == 0) {
            revert ZeroBorrowerRepurchaseObligation();
        }

        _lockCollateral(borrower, collateralToken, amount);
    }

    /// @param collateralToken The address of the collateral token to unlock
    /// @param amount The amount of collateral token to unlock
    function externalUnlockCollateral(
        address collateralToken,
        uint256 amount
    ) external isCollateralTokenAccepted(collateralToken) {
        address borrower = msg.sender;

        if (amount == 0) {
            revert InvalidParameters("Zero amount");
        }

        if (lockedCollateralLedger[borrower][collateralToken] == 0) {
            revert ZeroCollateralBalance();
        }
        if (
            // solhint-disable-next-line not-rely-on-time
            block.timestamp >= termRepoServicer.endOfRepurchaseWindow() &&
            // solhint-disable-next-line not-rely-on-time
            block.timestamp < termRepoServicer.redemptionTimestamp()
        ) {
            revert CollateralWithdrawalClosed();
        }
        bool decrementEncumberedCollateral;

        // if borrow balance is zero, collateral has already been unencumbered through liquidation
        if (termRepoServicer.getBorrowerRepurchaseObligation(borrower) != 0) {
            decrementEncumberedCollateral = true;
        }
        _unlockCollateral(
            borrower,
            collateralToken,
            amount,
            decrementEncumberedCollateral
        );
        if (isBorrowerInShortfall(borrower)) {
            revert CollateralBelowMaintenanceRatios(borrower, collateralToken);
        }
    }

    /// @param borrower The address of the borrower
    /// @param closureAmounts An array specifying the amounts of Term Repo exposure the liquidator proposes to cover in liquidation; an amount is required to be specified for each collateral token
    function batchLiquidation(
        address borrower,
        uint256[] calldata closureAmounts
    ) external whileLiquidationsNotPaused {
        bool allowFullLiquidation = _validateBatchLiquidationForFullLiquidation(
            borrower,
            msg.sender,
            closureAmounts
        );

        uint256 totalClosureAmount = 0;

        uint256 collateralSeizureAmount;
        uint256 collateralSeizureProtocolShare;

        for (uint256 i = 0; i < closureAmounts.length; ++i) {
            if (closureAmounts[i] == 0) {
                continue;
            }
            if (closureAmounts[i] == type(uint256).max) {
                revert InvalidParameters("closureAmounts cannot be uint max");
            }
            totalClosureAmount += closureAmounts[i];

            termRepoServicer.liquidatorCoverExposure(
                borrower,
                msg.sender,
                closureAmounts[i]
            );

            (
                collateralSeizureAmount,
                collateralSeizureProtocolShare
            ) = _collateralSeizureAmounts(
                closureAmounts[i],
                collateralTokens[i]
            );

            _transferLiquidationCollateral(
                borrower,
                msg.sender,
                collateralTokens[i],
                closureAmounts[i],
                collateralSeizureAmount,
                collateralSeizureProtocolShare,
                false
            );
        }

        if (totalClosureAmount == 0) {
            revert ZeroLiquidationNotPermitted();
        }

        /// allow any liquidations if within margin minimum
        if (!allowFullLiquidation) {
            if (!_withinNetExposureCapOnLiquidation(borrower)) {
                revert ExceedsNetExposureCapOnLiquidation();
            }
        }

        // unencumber all collateral tokens owned by borrower if balance paid off
        if (termRepoServicer.getBorrowerRepurchaseObligation(borrower) == 0) {
            _unencumberRemainingBorrowerCollateralOnZeroObligation(borrower);
        }
    }

    /// @param borrower The address of the borrower
    /// @param closureRepoTokenAmounts An array specifying the amounts of Term Repo Tokens the liquidator proposes to cover borrower repo exposure in liquidation; an amount is required to be specified for each collateral token
    function batchLiquidationWithRepoToken(
        address borrower,
        uint256[] calldata closureRepoTokenAmounts
    ) external whileLiquidationsNotPaused {
        bool allowFullLiquidation = _validateBatchLiquidationForFullLiquidation(
            borrower,
            msg.sender,
            closureRepoTokenAmounts
        );

        uint256 totalClosureRepoTokenAmounts = 0;

        uint256 closureValue;

        uint256 collateralSeizureAmount;
        uint256 collateralSeizureProtocolShare;

        for (uint256 i = 0; i < closureRepoTokenAmounts.length; ++i) {
            if (closureRepoTokenAmounts[i] == 0) {
                continue;
            }
            if (closureRepoTokenAmounts[i] == type(uint256).max) {
                revert InvalidParameters(
                    "closureRepoTokenAmounts cannot be uint max"
                );
            }
            totalClosureRepoTokenAmounts += closureRepoTokenAmounts[i];

            closureValue = termRepoServicer
                .liquidatorCoverExposureWithRepoToken(
                    borrower,
                    msg.sender,
                    closureRepoTokenAmounts[i]
                );

            (
                collateralSeizureAmount,
                collateralSeizureProtocolShare
            ) = _collateralSeizureAmounts(closureValue, collateralTokens[i]);

            _transferLiquidationCollateral(
                borrower,
                msg.sender,
                collateralTokens[i],
                closureRepoTokenAmounts[i],
                collateralSeizureAmount,
                collateralSeizureProtocolShare,
                false
            );
        }

        if (totalClosureRepoTokenAmounts == 0) {
            revert ZeroLiquidationNotPermitted();
        }

        /// allow any liquidations if within margin minimum
        if (!allowFullLiquidation) {
            if (!_withinNetExposureCapOnLiquidation(borrower)) {
                revert ExceedsNetExposureCapOnLiquidation();
            }
        }

        // unencumber all collateral tokens owned by borrower if balance paid off
        if (termRepoServicer.getBorrowerRepurchaseObligation(borrower) == 0) {
            _unencumberRemainingBorrowerCollateralOnZeroObligation(borrower);
        }
    }

    /// @param borrower The address of the borrower
    /// @param closureAmounts An array specifying the amounts of Term Repo exposure the liquidator proposes to cover in liquidation; an amount is required to be specified for each collateral token
    function batchDefault(
        address borrower,
        uint256[] calldata closureAmounts
    ) external whileLiquidationsNotPaused {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp <= termRepoServicer.endOfRepurchaseWindow()) {
            revert DefaultsClosed();
        }
        if (msg.sender == borrower) {
            revert SelfLiquidationNotPermitted();
        }
        if (collateralTokens.length != closureAmounts.length) {
            revert InvalidParameters(
                "Closure amounts array not same length as collateral tokens list"
            );
        }

        uint256 totalClosureAmount = 0;
        uint256 borrowerRepurchaseObligation = termRepoServicer
            .getBorrowerRepurchaseObligation(borrower);

        if (borrowerRepurchaseObligation == 0) {
            revert ZeroBorrowerRepurchaseObligation();
        }

        uint256 collateralSeizureAmount;

        uint256 collateralSeizureProtocolShare;

        for (uint256 i = 0; i < closureAmounts.length; ++i) {
            if (closureAmounts[i] == 0) {
                continue;
            }
            if (closureAmounts[i] == type(uint256).max) {
                revert InvalidParameters("closureAmounts cannot be uint max");
            }
            totalClosureAmount += closureAmounts[i];

            if (totalClosureAmount > borrowerRepurchaseObligation) {
                revert TotalRepaymentGreaterThangetBorrowerRepurchaseObligation();
            }

            termRepoServicer.liquidatorCoverExposure(
                borrower,
                msg.sender,
                closureAmounts[i]
            );

            (
                collateralSeizureAmount,
                collateralSeizureProtocolShare
            ) = _collateralSeizureAmounts(
                closureAmounts[i],
                collateralTokens[i]
            );

            _transferLiquidationCollateral(
                borrower,
                msg.sender,
                collateralTokens[i],
                closureAmounts[i],
                collateralSeizureAmount,
                collateralSeizureProtocolShare,
                true
            );
        }

        if (totalClosureAmount == 0) {
            revert ZeroLiquidationNotPermitted();
        }

        // unencumber all collateral tokens owned by borrower if balance paid off
        if (termRepoServicer.getBorrowerRepurchaseObligation(borrower) == 0) {
            _unencumberRemainingBorrowerCollateralOnZeroObligation(borrower);
        }
    }

    /// @param collateralToken The collateral token address of tokens locked
    /// @param amountToLock The amount of collateral tokens to lock
    function calculateMintableExposure(
        address collateralToken,
        uint256 amountToLock
    ) external view returns (Exp memory) {
        return
            div_(
                div_(
                    termPriceOracle.usdValueOfTokens(
                        collateralToken,
                        amountToLock
                    ),
                    Exp({mantissa: initialCollateralRatios[collateralToken]})
                ),
                termPriceOracle.usdValueOfTokens(purchaseToken, 1)
            );
    }

    /// @param borrower The address of the borrower
    /// @return An array of collateral token addresses
    /// @return An array collateral token balances locked on behalf of borrower
    function getCollateralBalances(
        address borrower
    ) external view returns (address[] memory, uint256[] memory) {
        address[] memory collateralTokensOwnedByBorrower = new address[](
            collateralTokens.length
        );
        uint256[] memory collateralBalancesOwnedByBorrower = new uint256[](
            collateralTokens.length
        );
        for (uint256 i = 0; i < collateralTokens.length; ++i) {
            address collateralToken = collateralTokens[i];
            uint256 collateralAmount = lockedCollateralLedger[borrower][
                collateralToken
            ];
            collateralTokensOwnedByBorrower[i] = collateralToken;
            collateralBalancesOwnedByBorrower[i] = collateralAmount;
        }
        return (
            collateralTokensOwnedByBorrower,
            collateralBalancesOwnedByBorrower
        );
    }

    /// @param borrower The address of the borrower
    /// @param collateralToken The collateral token address to query
    /// @return uint256 The amount of collateralToken locked on behalf of borrower
    function getCollateralBalance(
        address borrower,
        address collateralToken
    ) external view returns (uint256) {
        return lockedCollateralLedger[borrower][collateralToken];
    }

    /// @return bool A boolean that tests whether any encumbered collateral remains locked
    function encumberedCollateralRemaining() external view returns (bool) {
        for (uint256 i = 0; i < collateralTokens.length; ++i) {
            if (encumberedCollateralBalances[collateralTokens[i]] > 0) {
                return true;
            }
        }
        return false;
    }

    // ========================================================================
    // = Auction Functions  ===================================================
    // ========================================================================

    /// @param bidder The bidder's address
    /// @param collateralToken The address of the token to be used as collateral
    /// @param amount The amount of the token to lock
    function auctionLockCollateral(
        address bidder,
        address collateralToken,
        uint256 amount
    ) external onlyRole(AUCTION_LOCKER) {
        termRepoLocker.transferTokenFromWallet(bidder, collateralToken, amount);
    }

    /// @param bidder The bidder's address
    /// @param collateralToken The address of the token used as collateral
    /// @param amount The amount of collateral tokens to unlock
    function auctionUnlockCollateral(
        address bidder,
        address collateralToken,
        uint256 amount
    ) external onlyRole(AUCTION_LOCKER) {
        termRepoLocker.transferTokenToWallet(bidder, collateralToken, amount);
    }

    // ========================================================================
    // = Rollover Functions  ==================================================
    // ========================================================================

    /// @param borrower The address of the borrower
    /// @param collateralToken The address of a collateral token
    /// @param amount The amount of collateral tokens to lock
    function acceptRolloverCollateral(
        address borrower,
        address collateralToken,
        uint256 amount
    ) external onlyRole(AUCTION_LOCKER) {
        lockedCollateralLedger[borrower][collateralToken] += amount;
        encumberedCollateralBalances[collateralToken] += amount;

        emitter.emitCollateralLocked(
            termRepoId,
            borrower,
            collateralToken,
            amount
        );
    }

    /// @param borrower The borrower's address
    /// @param rolloverProportion The proportion of the collateral to be unlocked, equal to the proportion of the collateral repaid
    /// @param rolloverTermRepoLocker The address of the new TermRepoLocker contract to roll into
    /// @return An array representing a list of accepted collateral token addresses
    /// @return An array containing the amount of collateral tokens to pairoff and transfer to new TermRepoLocker to roll into
    function transferRolloverCollateral(
        address borrower,
        uint256 rolloverProportion,
        address rolloverTermRepoLocker
    )
        external
        onlyRole(ROLLOVER_TARGET_AUCTIONEER_ROLE)
        returns (address[] memory, uint256[] memory)
    {
        return (
            collateralTokens,
            _partialUnlockCollateral(
                borrower,
                rolloverProportion,
                rolloverTermRepoLocker
            )
        );
    }

    /// @param rolloverAuction The address of the rollover auction
    function approveRolloverAuction(
        address rolloverAuction
    ) external onlyRole(ROLLOVER_MANAGER) {
        _grantRole(ROLLOVER_TARGET_AUCTIONEER_ROLE, rolloverAuction);
    }

    // ========================================================================
    // = Servicer Functions  ========================================
    // ========================================================================

    /// @param borrower The address of the borrower
    function unlockCollateralOnRepurchase(
        address borrower
    ) external onlyRole(SERVICER_ROLE) {
        for (uint256 i = 0; i < collateralTokens.length; ++i) {
            address collateralToken = collateralTokens[i];
            uint256 collateralAmount = lockedCollateralLedger[borrower][
                collateralToken
            ];

            if (collateralAmount > 0) {
                _unlockCollateral(
                    borrower,
                    collateralToken,
                    collateralAmount,
                    true
                );
            }
        }
    }

    /// @param borrower The address of the borrower
    /// @param collateralTokenAddresses Collateral token addresses
    /// @param collateralTokenAmounts Collateral token amounts
    function journalBidCollateralToCollateralManager(
        address borrower,
        address[] calldata collateralTokenAddresses,
        uint256[] calldata collateralTokenAmounts
    ) external onlyRole(SERVICER_ROLE) {
        for (uint256 i = 0; i < collateralTokenAddresses.length; ++i) {
            lockedCollateralLedger[borrower][
                collateralTokenAddresses[i]
            ] += collateralTokenAmounts[i];
            encumberedCollateralBalances[
                collateralTokenAddresses[i]
            ] += collateralTokenAmounts[i];

            emitter.emitCollateralLocked(
                termRepoId,
                borrower,
                collateralTokenAddresses[i],
                collateralTokenAmounts[i]
            );
        }
    }

    /// @param borrower The address of the borrower
    /// @param collateralToken Collateral token addresse
    /// @param amount Collateral token amount
    function mintOpenExposureLockCollateral(
        address borrower,
        address collateralToken,
        uint256 amount
    ) external onlyRole(SERVICER_ROLE) {
        _lockCollateral(borrower, collateralToken, amount);
    }

    // ========================================================================
    // = Admin Functions ======================================================
    // ========================================================================

    /// @param termAuctionGroup A struct of auction contracts
    function reopenToNewAuction(
        TermAuctionGroup calldata termAuctionGroup
    ) external onlyRole(INITIALIZER_ROLE) {
        _grantRole(
            AUCTION_LOCKER,
            address(termAuctionGroup.termAuctionBidLocker)
        );

        _grantRole(AUCTION_LOCKER, address(termAuctionGroup.auction));

        emitter.emitPairReopeningBidLocker(
            termRepoId,
            address(this),
            address(termAuctionGroup.termAuctionBidLocker)
        );
    }

    function pauseLiquidations() external onlyRole(ADMIN_ROLE) {
        liquidationsPaused = true;
        emitter.emitLiquidationPaused(termRepoId);
    }

    function unpauseLiquidations() external onlyRole(ADMIN_ROLE) {
        liquidationsPaused = false;
        emitter.emitLiquidationUnpaused(termRepoId);
    }

    // ========================================================================
    // = Public Functions  ====================================================
    // ========================================================================

    /// @param borrower The address of the borrower
    /// @return Boolean testing whether the given borrower is in shortfall or margin deficit
    function isBorrowerInShortfall(
        address borrower
    ) public view returns (bool) {
        Exp memory repurchasePriceUSDValue = termPriceOracle.usdValueOfTokens(
            purchaseToken,
            termRepoServicer.getBorrowerRepurchaseObligation(borrower)
        );
        Exp memory haircutUSDTotalCollateralValue = Exp({mantissa: 0});
        for (uint256 i = 0; i < collateralTokens.length; ++i) {
            address collateralToken = collateralTokens[i];
            Exp memory additionalHairCutUSDCollateralValue = div_(
                termPriceOracle.usdValueOfTokens(
                    collateralToken,
                    lockedCollateralLedger[borrower][collateralToken]
                ),
                Exp({mantissa: maintenanceCollateralRatios[collateralToken]})
            );
            haircutUSDTotalCollateralValue = add_(
                additionalHairCutUSDCollateralValue,
                haircutUSDTotalCollateralValue
            );
        }
        if (
            lessThanExp(haircutUSDTotalCollateralValue, repurchasePriceUSDValue)
        ) {
            return true;
        }
        return false;
    }

    /// @param borrower The address of the borrower
    /// @return The market value of borrower's locked collateral denominated in USD
    function getCollateralMarketValue(
        address borrower
    ) public view returns (uint256) {
        return _usdValueOfBalances(lockedCollateralLedger[borrower]);
    }

    // ========================================================================
    // = Internal Functions  ==================================================
    // ========================================================================
    function _lockCollateral(
        address borrower,
        address collateralToken,
        uint256 amount
    ) internal {
        lockedCollateralLedger[borrower][collateralToken] += amount;
        encumberedCollateralBalances[collateralToken] += amount;
        termRepoLocker.transferTokenFromWallet(
            borrower,
            collateralToken,
            amount
        );

        emitter.emitCollateralLocked(
            termRepoId,
            borrower,
            collateralToken,
            amount
        );
    }

    function _unlockCollateral(
        address borrower,
        address collateralToken,
        uint256 amount,
        bool decrementEncumberedCollateral
    ) internal {
        if (amount > lockedCollateralLedger[borrower][collateralToken]) {
            revert UnlockAmountGreaterThanCollateralBalance();
        }
        lockedCollateralLedger[borrower][collateralToken] -= amount;
        if (decrementEncumberedCollateral) {
            encumberedCollateralBalances[collateralToken] -= amount;
        }
        termRepoLocker.transferTokenToWallet(borrower, collateralToken, amount);

        emitter.emitCollateralUnlocked(
            termRepoId,
            borrower,
            collateralToken,
            amount
        );
    }

    function _partialUnlockCollateral(
        address borrower,
        uint256 unlockProportion,
        address destinationwallet
    ) internal returns (uint256[] memory) {
        uint256[] memory unlockedCollateral = new uint256[](
            collateralTokens.length
        );
        for (uint256 i = 0; i < collateralTokens.length; ++i) {
            address collateralToken = collateralTokens[i];
            uint256 collateralAmount = lockedCollateralLedger[borrower][
                collateralToken
            ];

            if (collateralAmount > 0) {
                if (unlockProportion == expScale) {
                    uint256 unlockedAmount = lockedCollateralLedger[borrower][
                        collateralToken
                    ];
                    // slither-disable-start reentrancy-no-eth
                    lockedCollateralLedger[borrower][collateralToken] = 0;
                    unlockedCollateral[i] = unlockedAmount;
                    encumberedCollateralBalances[
                        collateralToken
                    ] -= unlockedAmount;
                    // slither-disable-end reentrancy-no-eth

                    termRepoLocker.transferTokenToWallet(
                        destinationwallet,
                        collateralToken,
                        unlockedAmount
                    );
                    emitter.emitCollateralUnlocked(
                        termRepoId,
                        borrower,
                        collateralToken,
                        unlockedAmount
                    );
                } else {
                    uint256 proportionToUnlock = mul_ScalarTruncate(
                        Exp({mantissa: unlockProportion}),
                        collateralAmount
                    );
                    // slither-disable-start reentrancy-no-eth
                    lockedCollateralLedger[borrower][
                        collateralToken
                    ] -= proportionToUnlock;
                    unlockedCollateral[i] = proportionToUnlock;
                    encumberedCollateralBalances[
                        collateralToken
                    ] -= proportionToUnlock;
                    // slither-disable-end reentrancy-no-eth

                    termRepoLocker.transferTokenToWallet(
                        destinationwallet,
                        collateralToken,
                        proportionToUnlock
                    );
                    emitter.emitCollateralUnlocked(
                        termRepoId,
                        borrower,
                        collateralToken,
                        proportionToUnlock
                    );
                }
            }
        }
        return unlockedCollateral;
    }

    /// @dev A helper function to validate various conditions required to liquidate
    /// @return A boolean for whether borrower position eligible for full liquidation
    function _validateBatchLiquidationForFullLiquidation(
        address borrower,
        address liquidator,
        uint256[] calldata closureTokenAmounts
    ) internal returns (bool) {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp > termRepoServicer.endOfRepurchaseWindow()) {
            revert ShortfallLiquidationsClosed();
        }
        if (liquidator == borrower) {
            revert SelfLiquidationNotPermitted();
        }
        if (collateralTokens.length != closureTokenAmounts.length) {
            revert InvalidParameters(
                "Closure amounts array not same length as collateral tokens list"
            );
        }
        uint256 borrowerRepurchaseObligation = termRepoServicer
            .getBorrowerRepurchaseObligation(borrower);
        if (borrowerRepurchaseObligation == 0) {
            revert ZeroBorrowerRepurchaseObligation();
        }

        if (!isBorrowerInShortfall(borrower)) {
            revert BorrowerNotInShortfall();
        }

        bool allowFullLiquidation = getCollateralMarketValue(borrower) <
            termPriceOracle
                .usdValueOfTokens(purchaseToken, borrowerRepurchaseObligation)
                .mantissa +
                deMinimisMarginThreshold;

        return allowFullLiquidation;
    }

    function _unencumberRemainingBorrowerCollateralOnZeroObligation(
        address borrower
    ) internal {
        for (uint256 i = 0; i < collateralTokens.length; ++i) {
            encumberedCollateralBalances[
                collateralTokens[i]
            ] -= lockedCollateralLedger[borrower][collateralTokens[i]];
        }
    }

    function _withinNetExposureCapOnLiquidation(
        address borrower
    ) internal view returns (bool) {
        uint256 borrowerRepurchaseObligation = termRepoServicer
            .getBorrowerRepurchaseObligation(borrower);

        /// Borrower should not be liquidated to zero balance in this case.
        if (borrowerRepurchaseObligation == 0) {
            return false;
        }

        Exp memory haircutUSDTotalCollateralValue = Exp({mantissa: 0});
        for (uint256 i = 0; i < collateralTokens.length; ++i) {
            address collateralToken = collateralTokens[i];
            Exp memory additionalHairCutUSDCollateralValue = div_(
                termPriceOracle.usdValueOfTokens(
                    collateralToken,
                    lockedCollateralLedger[borrower][collateralToken]
                ),
                Exp({mantissa: initialCollateralRatios[collateralToken]})
            );
            haircutUSDTotalCollateralValue = add_(
                additionalHairCutUSDCollateralValue,
                haircutUSDTotalCollateralValue
            );
        }
        Exp memory borrowerRepurchaseValue = termPriceOracle.usdValueOfTokens(
            purchaseToken,
            borrowerRepurchaseObligation
        );

        if (
            lessThanExp(haircutUSDTotalCollateralValue, borrowerRepurchaseValue)
        ) {
            return true;
        }
        Exp memory excessEquity = sub_(
            haircutUSDTotalCollateralValue,
            borrowerRepurchaseValue
        );

        return
            lessThanOrEqualExp(
                div_(excessEquity, borrowerRepurchaseValue),
                Exp({mantissa: netExposureCapOnLiquidation})
            );
    }

    ///@dev returns total amount of collateral seized in liquidation and the amount of that total going protocol
    function _collateralSeizureAmounts(
        uint256 amountToCover_,
        address collateralToken
    ) internal view returns (uint256, uint256) {
        IERC20MetadataUpgradeable tokenInstance = IERC20MetadataUpgradeable(
            collateralToken
        );
        Exp memory usdValueOfCoverAmount = termPriceOracle.usdValueOfTokens(
            purchaseToken,
            amountToCover_
        );
        Exp memory latestPriceValueCollateralAmount = div_(
            usdValueOfCoverAmount,
            termPriceOracle.usdValueOfTokens(
                collateralToken,
                10 ** (tokenInstance.decimals())
            )
        );

        Exp memory collateralAmountWithDiscount = mul_(
            latestPriceValueCollateralAmount,
            add_(
                Exp({mantissa: expScale}),
                Exp({mantissa: liquidatedDamages[collateralToken]})
            )
        );

        Exp memory protocolSeizureAmount = mul_(
            latestPriceValueCollateralAmount,
            Exp({mantissa: liquidatedDamagesDueToProtocol})
        );

        // this is equivalent to usdValueOfClosureAmount / discountedPriceofCollateralToken
        return (
            collateralAmountWithDiscount.mantissa /
                10 ** (18 - tokenInstance.decimals()),
            protocolSeizureAmount.mantissa /
                10 ** (18 - tokenInstance.decimals())
        );
    }

    /// @dev A helper function to transfer tokens and update relevant state variables and mappings
    function _transferLiquidationCollateral(
        address borrower,
        address liquidator,
        address collateralAddress,
        uint256 closureAmount,
        uint256 collateralSeizureAmount,
        uint256 collateralSeizureProtocolShare,
        bool isDefault
    ) internal {
        if (
            collateralSeizureAmount >
            lockedCollateralLedger[borrower][collateralAddress]
        ) {
            revert InsufficientCollateralForLiquidationRepayment(
                collateralAddress
            );
        }
        // slither-disable-start reentrancy-no-eth
        lockedCollateralLedger[borrower][
            collateralAddress
        ] -= collateralSeizureAmount;

        encumberedCollateralBalances[
            collateralAddress
        ] -= collateralSeizureAmount;
        // slither-disable-end reentrancy-no-eth

        termRepoLocker.transferTokenToWallet(
            termController.getProtocolReserveAddress(),
            collateralAddress,
            collateralSeizureProtocolShare
        );

        termRepoLocker.transferTokenToWallet(
            liquidator,
            collateralAddress,
            collateralSeizureAmount - collateralSeizureProtocolShare // Liquidation yield
        );

        emitter.emitLiquidation(
            termRepoId,
            borrower,
            liquidator,
            closureAmount,
            collateralAddress,
            collateralSeizureAmount,
            collateralSeizureProtocolShare,
            isDefault
        );
    }

    function _isAcceptedCollateralToken(
        address token_
    ) internal view returns (bool) {
        if (liquidatedDamages[token_] == 0) {
            return false;
        }
        return true;
    }

    function _usdValueOfBalances(
        mapping(address => uint256) storage _tokenBalances
    ) internal view returns (uint256) {
        Exp memory totalValue = Exp({mantissa: 0});
        for (uint256 i = 0; i < collateralTokens.length; ++i) {
            totalValue = add_(
                totalValue,
                termPriceOracle.usdValueOfTokens(
                    collateralTokens[i],
                    _tokenBalances[collateralTokens[i]]
                )
            );
        }
        return totalValue.mantissa;
    }

    ///@dev required override by the OpenZeppelin UUPS module
    ///@param impl new impl address for proxy upgrade
    function _authorizeUpgrade(
        address impl
    ) internal override onlyRole(DEVOPS_ROLE) {
        emitter.emitTermContractUpgraded(address(this), impl);
    }
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermRepoLocker} from "./interfaces/ITermRepoLocker.sol";
import {ITermRepoLockerErrors} from "./interfaces/ITermRepoLockerErrors.sol";
import {ITermEventEmitter} from "./interfaces/ITermEventEmitter.sol";
import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {IERC20Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import {SafeERC20Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/utils/SafeERC20Upgradeable.sol";
import {Versionable} from "./lib/Versionable.sol";

/// @author TermLabs
/// @title Term Repo Locker
/// @notice This is the contract in which Term Servicer locks collateral and purchase tokens
/// @dev This contract belongs to the Term Servicer group of contracts and is specific to a Term Repo deployment
contract TermRepoLocker is
    ITermRepoLocker,
    ITermRepoLockerErrors,
    Initializable,
    UUPSUpgradeable,
    AccessControlUpgradeable,
    Versionable
{
    using SafeERC20Upgradeable for IERC20Upgradeable;

    // ========================================================================
    // = Access Roles =========================================================
    // ========================================================================
    bytes32 public constant ADMIN_ROLE = keccak256("ADMIN_ROLE");
    bytes32 public constant DEVOPS_ROLE = keccak256("DEVOPS_ROLE");
    bytes32 public constant INITIALIZER_ROLE = keccak256("INITIALIZER_ROLE");
    bytes32 public constant SERVICER_ROLE = keccak256("SERVICER_ROLE");

    // ========================================================================
    // = State Variables ======================================================
    // ========================================================================
    bytes32 public termRepoId;
    bool public transfersPaused;
    // Boolean indicating if term contracts paired
    bool internal termContractPaired;
    ITermEventEmitter internal emitter;

    // ========================================================================
    // = Modifiers  ===========================================================
    // ========================================================================

    modifier whileTransfersNotPaused() {
        if (transfersPaused) {
            revert TermRepoLockerTransfersPaused();
        }
        _;
    }

    modifier notTermContractPaired() {
        if (termContractPaired) {
            revert AlreadyTermContractPaired();
        }
        termContractPaired = true;
        _;
    }

    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor() {
        _disableInitializers();
    }

    function initialize(
        string calldata termRepoId_,
        address termInitializer_
    ) external initializer {
        UUPSUpgradeable.__UUPSUpgradeable_init();
        AccessControlUpgradeable.__AccessControl_init();

        termRepoId = keccak256(abi.encodePacked(termRepoId_));

        transfersPaused = false;

        _grantRole(INITIALIZER_ROLE, termInitializer_);
    }

    function pairTermContracts(
        address termRepoCollateralManager_,
        address termRepoServicer_,
        ITermEventEmitter emitter_,
        address devopsMultisig_,
        address adminWallet_
    ) external onlyRole(INITIALIZER_ROLE) notTermContractPaired {
        emitter = emitter_;

        _grantRole(SERVICER_ROLE, termRepoCollateralManager_);
        _grantRole(SERVICER_ROLE, termRepoServicer_);
        _grantRole(DEVOPS_ROLE, devopsMultisig_);
        _grantRole(ADMIN_ROLE, adminWallet_);

        emitter.emitTermRepoLockerInitialized(termRepoId, address(this));
    }

    /// @notice Locks tokens from origin wallet
    /// @notice Reverts if caller doesn't have SERVICER_ROLE
    /// @param originWallet The wallet from which to transfer tokens
    /// @param token The address of token being transferred
    /// @param amount The amount of tokens to transfer
    function transferTokenFromWallet(
        address originWallet,
        address token,
        uint256 amount
    ) external override whileTransfersNotPaused onlyRole(SERVICER_ROLE) {
        IERC20Upgradeable tokenInstance = IERC20Upgradeable(token);

        // slither-disable-start arbitrary-send-erc20
        /// @dev This function is permissioned to be only callable by other term contracts. The entry points of calls that end up utilizing this function all use Authenticator to
        /// authenticate that the caller is the owner of the token whose approved this contract to spend the tokens. Therefore there is no risk of another wallet using this function
        /// to transfer somebody else's tokens.
        tokenInstance.safeTransferFrom(originWallet, address(this), amount);
        // slither-disable-end arbitrary-send-erc20
    }

    /// @notice Unlocks tokens to destination wallet
    /// @dev Reverts if caller doesn't have SERVICER_ROLE
    /// @param destinationWallet The wallet to unlock tokens into
    /// @param token The address of token being unlocked
    /// @param amount The amount of tokens to unlock
    function transferTokenToWallet(
        address destinationWallet,
        address token,
        uint256 amount
    ) external override whileTransfersNotPaused onlyRole(SERVICER_ROLE) {
        IERC20Upgradeable tokenInstance = IERC20Upgradeable(token);

        tokenInstance.safeTransfer(destinationWallet, amount);
    }

    // ========================================================================
    // = Pause Functions ======================================================
    // ========================================================================

    function pauseTransfers() external onlyRole(ADMIN_ROLE) {
        transfersPaused = true;
        emitter.emitTermRepoLockerTransfersPaused(termRepoId);
    }

    function unpauseTransfers() external onlyRole(ADMIN_ROLE) {
        transfersPaused = false;
        emitter.emitTermRepoLockerTransfersUnpaused(termRepoId);
    }

    ///@dev required override by the OpenZeppelin UUPS module
    ///@param impl new impl address for proxy upgrade
    function _authorizeUpgrade(
        address impl
    ) internal override onlyRole(DEVOPS_ROLE) {
        emitter.emitTermContractUpgraded(address(this), impl);
    }
}

//SPDX-License-Identifier: Unlicense
pragma solidity ^0.8.18;

import {ITermAuctionBidLocker} from "./interfaces/ITermAuctionBidLocker.sol";
import {ITermAuctionOfferLocker} from "./interfaces/ITermAuctionOfferLocker.sol";
import {ITermEventEmitter} from "./interfaces/ITermEventEmitter.sol";
import {ITermRepoRolloverManager} from "./interfaces/ITermRepoRolloverManager.sol";
import {ITermRepoRolloverManagerErrors} from "./interfaces/ITermRepoRolloverManagerErrors.sol";
import {ITermRepoCollateralManager} from "./interfaces/ITermRepoCollateralManager.sol";
import {ITermRepoServicer} from "./interfaces/ITermRepoServicer.sol";
import {ITermController} from "./interfaces/ITermController.sol";
import {ExponentialNoError} from "./lib/ExponentialNoError.sol";
import {TermAuctionBid} from "./lib/TermAuctionBid.sol";
import {TermRepoRolloverElection} from "./lib/TermRepoRolloverElection.sol";
import {TermRepoRolloverElectionSubmission} from "./lib/TermRepoRolloverElectionSubmission.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {IERC20Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import {Versionable} from "./lib/Versionable.sol";

/// @author TermLabs
/// @title Term Repo Rollover Manager
/// @notice This contract accepts and carries out borrower Term Repo rollover instructions
/// @dev This contract belongs to the Term Servicer group of contracts and is specific to a Term Repo deployment
contract TermRepoRolloverManager is
    ITermRepoRolloverManager,
    ITermRepoRolloverManagerErrors,
    ExponentialNoError,
    Initializable,
    UUPSUpgradeable,
    AccessControlUpgradeable,
    Versionable
{
    // ========================================================================
    // = Access Role  =========================================================
    // ========================================================================

    bytes32 public constant ADMIN_ROLE = keccak256("ADMIN_ROLE");
    bytes32 public constant DEVOPS_ROLE = keccak256("DEVOPS_ROLE");
    bytes32 public constant INITIALIZER_ROLE = keccak256("INITIALIZER_ROLE");
    bytes32 public constant ROLLOVER_BID_FULFILLER_ROLE =
        keccak256("ROLLOVER_BID_FULFILLER_ROLE");

    // ========================================================================
    // = State Variables ======================================================
    // ========================================================================
    bytes32 public termRepoId;
    ITermRepoCollateralManager internal termRepoCollateralManager;
    ITermRepoServicer internal termRepoServicer;
    ITermController internal termController;
    ITermEventEmitter internal emitter;

    // Mapping that returns true for approved Borrower Rollover Auction Bid Lockers
    mapping(address => bool) internal approvedRolloverAuctionBidLockers;

    // Borrow Rollover Ledger
    // For each borrower wallet address, keep ledger of borrow rollver election addresses.
    mapping(address => TermRepoRolloverElection) internal rolloverElections;

    bool internal termContractPaired;

    // ========================================================================
    // = Modifiers ============================================================
    // ========================================================================

    modifier whileNotMatured() {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp >= termRepoServicer.maturityTimestamp()) {
            revert MaturityReached();
        }
        _;
    }

    modifier notTermContractPaired() {
        if (termContractPaired) {
            revert AlreadyTermContractPaired();
        }
        termContractPaired = true;
        _;
    }

    // ========================================================================
    // = Deploy  ==============================================================
    // ========================================================================

    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor() {
        _disableInitializers();
    }

    function initialize(
        string calldata termRepoId_,
        ITermRepoServicer termRepoServicer_,
        ITermRepoCollateralManager termRepoCollateralManager_,
        ITermController termController_,
        address termInitializer_
    ) external initializer {
        UUPSUpgradeable.__UUPSUpgradeable_init();
        AccessControlUpgradeable.__AccessControl_init();

        termRepoId = keccak256(abi.encodePacked(termRepoId_));
        termRepoCollateralManager = termRepoCollateralManager_;
        termRepoServicer = termRepoServicer_;
        termController = termController_;

        termContractPaired = false;

        _grantRole(INITIALIZER_ROLE, termInitializer_);
    }

    function pairTermContracts(
        address termRepoServicer_,
        ITermEventEmitter emitter_,
        address devopsMultisig_,
        address adminWallet_
    ) external onlyRole(INITIALIZER_ROLE) notTermContractPaired {
        emitter = emitter_;
        _grantRole(ROLLOVER_BID_FULFILLER_ROLE, termRepoServicer_);
        _grantRole(DEVOPS_ROLE, devopsMultisig_);
        _grantRole(ADMIN_ROLE, adminWallet_);

        emitter.emitTermRepoRolloverManagerInitialized(
            termRepoId,
            address(this)
        );
    }

    // ========================================================================
    // = APIs  ================================================================
    // ========================================================================

    /// @notice An external function that accepted Term Repo rollover instructions
    /// @param termRepoRolloverElectionSubmission A struct containing borrower rollover instructions
    function electRollover(
        TermRepoRolloverElectionSubmission
            calldata termRepoRolloverElectionSubmission
    ) external whileNotMatured {
        address borrower = msg.sender;
        uint256 borrowerRepurchaseObligation = termRepoServicer
            .getBorrowerRepurchaseObligation(borrower);
        if (borrowerRepurchaseObligation == 0) {
            revert ZeroBorrowerRepurchaseObligation();
        }
        if (
            !approvedRolloverAuctionBidLockers[
                termRepoRolloverElectionSubmission.rolloverAuctionBidLocker
            ]
        ) {
            revert RolloverAddressNotApproved(
                termRepoRolloverElectionSubmission.rolloverAuctionBidLocker
            );
        }

        if (rolloverElections[borrower].processed) {
            revert RolloverProcessedToTerm();
        }

        if (termRepoRolloverElectionSubmission.rolloverAmount == 0) {
            revert InvalidParameters("Rollover amount cannot be 0");
        }

        if (
            borrowerRepurchaseObligation <
            termRepoRolloverElectionSubmission.rolloverAmount
        ) {
            revert BorrowerRepurchaseObligationInsufficient();
        }

        if(rolloverElections[borrower].rolloverAuctionBidLocker != address(0) && rolloverElections[borrower].rolloverAuctionBidLocker != termRepoRolloverElectionSubmission.rolloverAuctionBidLocker){
            rolloverElections[borrower].rolloverAmount = 0;
            _processRollover(borrower);
        }


        rolloverElections[borrower] = TermRepoRolloverElection({
            rolloverAuctionBidLocker: termRepoRolloverElectionSubmission.rolloverAuctionBidLocker,
            rolloverAmount: termRepoRolloverElectionSubmission.rolloverAmount,
            rolloverBidPriceHash: termRepoRolloverElectionSubmission
                .rolloverBidPriceHash,
            processed: false
        });

        ITermAuctionBidLocker auctionBidLocker = ITermAuctionBidLocker(
            termRepoRolloverElectionSubmission.rolloverAuctionBidLocker
        );

        emitter.emitRolloverElection(
            termRepoId,
            auctionBidLocker.termRepoId(),
            borrower,
            termRepoRolloverElectionSubmission.rolloverAuctionBidLocker,
            termRepoRolloverElectionSubmission.rolloverAmount,
            termRepoRolloverElectionSubmission.rolloverBidPriceHash
        );

        _processRollover(borrower);
    }

    /// @notice A view function that returns borrower rollover instructions
    /// @param borrower The address of the borrower
    /// @return A struct containing borrower rollover instructions
    function getRolloverInstructions(
        address borrower
    ) external view returns (TermRepoRolloverElection memory) {
        return rolloverElections[borrower];
    }

    /// @notice An external function to cancel previously submitted rollover instructions
    function cancelRollover() external {
        address borrower = msg.sender;
        if (termRepoServicer.getBorrowerRepurchaseObligation(borrower) == 0) {
            revert ZeroBorrowerRepurchaseObligation();
        }

        if (rolloverElections[borrower].rolloverAmount == 0) {
            revert NoRolloverToCancel();
        }

        if (rolloverElections[borrower].processed) {
            revert RolloverProcessedToTerm();
        }

        rolloverElections[borrower].rolloverAmount = 0;

        _processRollover(borrower);

        delete rolloverElections[borrower];

        emitter.emitRolloverCancellation(termRepoId, borrower);
    }

    // ========================================================================
    // = Fulfiller Functions ================================================
    // ========================================================================

    /// @notice An external function called by repo servicer to mark rollover as fulfilled
    /// @param borrower The address of the borrower
    function fulfillRollover(
        address borrower
    ) external onlyRole(ROLLOVER_BID_FULFILLER_ROLE) {
        rolloverElections[borrower].processed = true;
        emitter.emitRolloverProcessed(termRepoId, borrower);
    }

    // ========================================================================
    // = Admin Functions ======================================================
    // ========================================================================

    /// @param auctionBidLocker The ABI for ITermAuctionBidLocker interface
    function approveRolloverAuction(
        ITermAuctionBidLocker auctionBidLocker
    ) external onlyRole(ADMIN_ROLE) {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp >= termRepoServicer.maturityTimestamp()) {
            revert MaturityReached();
        }
        if (!termController.isTermDeployed(address(auctionBidLocker))) {
            revert NotTermContract(address(auctionBidLocker));
        }

        if (
            auctionBidLocker.auctionEndTime() >
            termRepoServicer.endOfRepurchaseWindow()
        ) {
            revert AuctionEndsAfterRepayment();
        }
        if (
            auctionBidLocker.auctionEndTime() <
            termRepoServicer.maturityTimestamp()
        ) {
            revert AuctionEndsBeforeMaturity();
        }
        if (
            termRepoServicer.purchaseToken() !=
            address(auctionBidLocker.purchaseToken())
        ) {
            revert DifferentPurchaseToken(
                termRepoServicer.purchaseToken(),
                address(auctionBidLocker.purchaseToken())
            );
        }

        uint256 numOfAcceptedCollateralTokens = termRepoCollateralManager
            .numOfAcceptedCollateralTokens();

        for (uint256 i = 0; i < numOfAcceptedCollateralTokens; ++i) {
            IERC20Upgradeable supportedIERC20Collateral = IERC20Upgradeable(
                termRepoCollateralManager.collateralTokens(i)
            );
            if (!auctionBidLocker.collateralTokens(supportedIERC20Collateral)) {
                revert CollateralTokenNotSupported(
                    address(supportedIERC20Collateral)
                );
            }
        }

        approvedRolloverAuctionBidLockers[address(auctionBidLocker)] = true;

        address termAuction = address(auctionBidLocker.termAuction());

        termRepoServicer.approveRolloverAuction(termAuction);
        termRepoCollateralManager.approveRolloverAuction(termAuction);

        _grantRole(ROLLOVER_BID_FULFILLER_ROLE, termAuction);

        emitter.emitRolloverTermApproved(
            termRepoId,
            auctionBidLocker.termAuctionId()
        );
    }

    /// @param auctionBidLocker The ABI for ITermAuctionBidLocker interface
    function revokeRolloverApproval(
        ITermAuctionBidLocker auctionBidLocker
    ) external onlyRole(ADMIN_ROLE) {
        approvedRolloverAuctionBidLockers[address(auctionBidLocker)] = false;

        emitter.emitRolloverTermApprovalRevoked(
            termRepoId,
            auctionBidLocker.termAuctionId()
        );
    }

    // ========================================================================
    // = Internal =============================================================
    // ========================================================================

    function _processRollover(address borrowerToRollover) internal {
        TermRepoRolloverElection memory rolloverElection = rolloverElections[
            borrowerToRollover
        ];

        ITermAuctionBidLocker termAuctionBidLocker = ITermAuctionBidLocker(
            rolloverElection.rolloverAuctionBidLocker
        );

        ITermRepoServicer futureTermRepoServicer = termAuctionBidLocker
            .termRepoServicer();

        uint256 servicingFeeProRatedMantissa = mul_(
            Exp({mantissa: termAuctionBidLocker.dayCountFractionMantissa()}),
            Exp({mantissa: futureTermRepoServicer.servicingFee()})
        ).mantissa;

        uint256 bidAmount;

        if (rolloverElection.rolloverAmount > 0) {
            bidAmount = truncate(
                div_(
                    Exp({mantissa: rolloverElection.rolloverAmount * expScale}),
                    Exp({mantissa: expScale - servicingFeeProRatedMantissa})
                )
            );
        } else {
            bidAmount = 0;
        }

        (address[] memory collateralTokens, ) = termRepoCollateralManager
            .getCollateralBalances(borrowerToRollover);

        uint256[] memory collateralAmounts = new uint256[](
            collateralTokens.length
        );

        TermAuctionBid memory termAuctionBid = TermAuctionBid({
            id: keccak256(abi.encodePacked(address(this), borrowerToRollover)),
            bidder: borrowerToRollover,
            bidPriceHash: rolloverElection.rolloverBidPriceHash,
            bidPriceRevealed: 0,
            amount: bidAmount,
            collateralTokens: collateralTokens,
            collateralAmounts: collateralAmounts,
            purchaseToken: termRepoServicer.purchaseToken(),
            isRollover: true,
            rolloverPairOffTermRepoServicer: address(termRepoServicer),
            isRevealed: false
        });

        termAuctionBidLocker.lockRolloverBid(termAuctionBid);
    }

    ///@dev required override by the OpenZeppelin UUPS module
    ///@param impl new impl address for proxy upgrade
    function _authorizeUpgrade(
        address impl
    ) internal override onlyRole(DEVOPS_ROLE) {
        emitter.emitTermContractUpgraded(address(this), impl);
    }
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ITermEventEmitter} from "./interfaces/ITermEventEmitter.sol";
import {ITermRepoServicer} from "./interfaces/ITermRepoServicer.sol";
import {ITermRepoServicerErrors} from "./interfaces/ITermRepoServicerErrors.sol";
import {ITermController} from "./interfaces/ITermController.sol";
import {ITermRepoCollateralManager} from "./interfaces/ITermRepoCollateralManager.sol";
import {ITermRepoLocker} from "./interfaces/ITermRepoLocker.sol";
import {ITermRepoRolloverManager} from "./interfaces/ITermRepoRolloverManager.sol";
import {ITermRepoToken} from "./interfaces/ITermRepoToken.sol";
import {ExponentialNoError} from "./lib/ExponentialNoError.sol";
import {TermAuctionGroup} from "./lib/TermAuctionGroup.sol";
import {TermRepoRolloverElection} from "./lib/TermRepoRolloverElection.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {IERC20MetadataUpgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/extensions/IERC20MetadataUpgradeable.sol";
import {Versionable} from "./lib/Versionable.sol";

/// @author TermLabs
/// @title Term Repo Servicer
/// @notice This contract maintains records, collects and disburse repurchase payments
/// @dev This contract belongs to the Term Servicer group of contracts and is specific to a Term Repo deployment
contract TermRepoServicer is
    ITermRepoServicer,
    ITermRepoServicerErrors,
    Initializable,
    UUPSUpgradeable,
    AccessControlUpgradeable,
    ExponentialNoError,
    Versionable
{
    // ========================================================================
    // = Constants  ===========================================================
    // ========================================================================
    uint256 public constant YEAR_SECONDS = 60 * 60 * 24 * 360;

    // ========================================================================
    // = Access Roles  ========================================================
    // ========================================================================

    bytes32 public constant ADMIN_ROLE = keccak256("ADMIN_ROLE");
    bytes32 public constant AUCTION_LOCKER = keccak256("AUCTION_LOCKER");
    bytes32 public constant AUCTIONEER = keccak256("AUCTIONEER");
    bytes32 public constant COLLATERAL_MANAGER =
        keccak256("COLLATERAL_MANAGER");
    bytes32 public constant DEVOPS_ROLE = keccak256("DEVOPS_ROLE");
    bytes32 public constant SPECIALIST_ROLE = keccak256("SPECIALIST_ROLE");
    bytes32 public constant ROLLOVER_MANAGER = keccak256("ROLLOVER_MANAGER");
    bytes32 public constant ROLLOVER_TARGET_AUCTIONEER_ROLE =
        keccak256("ROLLOVER_TARGET_AUCTIONEER_ROLE");
    bytes32 public constant INITIALIZER_ROLE = keccak256("INITIALIZER_ROLE");

    // ========================================================================
    // = State Variables  =====================================================
    // ========================================================================

    bytes32 public termRepoId;

    // Total Repurchase Price Owed by all borrowers
    uint256 public totalOutstandingRepurchaseExposure;

    // Total Repurchase Currency locked by TermLocker
    uint256 public totalRepurchaseCollected;

    // block timestamp at which repurchase is due
    uint256 public maturityTimestamp;

    //block timestamp at which repurchase period ends
    uint256 public endOfRepurchaseWindow;

    /// block timestamp at which term repo tokens can be redeemed
    uint256 public redemptionTimestamp;

    /// percentage share of bid amounts charged to bidder
    uint256 public servicingFee;

    /// proportion of redemption value for redemption
    uint256 public shortfallHaircutMantissa;

    // token used for purchase/loans
    address public purchaseToken;

    // collateral manager in same term
    ITermRepoCollateralManager public termRepoCollateralManager;

    // rollover manager in same term
    ITermRepoRolloverManager public termRepoRolloverManager;

    // TermRepoLocker for term funds
    ITermRepoLocker public termRepoLocker;

    // TermRepoToken for current term
    ITermRepoToken public termRepoToken;

    // global term controller contract
    ITermController internal termController;

    // global term event emitter
    ITermEventEmitter internal emitter;

    // Repurchase Exposure Ledger
    // For each borrower wallet address, keep ledger of repurchase obligations
    mapping(address => uint256) internal repurchaseExposureLedger;

    bool internal termContractPaired;

    // ========================================================================
    // = Modifiers  ===========================================================
    // ========================================================================
    modifier notTermContractPaired() {
        if (termContractPaired) {
            revert AlreadyTermContractPaired();
        }
        termContractPaired = true;
        _;
    }

    // ========================================================================
    // = Deploy  ==============================================================
    // ========================================================================

    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor() {
        _disableInitializers();
    }

    function initialize(
        string calldata termRepoId_,
        uint256 maturityTimestamp_,
        uint256 repurchaseWindow_,
        uint256 redemptionBuffer_,
        uint256 servicingFee_,
        address purchaseToken_,
        ITermController termController_,
        ITermEventEmitter emitter_,
        address termInitializer_
    ) external initializer {
        UUPSUpgradeable.__UUPSUpgradeable_init();
        AccessControlUpgradeable.__AccessControl_init();

        termRepoId = keccak256(abi.encodePacked(termRepoId_));
        totalOutstandingRepurchaseExposure = 0;
        totalRepurchaseCollected = 0;
        maturityTimestamp = maturityTimestamp_;
        endOfRepurchaseWindow = maturityTimestamp_ + repurchaseWindow_;
        redemptionTimestamp =
            maturityTimestamp_ +
            repurchaseWindow_ +
            redemptionBuffer_;
        servicingFee = servicingFee_;

        require(purchaseToken_ != address(0), "Zero address purchase token");
        purchaseToken = purchaseToken_;

        termController = termController_;
        emitter = emitter_;

        termContractPaired = false;

        _grantRole(INITIALIZER_ROLE, termInitializer_);
    }

    function pairTermContracts(
        address termRepoLocker_,
        address termRepoCollateralManager_,
        address termRepoToken_,
        address termAuctionOfferLocker_,
        address termAuction_,
        address rolloverManager_,
        address devopsMultisig_,
        address adminWallet_,
        string calldata version_
    ) external onlyRole(INITIALIZER_ROLE) notTermContractPaired {
        termRepoLocker = ITermRepoLocker(termRepoLocker_);
        termRepoCollateralManager = ITermRepoCollateralManager(
            termRepoCollateralManager_
        );
        termRepoRolloverManager = ITermRepoRolloverManager(rolloverManager_);
        termRepoToken = ITermRepoToken(termRepoToken_);

        _grantRole(AUCTION_LOCKER, termAuctionOfferLocker_);
        _grantRole(AUCTIONEER, termAuction_);
        _grantRole(ADMIN_ROLE, adminWallet_);
        _grantRole(DEVOPS_ROLE, devopsMultisig_);
        _grantRole(COLLATERAL_MANAGER, termRepoCollateralManager_);
        _grantRole(ROLLOVER_MANAGER, rolloverManager_);

        emitter.emitTermRepoServicerInitialized(
            termRepoId,
            address(this),
            purchaseToken,
            maturityTimestamp,
            endOfRepurchaseWindow,
            redemptionTimestamp,
            servicingFee,
            version_
        );
    }

    // ========================================================================
    // = APIs  ================================================================
    // ========================================================================

    /// @notice The max repurchase amount is the repurchase balance less any amounts earmarked for rollover
    /// @param amount The amount of purchase token to submit for repurchase
    function submitRepurchasePayment(uint256 amount) external {
        address borrower = msg.sender;

        if (amount == 0) {
            revert InvalidParameters("zero amount");
        }

        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp >= endOfRepurchaseWindow) {
            revert AfterRepurchaseWindow();
        }

        if (repurchaseExposureLedger[borrower] == 0) {
            revert ZeroBorrowerRepurchaseObligation();
        }

        if (amount == type(uint256).max) {
            revert InvalidParameters("repurchase amount cannot be uint max");
        }

        uint256 maxRepurchaseAmount = _getMaxRepaymentAroundRollover(borrower);

        if (amount > maxRepurchaseAmount) {
            revert RepurchaseAmountTooHigh();
        }

        _repay(borrower, borrower, amount);

        if (repurchaseExposureLedger[borrower] == 0) {
            termRepoCollateralManager.unlockCollateralOnRepurchase(borrower);
        }

        emitter.emitRepurchasePaymentSubmitted(termRepoId, borrower, amount);
    }

    /// @param amountToBurn The amount of TermRepoTokens to burn
    function burnCollapseExposure(uint256 amountToBurn) external {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp >= endOfRepurchaseWindow) {
            revert AfterRepurchaseWindow();
        }

        address borrower = msg.sender;

        if (repurchaseExposureLedger[borrower] == 0) {
            revert ZeroBorrowerRepurchaseObligation();
        }

        IERC20MetadataUpgradeable purchaseTokenInstance = IERC20MetadataUpgradeable(
                purchaseToken
            );
        uint256 purchaseTokenDecimals = uint256(
            purchaseTokenInstance.decimals()
        );

        uint256 maxRepurchaseAmount = _getMaxRepaymentAroundRollover(borrower);

        if (maxRepurchaseAmount == 0){
            revert ZeroMaxRepurchase();
        }

        uint256 termRepoTokenValueOfRepurchase = div_(
            Exp({
                mantissa: maxRepurchaseAmount *
                    10 ** (18 - purchaseTokenDecimals)
            }),
            Exp({mantissa: termRepoToken.redemptionValue()})
        ).mantissa / 10 ** (18 - purchaseTokenDecimals);

        if (amountToBurn < termRepoTokenValueOfRepurchase) {
            uint256 repayAmount = termRepoToken.burnAndReturnValue(
                borrower,
                amountToBurn
            );
            // slither-disable-start reentrancy-no-eth
            repurchaseExposureLedger[borrower] -= repayAmount;

            totalOutstandingRepurchaseExposure -= repayAmount;
            // slither-disable-end reentrancy-no-eth

            assert(_isTermRepoBalanced());

            emitter.emitBurnCollapseExposure(termRepoId, borrower, repayAmount);
        } else {
            // slither-disable-start reentrancy-no-eth
            totalOutstandingRepurchaseExposure -= maxRepurchaseAmount;
            repurchaseExposureLedger[borrower] -= maxRepurchaseAmount;
            // slither-disable-end reentrancy-no-eth

            termRepoToken.burn(borrower, termRepoTokenValueOfRepurchase);

            assert(_isTermRepoBalanced());

            emitter.emitBurnCollapseExposure(
                termRepoId,
                borrower,
                maxRepurchaseAmount
            );

            termRepoCollateralManager.unlockCollateralOnRepurchase(borrower);
        }
    }

    /// @param borrower The address of the borrower to query
    /// @return The total repurchase price due at maturity for a given borrower
    function getBorrowerRepurchaseObligation(
        address borrower
    ) external view returns (uint256) {
        return repurchaseExposureLedger[borrower];
    }

    /// @dev This method allows SPECIALIST_ROLE to open repurchase price exposure against a TermRepoToken mint of corresponding value outside of a Term Auction to create new supply
    /// @param amount The amount of Term Repo Tokens to mint
    /// @param collateralAmounts An array containing an amount of collateral token for each token in collateral basket
    function mintOpenExposure(
        uint256 amount,
        uint256[] calldata collateralAmounts
    ) external {
        address borrower = msg.sender;

        if (!termController.verifyMintExposureAccess(borrower)) {
            revert NoMintOpenExposureAccess();
        }

        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp > maturityTimestamp) {
            revert AfterMaturity();
        }

        if (
            collateralAmounts.length !=
            termRepoCollateralManager.numOfAcceptedCollateralTokens()
        ) {
            revert InvalidParameters(
                "Collateral Amounts array not same length as collateral tokens list"
            );
        }

        uint256 maxMintValue = 0;
        for (uint256 i = 0; i < collateralAmounts.length; ++i) {
            termRepoCollateralManager.mintOpenExposureLockCollateral(
                borrower,
                termRepoCollateralManager.collateralTokens(i),
                collateralAmounts[i]
            );
            uint256 maxTokensFromCollateral = truncate(
                div_(
                    termRepoCollateralManager.calculateMintableExposure(
                        termRepoCollateralManager.collateralTokens(i),
                        collateralAmounts[i]
                    ),
                    Exp({mantissa: termRepoToken.redemptionValue()})
                )
            );
            maxMintValue += maxTokensFromCollateral;
        }
        if (amount > maxMintValue) {
            revert InsufficientCollateral();
        }

        Exp memory proRate = div_(
            // solhint-disable-next-line not-rely-on-time
            Exp({mantissa: (maturityTimestamp - block.timestamp)}),
            Exp({mantissa: (YEAR_SECONDS)})
        );

        Exp memory protocolShareProRated = mul_(
            Exp({mantissa: servicingFee}),
            proRate
        );

        uint256 protocolMintTokens = mul_ScalarTruncate(
            protocolShareProRated,
            amount
        );
        uint256 minterTokens = amount - protocolMintTokens;

        uint256 protocolMintTokensValue = termRepoToken.mintTokens(
            termController.getTreasuryAddress(),
            protocolMintTokens
        );
        uint256 minterTokensValue = termRepoToken.mintTokens(
            borrower,
            minterTokens
        );
        termRepoToken.decrementMintExposureCap(amount);

        uint256 totalMintValue = protocolMintTokensValue + minterTokensValue;

        // slither-disable-start reentrancy-benign
        repurchaseExposureLedger[borrower] += totalMintValue;

        totalOutstandingRepurchaseExposure += totalMintValue;
        // slither-disable-end reentrancy-benign

        assert(_isTermRepoBalanced());

        emitter.emitBidFulfilled(
            termRepoId,
            borrower,
            minterTokensValue,
            totalMintValue,
            protocolMintTokensValue
        );

        emitter.emitMintExposure(
            termRepoId,
            borrower,
            minterTokens,
            protocolMintTokens,
            totalMintValue
        );
    }

    /// @param redeemer The address of redeemer
    /// @param amountToRedeem The amount of TermRepoTokens to redeem
    function redeemTermRepoTokens(
        address redeemer,
        uint256 amountToRedeem
    ) external {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp <= redemptionTimestamp) {
            revert RedemptionPeriodNotOpen();
        }

        if (termRepoToken.balanceOf(redeemer) == 0) {
            revert ZeroTermRepoTokenBalance();
        }

        if (
            termRepoToken.totalRedemptionValue() <=
            totalRepurchaseCollected + 10 ** 4
        ) {
            _parRedemption(redeemer, amountToRedeem);
        } else if (!termRepoCollateralManager.encumberedCollateralRemaining()) {
            _proRataRedemption(redeemer, amountToRedeem);
        } else {
            revert EncumberedCollateralRemaining();
        }
    }

    /// @return A boolean that represents whether the term repo locker is balanced
    function isTermRepoBalanced() external view returns (bool) {
        return _isTermRepoBalanced();
    }

    // ========================================================================
    // = Auction Functions  ===================================================
    // ========================================================================

    /// @param offeror The address of the offeror
    /// @param amount The amount of purchase tokens to lock
    function lockOfferAmount(
        address offeror,
        uint256 amount
    ) external onlyRole(AUCTION_LOCKER) {
        termRepoLocker.transferTokenFromWallet(offeror, purchaseToken, amount);

        emitter.emitOfferLockedByServicer(termRepoId, offeror, amount);
    }

    /// @param offeror The address of the offeror
    /// @param amount The amount of purchase tokens to unlocked
    function unlockOfferAmount(
        address offeror,
        uint256 amount
    ) external onlyRole(AUCTION_LOCKER) {
        termRepoLocker.transferTokenToWallet(offeror, purchaseToken, amount);

        emitter.emitOfferUnlockedByServicer(termRepoId, offeror, amount);
    }

    /// @param offeror The address of the offeror
    /// @param purchasePrice The offer amount to fulfill
    /// @param repurchasePrice The repurchase price due to offeror at maturity
    /// @param offerId Unique identifier for this offer
    function fulfillOffer(
        address offeror,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        bytes32 offerId
    ) external onlyRole(AUCTIONEER) {
        uint256 repoTokensMinted = termRepoToken.mintRedemptionValue(
            offeror,
            repurchasePrice
        );

        emitter.emitOfferFulfilled(
            offerId,
            offeror,
            purchasePrice,
            repurchasePrice,
            repoTokensMinted
        );
    }

    /// @param bidder The address of the bidder
    /// @param purchasePrice The bid amount to fulfill
    /// @param repurchasePrice The repurchase price due at maturity
    /// @param collateralTokens Collateral token addresses
    /// @param collateralAmounts Collateral token amounts
    /// @param dayCountFractionMantissa Actual/360 day count fraction parameter from Term Auction Group
    function fulfillBid(
        address bidder,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        address[] calldata collateralTokens,
        uint256[] calldata collateralAmounts,
        uint256 dayCountFractionMantissa
    ) external onlyRole(AUCTIONEER) {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp >= maturityTimestamp) {
            revert AfterMaturity();
        }

        repurchaseExposureLedger[bidder] += repurchasePrice;
        totalOutstandingRepurchaseExposure += repurchasePrice;

        termRepoCollateralManager.journalBidCollateralToCollateralManager(
            bidder,
            collateralTokens,
            collateralAmounts
        );

        uint256 protocolShare = mul_ScalarTruncate(
            mul_(
                Exp({mantissa: dayCountFractionMantissa}),
                Exp({mantissa: servicingFee})
            ),
            purchasePrice
        );

        termRepoLocker.transferTokenToWallet(
            termController.getTreasuryAddress(),
            purchaseToken,
            protocolShare
        );

        termRepoLocker.transferTokenToWallet(
            bidder,
            purchaseToken,
            purchasePrice - protocolShare
        );

        emitter.emitBidFulfilled(
            termRepoId,
            bidder,
            purchasePrice,
            repurchasePrice,
            protocolShare
        );
    }

    // ========================================================================
    // = Rollover Functions  ==================================================
    // ========================================================================

    /// @param termAuction The address of a TermAuction contract to receive autioneer role
    function approveRolloverAuction(
        address termAuction
    ) external onlyRole(ROLLOVER_MANAGER) {
        _grantRole(ROLLOVER_TARGET_AUCTIONEER_ROLE, termAuction);
    }

    /// @param borrower The address of the borrower rolling into new Term Repo
    /// @param purchasePrice The purchase price received from new TermRepo
    /// @param repurchasePrice The new repurchase price due at maturity of new TermRepo
    /// @param previousTermRepoLocker   The address of the old TermRepoLocker contract
    /// @param dayCountFractionMantissa Actual/360 day count fraction parameter from Term Auction Group
    /// @return The net purchase price received in after deducing protocol servicing fees
    function openExposureOnRolloverNew(
        address borrower,
        uint256 purchasePrice,
        uint256 repurchasePrice,
        address previousTermRepoLocker,
        uint256 dayCountFractionMantissa
    ) external onlyRole(AUCTIONEER) returns (uint256) {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp >= maturityTimestamp) {
            revert AfterMaturity();
        }

        repurchaseExposureLedger[borrower] += repurchasePrice;
        totalOutstandingRepurchaseExposure += repurchasePrice;

        uint256 protocolShare = mul_ScalarTruncate(
            mul_(
                Exp({mantissa: dayCountFractionMantissa}),
                Exp({mantissa: servicingFee})
            ),
            purchasePrice
        );

        termRepoLocker.transferTokenToWallet(
            termController.getTreasuryAddress(),
            purchaseToken,
            protocolShare
        );

        uint256 netPurchasePrice = purchasePrice - protocolShare;

        termRepoLocker.transferTokenToWallet(
            previousTermRepoLocker,
            purchaseToken,
            netPurchasePrice
        );

        emitter.emitExposureOpenedOnRolloverNew(
            termRepoId,
            borrower,
            netPurchasePrice,
            repurchasePrice,
            protocolShare
        );

        return netPurchasePrice;
    }

    /// @param borrower The address of the borrower
    /// @param rolloverSettlementAmount The amount of net proceeds received from new TermRepo to pay down existing repurchase obligation due to old Term Repo
    /// @return A uint256 representing the proportion of total repurchase due to old Term Repo from borrower settled by proceeds from new TermRepo
    function closeExposureOnRolloverExisting(
        address borrower,
        uint256 rolloverSettlementAmount
    ) external onlyRole(ROLLOVER_TARGET_AUCTIONEER_ROLE) returns (uint256) {
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp < maturityTimestamp) {
            revert NotMaturedYet();
        }
        // solhint-disable-next-line not-rely-on-time
        if (block.timestamp >= endOfRepurchaseWindow) {
            revert AfterRepurchaseWindow();
        }
        uint256 proportionPaid;
        if (rolloverSettlementAmount >= repurchaseExposureLedger[borrower]) {
            proportionPaid = expScale;
        } else {
            proportionPaid =
                (rolloverSettlementAmount * expScale) /
                repurchaseExposureLedger[borrower];
        }

        //NOTE: Prevent overflow errors in the case purchasePrice > remaining borrow balance
        if (rolloverSettlementAmount > repurchaseExposureLedger[borrower]) {
            totalOutstandingRepurchaseExposure -= repurchaseExposureLedger[
                borrower
            ];

            totalRepurchaseCollected += repurchaseExposureLedger[borrower];

            emitter.emitExposureClosedOnRolloverExisting(
                termRepoId,
                borrower,
                repurchaseExposureLedger[borrower]
            );
            // slither-disable-start reentrancy-no-eth
            repurchaseExposureLedger[borrower] = 0;
            // slither-disable-end reentrancy-no-eth
        } else {
            repurchaseExposureLedger[borrower] -= rolloverSettlementAmount;
            totalOutstandingRepurchaseExposure -= rolloverSettlementAmount;
            totalRepurchaseCollected += rolloverSettlementAmount;

            emitter.emitExposureClosedOnRolloverExisting(
                termRepoId,
                borrower,
                rolloverSettlementAmount
            );
        }

        assert(_isTermRepoBalanced());

        termRepoRolloverManager.fulfillRollover(borrower);

        return proportionPaid;
    }

    // ========================================================================
    // = Collateral Functions  ================================================
    // ========================================================================

    /// @param borrower The address of the borrower
    /// @param liquidator The address of the liquidator
    /// @param amountToCover The amount of repurchase exposure to cover in liquidation
    function liquidatorCoverExposure(
        address borrower,
        address liquidator,
        uint256 amountToCover
    ) external onlyRole(COLLATERAL_MANAGER) {
        _repay(borrower, liquidator, amountToCover);
    }

    /// @param borrower The address of the borrower
    /// @param liquidator The address of the liquidator
    /// @param amountOfRepoToken The amount of term tokens used to cover in liquidation
    /// @return A uint256 representing purchase value of repo tokens burned
    function liquidatorCoverExposureWithRepoToken(
        address borrower,
        address liquidator,
        uint256 amountOfRepoToken
    ) external onlyRole(COLLATERAL_MANAGER) returns (uint256) {
        uint256 burnValue = termRepoToken.burnAndReturnValue(
            liquidator,
            amountOfRepoToken
        );
        if (burnValue > repurchaseExposureLedger[borrower]) {
            revert RepurchaseAmountTooHigh();
        }
        repurchaseExposureLedger[borrower] -= burnValue;
        totalOutstandingRepurchaseExposure -= burnValue;

        assert(_isTermRepoBalanced());

        return burnValue;
    }

    // ========================================================================
    // = Admin Functions ======================================================
    // ========================================================================

    /// @param termAuctionGroup A struct containing contract addresses of a Term Auction deployment to pair for a reopening of a TermRepo
    function reopenToNewAuction(
        TermAuctionGroup calldata termAuctionGroup
    ) external onlyRole(INITIALIZER_ROLE) {
        _grantRole(
            AUCTION_LOCKER,
            address(termAuctionGroup.termAuctionOfferLocker)
        );
        _grantRole(AUCTIONEER, address(termAuctionGroup.auction));

        emitter.emitReopeningOfferLockerPaired(
            termRepoId,
            address(this),
            address(termAuctionGroup.termAuctionOfferLocker),
            address(termAuctionGroup.auction)
        );
    }

    // ========================================================================
    // = Internal Functions  ==================================================
    // ========================================================================

    /// @notice Truncation is by 4 decimal places due to the assumption that number of participants < 10000
    function _isTermRepoBalanced() internal view returns (bool) {
        if (shortfallHaircutMantissa == 0) {
            return
                (totalOutstandingRepurchaseExposure +
                    totalRepurchaseCollected) /
                    (10 ** 4) ==
                termRepoToken.totalRedemptionValue() / (10 ** 4);
        }

        // @note in the case of shortfall, purchase currency in termRepoLocker must balance the pro rata redemption value of remaining term repo tokens
        return
            (totalRepurchaseCollected) / (10 ** 4) ==
            mul_ScalarTruncate(
                Exp({mantissa: shortfallHaircutMantissa}),
                termRepoToken.totalRedemptionValue()
            ) /
                (10 ** 4);
    }

    function _getMaxRepaymentAroundRollover(
        address borrower
    ) internal view returns (uint256) {
        uint256 outstandingRolloverAmount;
        TermRepoRolloverElection
            memory rolloverElection = termRepoRolloverManager
                .getRolloverInstructions(borrower);
        if (
            rolloverElection.rolloverAmount == 0 || rolloverElection.processed
        ) {
            outstandingRolloverAmount = 0;
        } else {
            outstandingRolloverAmount = rolloverElection.rolloverAmount;
        }

        return repurchaseExposureLedger[borrower] - outstandingRolloverAmount;
    }

    // Reentrancy risk
    function _repay(
        address _borrower,
        address repayer_,
        uint256 amount_
    ) internal {
        if (amount_ > repurchaseExposureLedger[_borrower]) {
            revert RepurchaseAmountTooHigh();
        }
        repurchaseExposureLedger[_borrower] -= amount_;
        totalOutstandingRepurchaseExposure -= amount_;
        totalRepurchaseCollected += amount_;

        termRepoLocker.transferTokenFromWallet(
            repayer_,
            purchaseToken,
            amount_
        );

        assert(_isTermRepoBalanced());
    }

    function _parRedemption(address redeemer_, uint256 amount_) internal {
        uint256 redemptionValue = termRepoToken.burnAndReturnValue(
            redeemer_,
            amount_
        );

        if (redemptionValue <= totalRepurchaseCollected) {
            totalRepurchaseCollected -= redemptionValue;

            termRepoLocker.transferTokenToWallet(
                redeemer_,
                purchaseToken,
                redemptionValue
            );

            emitter.emitTermRepoTokensRedeemed(
                termRepoId,
                redeemer_,
                redemptionValue,
                0
            );
        } else {
            uint256 repurchaseRedeemed = totalRepurchaseCollected;
            totalRepurchaseCollected = 0;

            termRepoLocker.transferTokenToWallet(
                redeemer_,
                purchaseToken,
                repurchaseRedeemed
            );

            emitter.emitTermRepoTokensRedeemed(
                termRepoId,
                redeemer_,
                repurchaseRedeemed,
                0
            );
        }

        assert(_isTermRepoBalanced());
    }

    function _proRataRedemption(address redeemer_, uint256 amount_) internal {
        if (shortfallHaircutMantissa == 0) {
            shortfallHaircutMantissa = div_(
                Exp({mantissa: totalRepurchaseCollected * expScale}),
                Exp({
                    mantissa: (totalRepurchaseCollected +
                        totalOutstandingRepurchaseExposure) * expScale
                })
            ).mantissa;
        }

        // slither-disable-start reentrancy-no-eth
        uint256 redemptionAmount = termRepoToken.burnAndReturnValue(
            redeemer_,
            amount_
        );

        uint256 proRataRedemptionAmount = mul_ScalarTruncate(
            Exp({mantissa: shortfallHaircutMantissa}),
            redemptionAmount
        );

        if (proRataRedemptionAmount <= totalRepurchaseCollected) {
            totalRepurchaseCollected -= proRataRedemptionAmount;

            termRepoLocker.transferTokenToWallet(
                redeemer_,
                purchaseToken,
                proRataRedemptionAmount
            );

            emitter.emitTermRepoTokensRedeemed(
                termRepoId,
                redeemer_,
                proRataRedemptionAmount,
                expScale - shortfallHaircutMantissa
            );
        } else {
            uint256 repurchaseRedeemed = totalRepurchaseCollected;
            totalRepurchaseCollected = 0;

            termRepoLocker.transferTokenToWallet(
                redeemer_,
                purchaseToken,
                repurchaseRedeemed
            );

            emitter.emitTermRepoTokensRedeemed(
                termRepoId,
                redeemer_,
                repurchaseRedeemed,
                expScale - shortfallHaircutMantissa
            );
        }

        assert(_isTermRepoBalanced());
    }

    ///@dev required override by the OpenZeppelin UUPS module
    ///@param impl new impl address for proxy upgrade
    function _authorizeUpgrade(
        address impl
    ) internal override onlyRole(DEVOPS_ROLE) {
        emitter.emitTermContractUpgraded(address(this), impl);
    }
}

//SPDX-License-Identifier: CC-BY-NC-ND-4.0
pragma solidity ^0.8.18;

import {ExponentialNoError} from "./lib/ExponentialNoError.sol";
import {TermRepoTokenConfig} from "./lib/TermRepoTokenConfig.sol";
import {ITermRepoCollateralManager} from "./interfaces/ITermRepoCollateralManager.sol";
import {ITermRepoToken} from "./interfaces/ITermRepoToken.sol";
import {ITermRepoTokenErrors} from "./interfaces/ITermRepoTokenErrors.sol";
import {ITermEventEmitter} from "./interfaces/ITermEventEmitter.sol";
import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {ERC20Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/ERC20Upgradeable.sol";

import {ERC20PermitUpgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/extensions/ERC20PermitUpgradeable.sol";

import {Versionable} from "./lib/Versionable.sol";

/// @author TermLabs
/// @title Term Repo Token
/// @notice This is an ERC-20 contract to track claims to the aggregate repurchase obligations due on the repurchase date across all borrowers to a Term Repo
/// @dev This contract belongs to the Term Servicer group of contracts and is specific to a Term Repo deployment
contract TermRepoToken is
    Initializable,
    ERC20Upgradeable,
    ERC20PermitUpgradeable,
    UUPSUpgradeable,
    AccessControlUpgradeable,
    ExponentialNoError,
    ITermRepoTokenErrors,
    ITermRepoToken,
    Versionable
{
    // ========================================================================
    // = Access Roles  ========================================================
    // ========================================================================

    bytes32 public constant ADMIN_ROLE = keccak256("ADMIN_ROLE");
    bytes32 public constant DEVOPS_ROLE = keccak256("DEVOPS_ROLE");
    bytes32 public constant MINTER_ROLE = keccak256("MINTER_ROLE");
    bytes32 public constant BURNER_ROLE = keccak256("BURNER_ROLE");
    bytes32 public constant INITIALIZER_ROLE = keccak256("INITIALIZER_ROLE");

    // ========================================================================
    // = State Variables ======================================================
    // ========================================================================
    uint8 internal decimalPlaces; // NOTE: aligned with purchase token
    bool internal termContractPaired;
    bool public mintingPaused;
    bool public burningPaused;
    uint256 public redemptionValue; // NOTE: number of purchase tokens per unit
    bytes32 public termRepoId;
    uint256 public mintExposureCap;
    TermRepoTokenConfig public config;
    ITermEventEmitter internal emitter;

    // ========================================================================
    // = Modifiers  ===========================================================
    // ========================================================================

    modifier whileMintingNotPaused() {
        if (mintingPaused) {
            revert TermRepoTokenMintingPaused();
        }
        _;
    }

    modifier whileBurningNotPaused() {
        if (burningPaused) {
            revert TermRepoTokenBurningPaused();
        }
        _;
    }

    modifier notTermContractPaired() {
        if (termContractPaired) {
            revert AlreadyTermContractPaired();
        }
        termContractPaired = true;
        _;
    }

    // ========================================================================
    // = Deploy (https://docs.openzeppelin.com/contracts/4.x/upgradeable) =====
    // ========================================================================

    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor() {
        _disableInitializers();
    }

    function initialize(
        string calldata termRepoId_,
        string calldata name_,
        string calldata symbol_,
        uint8 decimalPlaces_,
        uint256 redemptionValue_,
        uint256 mintExposureCap_,
        address termInitializer_,
        TermRepoTokenConfig calldata config_
    ) external initializer {
        ERC20Upgradeable.__ERC20_init(name_, symbol_);
        ERC20PermitUpgradeable.__ERC20Permit_init(name_);
        UUPSUpgradeable.__UUPSUpgradeable_init();
        AccessControlUpgradeable.__AccessControl_init();

        _grantRole(INITIALIZER_ROLE, termInitializer_);

        // slither-disable-start reentrancy-no-eth events-maths
        decimalPlaces = decimalPlaces_;
        redemptionValue = redemptionValue_;
        require(config_.purchaseToken != address(0) && config_.termRepoCollateralManager != address(0) && config_.termRepoServicer != address(0), "zero address in config");
        config = config_;
        // slither-disable-end reentrancy-no-eth events-maths

        termRepoId = keccak256(abi.encodePacked(termRepoId_));

        mintExposureCap = mintExposureCap_;

        mintingPaused = false;

        termContractPaired = false;
    }

    function pairTermContracts(
        address termRepoServicer_,
        ITermEventEmitter emitter_,
        address devopsMultisig_,
        address adminWallet_
    ) external onlyRole(INITIALIZER_ROLE) notTermContractPaired {
        emitter = emitter_;

        _grantRole(ADMIN_ROLE, adminWallet_);
        _grantRole(MINTER_ROLE, termRepoServicer_);
        _grantRole(BURNER_ROLE, termRepoServicer_);
        _grantRole(DEVOPS_ROLE, devopsMultisig_);

        emitter.emitTermRepoTokenInitialized(
            termRepoId,
            address(this),
            redemptionValue
        );
    }

    function resetMintExposureCap(
        uint256 mintExposureCap_
    ) external onlyRole(ADMIN_ROLE) {
        mintExposureCap = mintExposureCap_;
    }

    // ========================================================================
    // = Interface/API ========================================================
    // ========================================================================

    /// @notice Calculates the total USD redemption value of all outstanding TermRepoTokens
    /// @return totalRedemptionValue The total redemption value of TermRepoTokens in USD
    function totalRedemptionValue() external view returns (uint256) {
        uint256 totalValue = truncate(
            mul_(
                Exp({mantissa: totalSupply() * expScale}),
                Exp({mantissa: redemptionValue})
            )
        );
        return totalValue;
    }

    /// @notice Burns TermRepoTokens held by an account
    /// @notice Reverts if caller does not have BURNER_ROLE
    /// @param account The address of account holding TermRepoTokens to burn
    /// @param amount The amount of TermRepoTokens to burn without decimal factor
    function burn(
        address account,
        uint256 amount
    ) external override onlyRole(BURNER_ROLE) whileBurningNotPaused {
        _burn(account, amount);
        mintExposureCap += amount;
    }

    /// @notice Burns TermRepoTokens held by an account and returns purchase redemption value of tokens burned
    /// @notice Reverts if caller does not have BURNER_ROLE
    /// @param account The address of account holding TermRepoTokens to burn
    /// @param amount The amount of TermRepoTokens to burn without decimal factor
    /// @return totalRedemptionValue Total redemption value of TermRepoTokens burned
    function burnAndReturnValue(
        address account,
        uint256 amount
    )
        external
        override
        onlyRole(BURNER_ROLE)
        whileBurningNotPaused
        returns (uint256)
    {
        _burn(account, amount);
        mintExposureCap += amount;
        uint256 valueBurned = truncate(
            mul_(
                Exp({mantissa: amount * expScale}),
                Exp({mantissa: redemptionValue})
            )
        );
        return valueBurned;
    }

    /// @notice Mints TermRepoTokens in an amount equal to caller specified target redemption amount
    /// @notice The redemptionValue is the amount of purchase tokens redeemable per unit of TermRepoToken
    /// @notice Reverts if caller does not have MINTER_ROLE
    /// @param account The address of account to mint TermRepoTokens to
    /// @param redemptionAmount The target redemption amount to mint in TermRepoTokens
    /// @return numTokens The amount of Term Repo Tokens minted
    function mintRedemptionValue(
        address account,
        uint256 redemptionAmount
    )
        external
        override
        whileMintingNotPaused
        onlyRole(MINTER_ROLE)
        returns (uint256)
    {
        uint256 numTokens = truncate(
            div_(
                Exp({mantissa: redemptionAmount * expScale}),
                Exp({mantissa: redemptionValue})
            )
        );
        _mint(account, numTokens);
        return numTokens;
    }

    /// @notice Mints an exact amount of TermRepoTokens
    /// @notice Reverts if caller does not have MINTER_ROLE
    /// @param account The address of account to mint TermRepoTokens to
    /// @param numTokens The exact number of term repo tokens to mint
    function mintTokens(
        address account,
        uint256 numTokens
    )
        external
        override
        whileMintingNotPaused
        onlyRole(MINTER_ROLE)
        returns (uint256)
    {
        _mint(account, numTokens);
        uint256 redemptionValueMinted = truncate(
            mul_(
                Exp({mantissa: numTokens * expScale}),
                Exp({mantissa: redemptionValue})
            )
        );
        return redemptionValueMinted;
    }

    /// @notice Decrements the mintExposureCap
    /// @notice Reverts if caller does not have MINTER_ROLE
    /// @param supplyMinted The number of Tokens Minted
    function decrementMintExposureCap(
        uint256 supplyMinted
    ) external override onlyRole(MINTER_ROLE) {
        if (supplyMinted > mintExposureCap) {
            revert MintExposureCapExceeded();
        }
        mintExposureCap -= supplyMinted;
    }

    /// @return uint8 A uint8 that specifies how many decimal places a token has
    function decimals() public view virtual override returns (uint8) {
        return decimalPlaces;
    }

    /// @return collateralTokens An array of collateral token addresses eligible to serve as collateral backing this repoToken
    /// @return maintenanceRatios An array of maintenance ratios applicable to each collateral token backing this repoToken
    function getCollateralRequirements() external view returns (address[] memory collateralTokens, uint256[] memory maintenanceRatios) {
        ITermRepoCollateralManager collateralManager = ITermRepoCollateralManager(config.termRepoCollateralManager);
        uint256 numOfCollateralTokens = uint256(collateralManager.numOfAcceptedCollateralTokens());
        collateralTokens = new address[](numOfCollateralTokens);
        maintenanceRatios = new uint256[](numOfCollateralTokens);
        for (uint256 i = 0; i < numOfCollateralTokens; ++i){
            collateralTokens[i] = collateralManager.collateralTokens(i);
            maintenanceRatios[i] = collateralManager.maintenanceCollateralRatios(collateralTokens[i]);
        }
    }

    // ========================================================================
    // = Pause Functions ======================================================
    // ========================================================================

    function pauseMinting() external onlyRole(ADMIN_ROLE) {
        mintingPaused = true;
        emitter.emitTermRepoTokenMintingPaused(termRepoId);
    }

    function unpauseMinting() external onlyRole(ADMIN_ROLE) {
        mintingPaused = false;
        emitter.emitTermRepoTokenMintingUnpaused(termRepoId);
    }

    function pauseBurning() external onlyRole(ADMIN_ROLE) {
        burningPaused = true;
        emitter.emitTermRepoTokenBurningPaused(termRepoId);
    }

    function unpauseBurning() external onlyRole(ADMIN_ROLE) {
        burningPaused = false;
        emitter.emitTermRepoTokenBurningUnpaused(termRepoId);
    }

    ///@dev required override by the OpenZeppelin UUPS module
    ///@param impl new impl address for proxy upgrade
    function _authorizeUpgrade(
        address impl
    ) internal override onlyRole(DEVOPS_ROLE) {
        emitter.emitTermContractUpgraded(address(this), impl);
    }
}

{
  "optimizer": {
    "enabled": true,
    "runs": 50
  },
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  },
  "libraries": {}
}

• No Contract Security Audit Submitted- Submit Audit Here

[{"inputs":[{"internalType":"address","name":"initializerApprovalRole_","type":"address"},{"internalType":"address","name":"devopsWallet_","type":"address"}],"stateMutability":"nonpayable","type":"constructor"},{"inputs":[],"name":"DeployingPaused","type":"error"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint8","name":"version","type":"uint8"}],"name":"Initialized","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"bytes32","name":"role","type":"bytes32"},{"indexed":true,"internalType":"bytes32","name":"previousAdminRole","type":"bytes32"},{"indexed":true,"internalType":"bytes32","name":"newAdminRole","type":"bytes32"}],"name":"RoleAdminChanged","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"bytes32","name":"role","type":"bytes32"},{"indexed":true,"internalType":"address","name":"account","type":"address"},{"indexed":true,"internalType":"address","name":"sender","type":"address"}],"name":"RoleGranted","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"bytes32","name":"role","type":"bytes32"},{"indexed":true,"internalType":"address","name":"account","type":"address"},{"indexed":true,"internalType":"address","name":"sender","type":"address"}],"name":"RoleRevoked","type":"event"},{"inputs":[],"name":"DEFAULT_ADMIN_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"DEPLOYER_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"DEVOPS_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"INITIALIZER_APPROVAL_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"bytes32","name":"role","type":"bytes32"}],"name":"getRoleAdmin","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"bytes32","name":"role","type":"bytes32"},{"internalType":"address","name":"account","type":"address"}],"name":"grantRole","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"bytes32","name":"role","type":"bytes32"},{"internalType":"address","name":"account","type":"address"}],"name":"hasRole","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"contract ITermController","name":"controller_","type":"address"},{"internalType":"contract ITermEventEmitter","name":"emitter_","type":"address"},{"internalType":"contract TermPriceConsumerV3","name":"priceOracle_","type":"address"}],"name":"pairTermContracts","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"pauseDeploying","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"bytes32","name":"role","type":"bytes32"},{"internalType":"address","name":"account","type":"address"}],"name":"renounceRole","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"bytes32","name":"role","type":"bytes32"},{"internalType":"address","name":"account","type":"address"}],"name":"revokeRole","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"contract TermRepoServicer","name":"termRepoServicer","type":"address"},{"internalType":"contract TermRepoCollateralManager","name":"termRepoCollateralManager","type":"address"},{"internalType":"contract TermAuctionOfferLocker","name":"termAuctionOfferLocker","type":"address"},{"internalType":"contract TermAuctionBidLocker","name":"termAuctionBidLocker","type":"address"},{"internalType":"contract TermAuction","name":"auction","type":"address"},{"internalType":"address","name":"devOpsMultiSig","type":"address"},{"internalType":"address","name":"adminWallet","type":"address"},{"internalType":"string","name":"auctionVersion","type":"string"}],"name":"setupAuction","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"components":[{"internalType":"contract TermRepoLocker","name":"termRepoLocker","type":"address"},{"internalType":"contract TermRepoServicer","name":"termRepoServicer","type":"address"},{"internalType":"contract TermRepoCollateralManager","name":"termRepoCollateralManager","type":"address"},{"internalType":"contract TermRepoRolloverManager","name":"rolloverManager","type":"address"},{"internalType":"contract TermRepoToken","name":"termRepoToken","type":"address"},{"internalType":"contract TermAuctionOfferLocker","name":"termAuctionOfferLocker","type":"address"},{"internalType":"contract TermAuctionBidLocker","name":"termAuctionBidLocker","type":"address"},{"internalType":"contract TermAuction","name":"auction","type":"address"}],"internalType":"struct TermContractGroup","name":"termContractGroup","type":"tuple"},{"internalType":"address","name":"devOpsMultiSig","type":"address"},{"internalType":"address","name":"adminWallet","type":"address"},{"internalType":"string","name":"termVersion","type":"string"},{"internalType":"string","name":"auctionVersion","type":"string"}],"name":"setupTerm","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"bytes4","name":"interfaceId","type":"bytes4"}],"name":"supportsInterface","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"unpauseDeploying","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"version","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"}]

60806040523480156200001157600080fd5b5060405162002b2738038062002b2783398101604081905262000034916200018f565b620000607f793a6c9b7e0a9549c74edc2f9ae0dc50903dfaa9a56fb0116b27a8c71de3e2c682620000cd565b6200008c7f6ed99f2da23f40576cbf78aa7c8ca667edae2da83ffc25cda14b3818f7b0d08483620000cd565b620000b87ffc425f2263d0df187444b70e47283d622c70181c5baebb1306a01edba1ce184c33620000cd565b50506099805460ff60a01b19169055620001c7565b60008281526065602090815260408083206001600160a01b038516845290915290205460ff166200016e5760008281526065602090815260408083206001600160a01b03851684529091529020805460ff191660011790556200012d3390565b6001600160a01b0316816001600160a01b0316837f2f8788117e7eff1d82e926ec794901d17c78024a50270940304540a733656f0d60405160405180910390a45b5050565b80516001600160a01b03811681146200018a57600080fd5b919050565b60008060408385031215620001a357600080fd5b620001ae8362000172565b9150620001be6020840162000172565b90509250929050565b61295080620001d76000396000f3fe608060405234801561001057600080fd5b50600436106100e05760003560e01c806391d148541161008757806391d14854146101c8578063a217fddf146101db578063acdaa72b146101e3578063ad1083f5146101f6578063d547741f1461020b578063e7bd30be1461021e578063ecd0026114610226578063f734b1351461024d57600080fd5b806301ffc9a7146100e5578063159cce5f1461010d578063201a662514610122578063248a9ca3146101455780632f2ff15d1461016857806336568abe1461017b57806354fd4d501461018e57806374d425f7146101b5575b600080fd5b6100f86100f33660046120ae565b610255565b60405190151581526020015b60405180910390f35b61012061011b3660046120ed565b61028c565b005b6101376000805160206128db83398151915281565b604051908152602001610104565b610137610153366004612138565b60009081526065602052604090206001015490565b610120610176366004612151565b6102f6565b610120610189366004612151565b610320565b60408051808201825260058152640302e392e360dc1b6020820152905161010491906121d1565b6101206101c3366004612286565b6103a3565b6100f86101d6366004612151565b61158e565b610137600081565b6101206101f136600461232c565b6115b9565b6101376000805160206128fb83398151915281565b610120610219366004612151565b611d2c565b610120611d51565b6101377ffc425f2263d0df187444b70e47283d622c70181c5baebb1306a01edba1ce184c81565b610120611d79565b60006001600160e01b03198216637965db0b60e01b148061028657506301ffc9a760e01b6001600160e01b03198316145b92915050565b7ffc425f2263d0df187444b70e47283d622c70181c5baebb1306a01edba1ce184c6102b681611da7565b50609780546001600160a01b039485166001600160a01b031991821617909155609880549385169382169390931790925560998054919093169116179055565b60008281526065602052604090206001015461031181611da7565b61031b8383611db4565b505050565b6001600160a01b03811633146103955760405162461bcd60e51b815260206004820152602f60248201527f416363657373436f6e74726f6c3a2063616e206f6e6c792072656e6f756e636560448201526e103937b632b9903337b91039b2b63360891b60648201526084015b60405180910390fd5b61039f8282611e3a565b5050565b6000805160206128fb8339815191526103bb81611da7565b609954600160a01b900460ff16156103e657604051633b335e4560e11b815260040160405180910390fd5b6097546001600160a01b031663e7e4b8db6104076040890160208a01612420565b6040518263ffffffff1660e01b8152600401610423919061243d565b602060405180830381865afa158015610440573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906104649190612451565b6104805760405162461bcd60e51b815260040161038c90612473565b6097546001600160a01b031663e7e4b8db6104a16060890160408a01612420565b6040518263ffffffff1660e01b81526004016104bd919061243d565b602060405180830381865afa1580156104da573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906104fe9190612451565b61051a5760405162461bcd60e51b815260040161038c90612499565b6097546001600160a01b031663e7e4b8db6105386020890189612420565b6040518263ffffffff1660e01b8152600401610554919061243d565b602060405180830381865afa158015610571573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906105959190612451565b6105d05760405162461bcd60e51b815260206004820152600c60248201526b139bdb8b55195c9b4815149360a21b604482015260640161038c565b6097546001600160a01b031663e7e4b8db6105f160a0890160808a01612420565b6040518263ffffffff1660e01b815260040161060d919061243d565b602060405180830381865afa15801561062a573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061064e9190612451565b6106895760405162461bcd60e51b815260206004820152600c60248201526b139bdb8b55195c9b4815149560a21b604482015260640161038c565b6097546001600160a01b031663e7e4b8db6106aa6080890160608a01612420565b6040518263ffffffff1660e01b81526004016106c6919061243d565b602060405180830381865afa1580156106e3573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906107079190612451565b6107425760405162461bcd60e51b815260206004820152600c60248201526b4e6f6e2d5465726d2054524d60a01b604482015260640161038c565b6097546001600160a01b031663e7e4b8db61076360e0890160c08a01612420565b6040518263ffffffff1660e01b815260040161077f919061243d565b602060405180830381865afa15801561079c573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906107c09190612451565b6107dc5760405162461bcd60e51b815260040161038c906124c0565b6097546001600160a01b031663e7e4b8db6107fd60c0890160a08a01612420565b6040518263ffffffff1660e01b8152600401610819919061243d565b602060405180830381865afa158015610836573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061085a9190612451565b6108765760405162461bcd60e51b815260040161038c906124e7565b6097546001600160a01b031663e7e4b8db610898610100890160e08a01612420565b6040518263ffffffff1660e01b81526004016108b4919061243d565b602060405180830381865afa1580156108d1573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906108f59190612451565b6109115760405162461bcd60e51b815260040161038c9061250e565b60006109236040880160208901612420565b6001600160a01b0316036109715760405162461bcd60e51b81526020600482015260156024820152742d32b9379020b2323932b9b99029b2b93b34b1b2b960591b604482015260640161038c565b60006109836060880160408901612420565b6001600160a01b0316036109d95760405162461bcd60e51b815260206004820152601f60248201527f5a65726f204164647265737320436f6c6c61746572616c204d616e6167657200604482015260640161038c565b60006109e86020880188612420565b6001600160a01b031603610a345760405162461bcd60e51b81526020600482015260136024820152722d32b9379020b2323932b9b9902637b1b5b2b960691b604482015260640161038c565b6000610a4660a0880160808901612420565b6001600160a01b031603610a955760405162461bcd60e51b81526020600482015260166024820152752d32b9379020b2323932b9b9902932b837aa37b5b2b760511b604482015260640161038c565b6000610aa76080880160608901612420565b6001600160a01b031603610afd5760405162461bcd60e51b815260206004820152601c60248201527f5a65726f204164647265737320526f6c6c6f7665724d616e6167657200000000604482015260640161038c565b6000610b0f60e0880160c08901612420565b6001600160a01b031603610b355760405162461bcd60e51b815260040161038c90612533565b6000610b4760c0880160a08901612420565b6001600160a01b031603610b6d5760405162461bcd60e51b815260040161038c90612574565b6000610b80610100880160e08901612420565b6001600160a01b031603610ba65760405162461bcd60e51b815260040161038c906125b7565b6098546001600160a01b031663ee407388610bc46020890189612420565b6040518263ffffffff1660e01b8152600401610be0919061243d565b600060405180830381600087803b158015610bfa57600080fd5b505af1158015610c0e573d6000803e3d6000fd5b50506097546001600160a01b03169150632ce810749050610c36610100890160e08a01612420565b6040518263ffffffff1660e01b8152600401610c52919061243d565b600060405180830381600087803b158015610c6c57600080fd5b505af1158015610c80573d6000803e3d6000fd5b50610c92925050506020870187612420565b6001600160a01b0316637910b464610cb06060890160408a01612420565b610cc060408a0160208b01612420565b6098546040516001600160e01b031960e086901b168152610cf39392916001600160a01b0316908b908b906004016125e5565b600060405180830381600087803b158015610d0d57600080fd5b505af1158015610d21573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee4073889050610d4860a0890160808a01612420565b6040518263ffffffff1660e01b8152600401610d64919061243d565b600060405180830381600087803b158015610d7e57600080fd5b505af1158015610d92573d6000803e3d6000fd5b50610da79250505060a0870160808801612420565b6001600160a01b031663a8f421c2610dc56040890160208a01612420565b6098546040516001600160e01b031960e085901b168152610df792916001600160a01b0316908a908a90600401612617565b600060405180830381600087803b158015610e1157600080fd5b505af1158015610e25573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee4073889050610e4c60e0890160c08a01612420565b6040518263ffffffff1660e01b8152600401610e68919061243d565b600060405180830381600087803b158015610e8257600080fd5b505af1158015610e96573d6000803e3d6000fd5b50610eab9250505060e0870160c08801612420565b6001600160a01b031663cdae1ee0610eca610100890160e08a01612420565b610eda60408a0160208b01612420565b6098546001600160a01b0316610ef660608c0160408d01612420565b6099546040516001600160e01b031960e088901b168152610f2b95949392916001600160a01b0316908d908d90600401612642565b600060405180830381600087803b158015610f4557600080fd5b505af1158015610f59573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee4073889050610f8060c0890160a08a01612420565b6040518263ffffffff1660e01b8152600401610f9c919061243d565b600060405180830381600087803b158015610fb657600080fd5b505af1158015610fca573d6000803e3d6000fd5b50610fdf9250505060c0870160a08801612420565b6001600160a01b0316637910b464610ffe610100890160e08a01612420565b6098546001600160a01b031661101a60408b0160208c01612420565b89896040518663ffffffff1660e01b815260040161103c9594939291906125e5565b600060405180830381600087803b15801561105657600080fd5b505af115801561106a573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee4073889050611092610100890160e08a01612420565b6040518263ffffffff1660e01b81526004016110ae919061243d565b600060405180830381600087803b1580156110c857600080fd5b505af11580156110dc573d6000803e3d6000fd5b506110f292505050610100870160e08801612420565b6098546097546001600160a01b039283169263e8c856f1928116911661111e60408b0160208c01612420565b61112e60e08c0160c08d01612420565b61113e60c08d0160a08e01612420565b8b8b8a6040518963ffffffff1660e01b8152600401611164989796959493929190612683565b600060405180830381600087803b15801561117e57600080fd5b505af1158015611192573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee40738890506111b96040890160208a01612420565b6040518263ffffffff1660e01b81526004016111d5919061243d565b600060405180830381600087803b1580156111ef57600080fd5b505af1158015611203573d6000803e3d6000fd5b50611218925050506040870160208801612420565b6001600160a01b031663321532206112336020890189612420565b61124360608a0160408b01612420565b61125360a08b0160808c01612420565b61126360c08c0160a08d01612420565b6112746101008d0160e08e01612420565b61128460808e0160608f01612420565b8c8c8c6040518a63ffffffff1660e01b81526004016112ab999897969594939291906126e7565b600060405180830381600087803b1580156112c557600080fd5b505af11580156112d9573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee40738890506113006060890160408a01612420565b6040518263ffffffff1660e01b815260040161131c919061243d565b600060405180830381600087803b15801561133657600080fd5b505af115801561134a573d6000803e3d6000fd5b5061135f925050506060870160408801612420565b6001600160a01b03166316febdd361137a6020890189612420565b61138a60408a0160208b01612420565b61139a60e08b0160c08c01612420565b6113ab6101008c0160e08d01612420565b609760009054906101000a90046001600160a01b0316609960009054906101000a90046001600160a01b03168d60600160208101906113ea9190612420565b6040516001600160e01b031960e08a901b1681526001600160a01b03978816600482015295871660248701529386166044860152918516606485015284166084840152831660a4830152821660c482015281891660e482015290871661010482015261012401600060405180830381600087803b15801561146a57600080fd5b505af115801561147e573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee40738890506114a56080890160608a01612420565b6040518263ffffffff1660e01b81526004016114c1919061243d565b600060405180830381600087803b1580156114db57600080fd5b505af11580156114ef573d6000803e3d6000fd5b50611504925050506080870160608801612420565b6001600160a01b031663a8f421c26115226040890160208a01612420565b6098546040516001600160e01b031960e085901b16815261155492916001600160a01b0316908a908a90600401612617565b600060405180830381600087803b15801561156e57600080fd5b505af1158015611582573d6000803e3d6000fd5b50505050505050505050565b60009182526065602090815260408084206001600160a01b0393909316845291905290205460ff1690565b6000805160206128fb8339815191526115d181611da7565b609954600160a01b900460ff16156115fc57604051633b335e4560e11b815260040160405180910390fd5b60975460405163e7e4b8db60e01b81526001600160a01b039091169063e7e4b8db9061162c908d9060040161243d565b602060405180830381865afa158015611649573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061166d9190612451565b6116895760405162461bcd60e51b815260040161038c90612473565b60975460405163e7e4b8db60e01b81526001600160a01b039091169063e7e4b8db906116b9908c9060040161243d565b602060405180830381865afa1580156116d6573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906116fa9190612451565b6117165760405162461bcd60e51b815260040161038c90612499565b60975460405163e7e4b8db60e01b81526001600160a01b039091169063e7e4b8db90611746908a9060040161243d565b602060405180830381865afa158015611763573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906117879190612451565b6117a35760405162461bcd60e51b815260040161038c906124c0565b60975460405163e7e4b8db60e01b81526001600160a01b039091169063e7e4b8db906117d3908b9060040161243d565b602060405180830381865afa1580156117f0573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906118149190612451565b6118305760405162461bcd60e51b815260040161038c906124e7565b60975460405163e7e4b8db60e01b81526001600160a01b039091169063e7e4b8db9061186090899060040161243d565b602060405180830381865afa15801561187d573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906118a19190612451565b6118bd5760405162461bcd60e51b815260040161038c9061250e565b6001600160a01b0387166118e35760405162461bcd60e51b815260040161038c90612533565b6001600160a01b0388166119095760405162461bcd60e51b815260040161038c90612574565b6001600160a01b03861661192f5760405162461bcd60e51b815260040161038c906125b7565b609754604051630b3a041d60e21b81526001600160a01b0390911690632ce810749061195f90899060040161243d565b600060405180830381600087803b15801561197957600080fd5b505af115801561198d573d6000803e3d6000fd5b5050609854604051631dc80e7160e31b81526001600160a01b03909116925063ee40738891506119c1908a9060040161243d565b600060405180830381600087803b1580156119db57600080fd5b505af11580156119ef573d6000803e3d6000fd5b50505050866001600160a01b031663cdae1ee0878c609860009054906101000a90046001600160a01b03168d609960009054906101000a90046001600160a01b03168b8b6040518863ffffffff1660e01b8152600401611a559796959493929190612642565b600060405180830381600087803b158015611a6f57600080fd5b505af1158015611a83573d6000803e3d6000fd5b5050609854604051631dc80e7160e31b81526001600160a01b03909116925063ee4073889150611ab7908b9060040161243d565b600060405180830381600087803b158015611ad157600080fd5b505af1158015611ae5573d6000803e3d6000fd5b5050609854604051631e442d1960e21b81526001600160a01b03808d169450637910b4649350611b22928b929116908f908b908b906004016125e5565b600060405180830381600087803b158015611b3c57600080fd5b505af1158015611b50573d6000803e3d6000fd5b5050609854604051631dc80e7160e31b81526001600160a01b03909116925063ee4073889150611b8490899060040161243d565b600060405180830381600087803b158015611b9e57600080fd5b505af1158015611bb2573d6000803e3d6000fd5b505060985460975460405163e8c856f160e01b81526001600160a01b03808c16955063e8c856f19450611bfa9381169216908f908d908f908d908d908d908d90600401612755565b600060405180830381600087803b158015611c1457600080fd5b505af1158015611c28573d6000803e3d6000fd5b5050604080516060810182526001600160a01b038a811682528b811660208301528c811682840152915163202a804560e11b8152918d169350634055008a9250611c74916004016127cf565b600060405180830381600087803b158015611c8e57600080fd5b505af1158015611ca2573d6000803e3d6000fd5b5050604080516060810182526001600160a01b038a811682528b811660208301528c811682840152915163202a804560e11b8152918e169350634055008a9250611cee916004016127cf565b600060405180830381600087803b158015611d0857600080fd5b505af1158015611d1c573d6000803e3d6000fd5b5050505050505050505050505050565b600082815260656020526040902060010154611d4781611da7565b61031b8383611e3a565b6000805160206128db833981519152611d6981611da7565b506099805460ff60a01b19169055565b6000805160206128db833981519152611d9181611da7565b506099805460ff60a01b1916600160a01b179055565b611db18133611ea1565b50565b611dbe828261158e565b61039f5760008281526065602090815260408083206001600160a01b03851684529091529020805460ff19166001179055611df63390565b6001600160a01b0316816001600160a01b0316837f2f8788117e7eff1d82e926ec794901d17c78024a50270940304540a733656f0d60405160405180910390a45050565b611e44828261158e565b1561039f5760008281526065602090815260408083206001600160a01b0385168085529252808320805460ff1916905551339285917ff6391f5c32d9c69d2a47ea670b442974b53935d1edc7fd64eb21e047a839171b9190a45050565b611eab828261158e565b61039f57611eb881611efa565b611ec3836020611f0c565b604051602001611ed49291906127fe565b60408051601f198184030181529082905262461bcd60e51b825261038c916004016121d1565b60606102866001600160a01b03831660145b60606000611f1b836002612883565b611f2690600261289a565b6001600160401b03811115611f3d57611f3d6121e4565b6040519080825280601f01601f191660200182016040528015611f67576020820181803683370190505b509050600360fc1b81600081518110611f8257611f826128ad565b60200101906001600160f81b031916908160001a905350600f60fb1b81600181518110611fb157611fb16128ad565b60200101906001600160f81b031916908160001a9053506000611fd5846002612883565b611fe090600161289a565b90505b6001811115612058576f181899199a1a9b1b9c1cb0b131b232b360811b85600f1660108110612014576120146128ad565b1a60f81b82828151811061202a5761202a6128ad565b60200101906001600160f81b031916908160001a90535060049490941c93612051816128c3565b9050611fe3565b5083156120a75760405162461bcd60e51b815260206004820181905260248201527f537472696e67733a20686578206c656e67746820696e73756666696369656e74604482015260640161038c565b9392505050565b6000602082840312156120c057600080fd5b81356001600160e01b0319811681146120a757600080fd5b6001600160a01b0381168114611db157600080fd5b60008060006060848603121561210257600080fd5b833561210d816120d8565b9250602084013561211d816120d8565b9150604084013561212d816120d8565b809150509250925092565b60006020828403121561214a57600080fd5b5035919050565b6000806040838503121561216457600080fd5b823591506020830135612176816120d8565b809150509250929050565b60005b8381101561219c578181015183820152602001612184565b50506000910152565b600081518084526121bd816020860160208601612181565b601f01601f19169290920160200192915050565b6020815260006120a760208301846121a5565b634e487b7160e01b600052604160045260246000fd5b600082601f83011261220b57600080fd5b81356001600160401b0380821115612225576122256121e4565b604051601f8301601f19908116603f0116810190828211818310171561224d5761224d6121e4565b8160405283815286602085880101111561226657600080fd5b836020870160208301376000602085830101528094505050505092915050565b60008060008060008587036101808112156122a057600080fd5b610100808212156122b057600080fd5b87965086013590506122c1816120d8565b93506101208601356122d2816120d8565b92506101408601356001600160401b03808211156122ef57600080fd5b6122fb89838a016121fa565b935061016088013591508082111561231257600080fd5b5061231f888289016121fa565b9150509295509295909350565b60008060008060008060008060006101008a8c03121561234b57600080fd5b8935612356816120d8565b985060208a0135612366816120d8565b975060408a0135612376816120d8565b965060608a0135612386816120d8565b955060808a0135612396816120d8565b945060a08a01356123a6816120d8565b935060c08a01356123b6816120d8565b925060e08a01356001600160401b03808211156123d257600080fd5b818c0191508c601f8301126123e657600080fd5b8135818111156123f557600080fd5b8d602082850101111561240757600080fd5b6020830194508093505050509295985092959850929598565b60006020828403121561243257600080fd5b81356120a7816120d8565b6001600160a01b0391909116815260200190565b60006020828403121561246357600080fd5b815180151581146120a757600080fd5b6020808252600c908201526b4e6f6e2d5465726d2054525360a01b604082015260600190565b6020808252600d908201526c4e6f6e2d5465726d205452434d60981b604082015260600190565b6020808252600d908201526c139bdb8b55195c9b4815105093609a1b604082015260600190565b6020808252600d908201526c139bdb8b55195c9b48151053d3609a1b604082015260600190565b6020808252600b908201526a4e6f6e2d5465726d20544160a81b604082015260600190565b60208082526021908201527f5a65726f2041646472657373207465726d41756374696f6e4269644c6f636b656040820152603960f91b606082015260800190565b60208082526023908201527f5a65726f2041646472657373207465726d41756374696f6e4f666665724c6f6360408201526235b2b960e91b606082015260800190565b6020808252601490820152732d32b9379020b2323932b9b99030bab1ba34b7b760611b604082015260600190565b6001600160a01b0395861681529385166020850152918416604084015283166060830152909116608082015260a00190565b6001600160a01b03948516815292841660208401529083166040830152909116606082015260800190565b6001600160a01b03978816815295871660208701529386166040860152918516606085015284166080840152831660a083015290911660c082015260e00190565b6001600160a01b038981168252888116602083015287811660408301528681166060830152858116608083015284811660a0830152831660c082015261010060e082018190526000906126d8838201856121a5565b9b9a5050505050505050505050565b6001600160a01b038a81168252898116602083015288811660408301528781166060830152868116608083015285811660a083015284811660c0830152831660e08201526101206101008201819052600090612745838201856121a5565b9c9b505050505050505050505050565b6001600160a01b038a81168252898116602083015288811660408301528781166060830152868116608083015285811660a0830152841660c082015261010060e08201819052810182905260006101208385828501376000838501820152601f909301601f19169091019091019998505050505050505050565b81516001600160a01b039081168252602080840151821690830152604092830151169181019190915260600190565b76020b1b1b2b9b9a1b7b73a3937b61d1030b1b1b7bab73a1604d1b815260008351612830816017850160208801612181565b7001034b99036b4b9b9b4b733903937b6329607d1b6017918401918201528351612861816028840160208801612181565b01602801949350505050565b634e487b7160e01b600052601160045260246000fd5b80820281158282048414176102865761028661286d565b808201808211156102865761028661286d565b634e487b7160e01b600052603260045260246000fd5b6000816128d2576128d261286d565b50600019019056fe793a6c9b7e0a9549c74edc2f9ae0dc50903dfaa9a56fb0116b27a8c71de3e2c66ed99f2da23f40576cbf78aa7c8ca667edae2da83ffc25cda14b3818f7b0d084a2646970667358221220028fadbc237a0b74e866e87c1d7aef59087ce23e5b6d0ec19acc5fd4c9154f5d64736f6c63430008120033000000000000000000000000d03a6771b64e9a759523af3a89fc982b2dd38591000000000000000000000000b8a1df43c1c88b13937c0c5cebbad15830caec03

0x608060405234801561001057600080fd5b50600436106100e05760003560e01c806391d148541161008757806391d14854146101c8578063a217fddf146101db578063acdaa72b146101e3578063ad1083f5146101f6578063d547741f1461020b578063e7bd30be1461021e578063ecd0026114610226578063f734b1351461024d57600080fd5b806301ffc9a7146100e5578063159cce5f1461010d578063201a662514610122578063248a9ca3146101455780632f2ff15d1461016857806336568abe1461017b57806354fd4d501461018e57806374d425f7146101b5575b600080fd5b6100f86100f33660046120ae565b610255565b60405190151581526020015b60405180910390f35b61012061011b3660046120ed565b61028c565b005b6101376000805160206128db83398151915281565b604051908152602001610104565b610137610153366004612138565b60009081526065602052604090206001015490565b610120610176366004612151565b6102f6565b610120610189366004612151565b610320565b60408051808201825260058152640302e392e360dc1b6020820152905161010491906121d1565b6101206101c3366004612286565b6103a3565b6100f86101d6366004612151565b61158e565b610137600081565b6101206101f136600461232c565b6115b9565b6101376000805160206128fb83398151915281565b610120610219366004612151565b611d2c565b610120611d51565b6101377ffc425f2263d0df187444b70e47283d622c70181c5baebb1306a01edba1ce184c81565b610120611d79565b60006001600160e01b03198216637965db0b60e01b148061028657506301ffc9a760e01b6001600160e01b03198316145b92915050565b7ffc425f2263d0df187444b70e47283d622c70181c5baebb1306a01edba1ce184c6102b681611da7565b50609780546001600160a01b039485166001600160a01b031991821617909155609880549385169382169390931790925560998054919093169116179055565b60008281526065602052604090206001015461031181611da7565b61031b8383611db4565b505050565b6001600160a01b03811633146103955760405162461bcd60e51b815260206004820152602f60248201527f416363657373436f6e74726f6c3a2063616e206f6e6c792072656e6f756e636560448201526e103937b632b9903337b91039b2b63360891b60648201526084015b60405180910390fd5b61039f8282611e3a565b5050565b6000805160206128fb8339815191526103bb81611da7565b609954600160a01b900460ff16156103e657604051633b335e4560e11b815260040160405180910390fd5b6097546001600160a01b031663e7e4b8db6104076040890160208a01612420565b6040518263ffffffff1660e01b8152600401610423919061243d565b602060405180830381865afa158015610440573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906104649190612451565b6104805760405162461bcd60e51b815260040161038c90612473565b6097546001600160a01b031663e7e4b8db6104a16060890160408a01612420565b6040518263ffffffff1660e01b81526004016104bd919061243d565b602060405180830381865afa1580156104da573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906104fe9190612451565b61051a5760405162461bcd60e51b815260040161038c90612499565b6097546001600160a01b031663e7e4b8db6105386020890189612420565b6040518263ffffffff1660e01b8152600401610554919061243d565b602060405180830381865afa158015610571573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906105959190612451565b6105d05760405162461bcd60e51b815260206004820152600c60248201526b139bdb8b55195c9b4815149360a21b604482015260640161038c565b6097546001600160a01b031663e7e4b8db6105f160a0890160808a01612420565b6040518263ffffffff1660e01b815260040161060d919061243d565b602060405180830381865afa15801561062a573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061064e9190612451565b6106895760405162461bcd60e51b815260206004820152600c60248201526b139bdb8b55195c9b4815149560a21b604482015260640161038c565b6097546001600160a01b031663e7e4b8db6106aa6080890160608a01612420565b6040518263ffffffff1660e01b81526004016106c6919061243d565b602060405180830381865afa1580156106e3573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906107079190612451565b6107425760405162461bcd60e51b815260206004820152600c60248201526b4e6f6e2d5465726d2054524d60a01b604482015260640161038c565b6097546001600160a01b031663e7e4b8db61076360e0890160c08a01612420565b6040518263ffffffff1660e01b815260040161077f919061243d565b602060405180830381865afa15801561079c573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906107c09190612451565b6107dc5760405162461bcd60e51b815260040161038c906124c0565b6097546001600160a01b031663e7e4b8db6107fd60c0890160a08a01612420565b6040518263ffffffff1660e01b8152600401610819919061243d565b602060405180830381865afa158015610836573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061085a9190612451565b6108765760405162461bcd60e51b815260040161038c906124e7565b6097546001600160a01b031663e7e4b8db610898610100890160e08a01612420565b6040518263ffffffff1660e01b81526004016108b4919061243d565b602060405180830381865afa1580156108d1573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906108f59190612451565b6109115760405162461bcd60e51b815260040161038c9061250e565b60006109236040880160208901612420565b6001600160a01b0316036109715760405162461bcd60e51b81526020600482015260156024820152742d32b9379020b2323932b9b99029b2b93b34b1b2b960591b604482015260640161038c565b60006109836060880160408901612420565b6001600160a01b0316036109d95760405162461bcd60e51b815260206004820152601f60248201527f5a65726f204164647265737320436f6c6c61746572616c204d616e6167657200604482015260640161038c565b60006109e86020880188612420565b6001600160a01b031603610a345760405162461bcd60e51b81526020600482015260136024820152722d32b9379020b2323932b9b9902637b1b5b2b960691b604482015260640161038c565b6000610a4660a0880160808901612420565b6001600160a01b031603610a955760405162461bcd60e51b81526020600482015260166024820152752d32b9379020b2323932b9b9902932b837aa37b5b2b760511b604482015260640161038c565b6000610aa76080880160608901612420565b6001600160a01b031603610afd5760405162461bcd60e51b815260206004820152601c60248201527f5a65726f204164647265737320526f6c6c6f7665724d616e6167657200000000604482015260640161038c565b6000610b0f60e0880160c08901612420565b6001600160a01b031603610b355760405162461bcd60e51b815260040161038c90612533565b6000610b4760c0880160a08901612420565b6001600160a01b031603610b6d5760405162461bcd60e51b815260040161038c90612574565b6000610b80610100880160e08901612420565b6001600160a01b031603610ba65760405162461bcd60e51b815260040161038c906125b7565b6098546001600160a01b031663ee407388610bc46020890189612420565b6040518263ffffffff1660e01b8152600401610be0919061243d565b600060405180830381600087803b158015610bfa57600080fd5b505af1158015610c0e573d6000803e3d6000fd5b50506097546001600160a01b03169150632ce810749050610c36610100890160e08a01612420565b6040518263ffffffff1660e01b8152600401610c52919061243d565b600060405180830381600087803b158015610c6c57600080fd5b505af1158015610c80573d6000803e3d6000fd5b50610c92925050506020870187612420565b6001600160a01b0316637910b464610cb06060890160408a01612420565b610cc060408a0160208b01612420565b6098546040516001600160e01b031960e086901b168152610cf39392916001600160a01b0316908b908b906004016125e5565b600060405180830381600087803b158015610d0d57600080fd5b505af1158015610d21573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee4073889050610d4860a0890160808a01612420565b6040518263ffffffff1660e01b8152600401610d64919061243d565b600060405180830381600087803b158015610d7e57600080fd5b505af1158015610d92573d6000803e3d6000fd5b50610da79250505060a0870160808801612420565b6001600160a01b031663a8f421c2610dc56040890160208a01612420565b6098546040516001600160e01b031960e085901b168152610df792916001600160a01b0316908a908a90600401612617565b600060405180830381600087803b158015610e1157600080fd5b505af1158015610e25573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee4073889050610e4c60e0890160c08a01612420565b6040518263ffffffff1660e01b8152600401610e68919061243d565b600060405180830381600087803b158015610e8257600080fd5b505af1158015610e96573d6000803e3d6000fd5b50610eab9250505060e0870160c08801612420565b6001600160a01b031663cdae1ee0610eca610100890160e08a01612420565b610eda60408a0160208b01612420565b6098546001600160a01b0316610ef660608c0160408d01612420565b6099546040516001600160e01b031960e088901b168152610f2b95949392916001600160a01b0316908d908d90600401612642565b600060405180830381600087803b158015610f4557600080fd5b505af1158015610f59573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee4073889050610f8060c0890160a08a01612420565b6040518263ffffffff1660e01b8152600401610f9c919061243d565b600060405180830381600087803b158015610fb657600080fd5b505af1158015610fca573d6000803e3d6000fd5b50610fdf9250505060c0870160a08801612420565b6001600160a01b0316637910b464610ffe610100890160e08a01612420565b6098546001600160a01b031661101a60408b0160208c01612420565b89896040518663ffffffff1660e01b815260040161103c9594939291906125e5565b600060405180830381600087803b15801561105657600080fd5b505af115801561106a573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee4073889050611092610100890160e08a01612420565b6040518263ffffffff1660e01b81526004016110ae919061243d565b600060405180830381600087803b1580156110c857600080fd5b505af11580156110dc573d6000803e3d6000fd5b506110f292505050610100870160e08801612420565b6098546097546001600160a01b039283169263e8c856f1928116911661111e60408b0160208c01612420565b61112e60e08c0160c08d01612420565b61113e60c08d0160a08e01612420565b8b8b8a6040518963ffffffff1660e01b8152600401611164989796959493929190612683565b600060405180830381600087803b15801561117e57600080fd5b505af1158015611192573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee40738890506111b96040890160208a01612420565b6040518263ffffffff1660e01b81526004016111d5919061243d565b600060405180830381600087803b1580156111ef57600080fd5b505af1158015611203573d6000803e3d6000fd5b50611218925050506040870160208801612420565b6001600160a01b031663321532206112336020890189612420565b61124360608a0160408b01612420565b61125360a08b0160808c01612420565b61126360c08c0160a08d01612420565b6112746101008d0160e08e01612420565b61128460808e0160608f01612420565b8c8c8c6040518a63ffffffff1660e01b81526004016112ab999897969594939291906126e7565b600060405180830381600087803b1580156112c557600080fd5b505af11580156112d9573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee40738890506113006060890160408a01612420565b6040518263ffffffff1660e01b815260040161131c919061243d565b600060405180830381600087803b15801561133657600080fd5b505af115801561134a573d6000803e3d6000fd5b5061135f925050506060870160408801612420565b6001600160a01b03166316febdd361137a6020890189612420565b61138a60408a0160208b01612420565b61139a60e08b0160c08c01612420565b6113ab6101008c0160e08d01612420565b609760009054906101000a90046001600160a01b0316609960009054906101000a90046001600160a01b03168d60600160208101906113ea9190612420565b6040516001600160e01b031960e08a901b1681526001600160a01b03978816600482015295871660248701529386166044860152918516606485015284166084840152831660a4830152821660c482015281891660e482015290871661010482015261012401600060405180830381600087803b15801561146a57600080fd5b505af115801561147e573d6000803e3d6000fd5b50506098546001600160a01b0316915063ee40738890506114a56080890160608a01612420565b6040518263ffffffff1660e01b81526004016114c1919061243d565b600060405180830381600087803b1580156114db57600080fd5b505af11580156114ef573d6000803e3d6000fd5b50611504925050506080870160608801612420565b6001600160a01b031663a8f421c26115226040890160208a01612420565b6098546040516001600160e01b031960e085901b16815261155492916001600160a01b0316908a908a90600401612617565b600060405180830381600087803b15801561156e57600080fd5b505af1158015611582573d6000803e3d6000fd5b50505050505050505050565b60009182526065602090815260408084206001600160a01b0393909316845291905290205460ff1690565b6000805160206128fb8339815191526115d181611da7565b609954600160a01b900460ff16156115fc57604051633b335e4560e11b815260040160405180910390fd5b60975460405163e7e4b8db60e01b81526001600160a01b039091169063e7e4b8db9061162c908d9060040161243d565b602060405180830381865afa158015611649573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061166d9190612451565b6116895760405162461bcd60e51b815260040161038c90612473565b60975460405163e7e4b8db60e01b81526001600160a01b039091169063e7e4b8db906116b9908c9060040161243d565b602060405180830381865afa1580156116d6573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906116fa9190612451565b6117165760405162461bcd60e51b815260040161038c90612499565b60975460405163e7e4b8db60e01b81526001600160a01b039091169063e7e4b8db90611746908a9060040161243d565b602060405180830381865afa158015611763573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906117879190612451565b6117a35760405162461bcd60e51b815260040161038c906124c0565b60975460405163e7e4b8db60e01b81526001600160a01b039091169063e7e4b8db906117d3908b9060040161243d565b602060405180830381865afa1580156117f0573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906118149190612451565b6118305760405162461bcd60e51b815260040161038c906124e7565b60975460405163e7e4b8db60e01b81526001600160a01b039091169063e7e4b8db9061186090899060040161243d565b602060405180830381865afa15801561187d573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906118a19190612451565b6118bd5760405162461bcd60e51b815260040161038c9061250e565b6001600160a01b0387166118e35760405162461bcd60e51b815260040161038c90612533565b6001600160a01b0388166119095760405162461bcd60e51b815260040161038c90612574565b6001600160a01b03861661192f5760405162461bcd60e51b815260040161038c906125b7565b609754604051630b3a041d60e21b81526001600160a01b0390911690632ce810749061195f90899060040161243d565b600060405180830381600087803b15801561197957600080fd5b505af115801561198d573d6000803e3d6000fd5b5050609854604051631dc80e7160e31b81526001600160a01b03909116925063ee40738891506119c1908a9060040161243d565b600060405180830381600087803b1580156119db57600080fd5b505af11580156119ef573d6000803e3d6000fd5b50505050866001600160a01b031663cdae1ee0878c609860009054906101000a90046001600160a01b03168d609960009054906101000a90046001600160a01b03168b8b6040518863ffffffff1660e01b8152600401611a559796959493929190612642565b600060405180830381600087803b158015611a6f57600080fd5b505af1158015611a83573d6000803e3d6000fd5b5050609854604051631dc80e7160e31b81526001600160a01b03909116925063ee4073889150611ab7908b9060040161243d565b600060405180830381600087803b158015611ad157600080fd5b505af1158015611ae5573d6000803e3d6000fd5b5050609854604051631e442d1960e21b81526001600160a01b03808d169450637910b4649350611b22928b929116908f908b908b906004016125e5565b600060405180830381600087803b158015611b3c57600080fd5b505af1158015611b50573d6000803e3d6000fd5b5050609854604051631dc80e7160e31b81526001600160a01b03909116925063ee4073889150611b8490899060040161243d565b600060405180830381600087803b158015611b9e57600080fd5b505af1158015611bb2573d6000803e3d6000fd5b505060985460975460405163e8c856f160e01b81526001600160a01b03808c16955063e8c856f19450611bfa9381169216908f908d908f908d908d908d908d90600401612755565b600060405180830381600087803b158015611c1457600080fd5b505af1158015611c28573d6000803e3d6000fd5b5050604080516060810182526001600160a01b038a811682528b811660208301528c811682840152915163202a804560e11b8152918d169350634055008a9250611c74916004016127cf565b600060405180830381600087803b158015611c8e57600080fd5b505af1158015611ca2573d6000803e3d6000fd5b5050604080516060810182526001600160a01b038a811682528b811660208301528c811682840152915163202a804560e11b8152918e169350634055008a9250611cee916004016127cf565b600060405180830381600087803b158015611d0857600080fd5b505af1158015611d1c573d6000803e3d6000fd5b5050505050505050505050505050565b600082815260656020526040902060010154611d4781611da7565b61031b8383611e3a565b6000805160206128db833981519152611d6981611da7565b506099805460ff60a01b19169055565b6000805160206128db833981519152611d9181611da7565b506099805460ff60a01b1916600160a01b179055565b611db18133611ea1565b50565b611dbe828261158e565b61039f5760008281526065602090815260408083206001600160a01b03851684529091529020805460ff19166001179055611df63390565b6001600160a01b0316816001600160a01b0316837f2f8788117e7eff1d82e926ec794901d17c78024a50270940304540a733656f0d60405160405180910390a45050565b611e44828261158e565b1561039f5760008281526065602090815260408083206001600160a01b0385168085529252808320805460ff1916905551339285917ff6391f5c32d9c69d2a47ea670b442974b53935d1edc7fd64eb21e047a839171b9190a45050565b611eab828261158e565b61039f57611eb881611efa565b611ec3836020611f0c565b604051602001611ed49291906127fe565b60408051601f198184030181529082905262461bcd60e51b825261038c916004016121d1565b60606102866001600160a01b03831660145b60606000611f1b836002612883565b611f2690600261289a565b6001600160401b03811115611f3d57611f3d6121e4565b6040519080825280601f01601f191660200182016040528015611f67576020820181803683370190505b509050600360fc1b81600081518110611f8257611f826128ad565b60200101906001600160f81b031916908160001a905350600f60fb1b81600181518110611fb157611fb16128ad565b60200101906001600160f81b031916908160001a9053506000611fd5846002612883565b611fe090600161289a565b90505b6001811115612058576f181899199a1a9b1b9c1cb0b131b232b360811b85600f1660108110612014576120146128ad565b1a60f81b82828151811061202a5761202a6128ad565b60200101906001600160f81b031916908160001a90535060049490941c93612051816128c3565b9050611fe3565b5083156120a75760405162461bcd60e51b815260206004820181905260248201527f537472696e67733a20686578206c656e67746820696e73756666696369656e74604482015260640161038c565b9392505050565b6000602082840312156120c057600080fd5b81356001600160e01b0319811681146120a757600080fd5b6001600160a01b0381168114611db157600080fd5b60008060006060848603121561210257600080fd5b833561210d816120d8565b9250602084013561211d816120d8565b9150604084013561212d816120d8565b809150509250925092565b60006020828403121561214a57600080fd5b5035919050565b6000806040838503121561216457600080fd5b823591506020830135612176816120d8565b809150509250929050565b60005b8381101561219c578181015183820152602001612184565b50506000910152565b600081518084526121bd816020860160208601612181565b601f01601f19169290920160200192915050565b6020815260006120a760208301846121a5565b634e487b7160e01b600052604160045260246000fd5b600082601f83011261220b57600080fd5b81356001600160401b0380821115612225576122256121e4565b604051601f8301601f19908116603f0116810190828211818310171561224d5761224d6121e4565b8160405283815286602085880101111561226657600080fd5b836020870160208301376000602085830101528094505050505092915050565b60008060008060008587036101808112156122a057600080fd5b610100808212156122b057600080fd5b87965086013590506122c1816120d8565b93506101208601356122d2816120d8565b92506101408601356001600160401b03808211156122ef57600080fd5b6122fb89838a016121fa565b935061016088013591508082111561231257600080fd5b5061231f888289016121fa565b9150509295509295909350565b60008060008060008060008060006101008a8c03121561234b57600080fd5b8935612356816120d8565b985060208a0135612366816120d8565b975060408a0135612376816120d8565b965060608a0135612386816120d8565b955060808a0135612396816120d8565b945060a08a01356123a6816120d8565b935060c08a01356123b6816120d8565b925060e08a01356001600160401b03808211156123d257600080fd5b818c0191508c601f8301126123e657600080fd5b8135818111156123f557600080fd5b8d602082850101111561240757600080fd5b6020830194508093505050509295985092959850929598565b60006020828403121561243257600080fd5b81356120a7816120d8565b6001600160a01b0391909116815260200190565b60006020828403121561246357600080fd5b815180151581146120a757600080fd5b6020808252600c908201526b4e6f6e2d5465726d2054525360a01b604082015260600190565b6020808252600d908201526c4e6f6e2d5465726d205452434d60981b604082015260600190565b6020808252600d908201526c139bdb8b55195c9b4815105093609a1b604082015260600190565b6020808252600d908201526c139bdb8b55195c9b48151053d3609a1b604082015260600190565b6020808252600b908201526a4e6f6e2d5465726d20544160a81b604082015260600190565b60208082526021908201527f5a65726f2041646472657373207465726d41756374696f6e4269644c6f636b656040820152603960f91b606082015260800190565b60208082526023908201527f5a65726f2041646472657373207465726d41756374696f6e4f666665724c6f6360408201526235b2b960e91b606082015260800190565b6020808252601490820152732d32b9379020b2323932b9b99030bab1ba34b7b760611b604082015260600190565b6001600160a01b0395861681529385166020850152918416604084015283166060830152909116608082015260a00190565b6001600160a01b03948516815292841660208401529083166040830152909116606082015260800190565b6001600160a01b03978816815295871660208701529386166040860152918516606085015284166080840152831660a083015290911660c082015260e00190565b6001600160a01b038981168252888116602083015287811660408301528681166060830152858116608083015284811660a0830152831660c082015261010060e082018190526000906126d8838201856121a5565b9b9a5050505050505050505050565b6001600160a01b038a81168252898116602083015288811660408301528781166060830152868116608083015285811660a083015284811660c0830152831660e08201526101206101008201819052600090612745838201856121a5565b9c9b505050505050505050505050565b6001600160a01b038a81168252898116602083015288811660408301528781166060830152868116608083015285811660a0830152841660c082015261010060e08201819052810182905260006101208385828501376000838501820152601f909301601f19169091019091019998505050505050505050565b81516001600160a01b039081168252602080840151821690830152604092830151169181019190915260600190565b76020b1b1b2b9b9a1b7b73a3937b61d1030b1b1b7bab73a1604d1b815260008351612830816017850160208801612181565b7001034b99036b4b9b9b4b733903937b6329607d1b6017918401918201528351612861816028840160208801612181565b01602801949350505050565b634e487b7160e01b600052601160045260246000fd5b80820281158282048414176102865761028661286d565b808201808211156102865761028661286d565b634e487b7160e01b600052603260045260246000fd5b6000816128d2576128d261286d565b50600019019056fe793a6c9b7e0a9549c74edc2f9ae0dc50903dfaa9a56fb0116b27a8c71de3e2c66ed99f2da23f40576cbf78aa7c8ca667edae2da83ffc25cda14b3818f7b0d084a2646970667358221220028fadbc237a0b74e866e87c1d7aef59087ce23e5b6d0ec19acc5fd4c9154f5d64736f6c63430008120033

000000000000000000000000d03a6771b64e9a759523af3a89fc982b2dd38591000000000000000000000000b8a1df43c1c88b13937c0c5cebbad15830caec03

-----Decoded View---------------
Arg [0] : initializerApprovalRole_ (address): 0xD03a6771b64E9A759523af3a89Fc982b2dd38591
Arg [1] : devopsWallet_ (address): 0xb8A1dF43c1c88b13937C0c5CEBbAd15830cAeC03

-----Encoded View---------------
2 Constructor Arguments found :
Arg [0] : 000000000000000000000000d03a6771b64e9a759523af3a89fc982b2dd38591
Arg [1] : 000000000000000000000000b8a1df43c1c88b13937c0c5cebbad15830caec03