ETH Price: $3,104.33 (-0.21%)
Gas: 2 Gwei

Contract

0xff830ce17D39BbD6a4fef9683308D793dF8E34fC
 

Overview

ETH Balance

0.05 ETH

Eth Value

$155.22 (@ $3,104.33/ETH)

Multichain Info

1 address found via
Transaction Hash
Method
Block
From
To
Value
Exec Transaction197767982024-05-01 17:33:1118 days ago1714584791IN
0xff830ce1...3dF8E34fC
0 ETH0.0014367814.56389355
Exec Transaction197415102024-04-26 19:08:5923 days ago1714158539IN
0xff830ce1...3dF8E34fC
0 ETH0.000558946.56318464
Exec Transaction195990132024-04-06 20:18:4743 days ago1712434727IN
0xff830ce1...3dF8E34fC
0 ETH0.0013715416.85571793
Exec Transaction195920102024-04-05 20:47:2344 days ago1712350043IN
0xff830ce1...3dF8E34fC
0 ETH0.004898324.06285245
Exec Transaction195367662024-03-29 2:44:2352 days ago1711680263IN
0xff830ce1...3dF8E34fC
0 ETH0.0018401921.61378372
Exec Transaction195365112024-03-29 1:52:5952 days ago1711677179IN
0xff830ce1...3dF8E34fC
0 ETH0.0013692329
Exec Transaction195365102024-03-29 1:52:4752 days ago1711677167IN
0xff830ce1...3dF8E34fC
0 ETH0.0024620525
Exec Transaction194725542024-03-20 1:09:4761 days ago1710896987IN
0xff830ce1...3dF8E34fC
0 ETH0.0025078530.81580061
Exec Transaction193951632024-03-09 4:29:3572 days ago1709958575IN
0xff830ce1...3dF8E34fC
0 ETH0.0019464940.79085744
Exec Transaction193951632024-03-09 4:29:3572 days ago1709958575IN
0xff830ce1...3dF8E34fC
0 ETH0.0032779338.48962799
Exec Transaction193951512024-03-09 4:27:1172 days ago1709958431IN
0xff830ce1...3dF8E34fC
0 ETH0.0036625643
Exec Transaction193951482024-03-09 4:26:3572 days ago1709958395IN
0xff830ce1...3dF8E34fC
0 ETH0.0044496543.51652519
Exec Transaction193951452024-03-09 4:25:5972 days ago1709958359IN
0xff830ce1...3dF8E34fC
0 ETH0.0036845243.25173467
Exec Transaction193951162024-03-09 4:20:1172 days ago1709958011IN
0xff830ce1...3dF8E34fC
0 ETH0.0045285146
Exec Transaction193164252024-02-27 4:12:4783 days ago1709007167IN
0xff830ce1...3dF8E34fC
0 ETH0.0039387838.44217023
Exec Transaction193164212024-02-27 4:11:5983 days ago1709007119IN
0xff830ce1...3dF8E34fC
0 ETH0.0042147142.72216426
Exec Transaction192919252024-02-23 17:57:4786 days ago1708711067IN
0xff830ce1...3dF8E34fC
0 ETH0.0029345135.99840519
Exec Transaction192916742024-02-23 17:07:1186 days ago1708708031IN
0xff830ce1...3dF8E34fC
0 ETH0.0043769144.4546334
Exec Transaction192563902024-02-18 18:13:5991 days ago1708280039IN
0xff830ce1...3dF8E34fC
0 ETH0.0025523525.8749095
Exec Transaction192138242024-02-12 18:46:5997 days ago1707763619IN
0xff830ce1...3dF8E34fC
0 ETH0.0031037838.13851101
Exec Transaction191950222024-02-10 3:25:47100 days ago1707535547IN
0xff830ce1...3dF8E34fC
0 ETH0.00392238.3427668
Exec Transaction191950192024-02-10 3:25:11100 days ago1707535511IN
0xff830ce1...3dF8E34fC
0 ETH0.0037760244.33197437
Exec Transaction191950142024-02-10 3:24:11100 days ago1707535451IN
0xff830ce1...3dF8E34fC
0 ETH0.0036999445.46393293
Exec Transaction191950092024-02-10 3:23:11100 days ago1707535391IN
0xff830ce1...3dF8E34fC
0 ETH0.0049987550.76421971
Exec Transaction191294242024-01-31 22:26:11109 days ago1706739971IN
0xff830ce1...3dF8E34fC
0 ETH0.0028483735
View all transactions

Latest 2 internal transactions

Advanced mode:
Parent Transaction Hash Block From To Value
142647942022-02-23 21:33:07816 days ago1645651987
0xff830ce1...3dF8E34fC
0.05 ETH
142646982022-02-23 21:12:42816 days ago1645650762  Contract Creation0 ETH
Loading...
Loading

Similar Match Source Code
This contract matches the deployed Bytecode of the Source Code for Contract 0xDaB5dc22...0ba42d2a6
The constructor portion of the code might be different and could alter the actual behaviour of the contract

Contract Name:
GnosisSafeProxy

Compiler Version
v0.7.6+commit.7338295f

Optimization Enabled:
No with 200 runs

Other Settings:
default evmVersion, GNU LGPLv3 license
/**
 *Submitted for verification at Etherscan.io on 2021-07-09
*/

// SPDX-License-Identifier: LGPL-3.0-only
pragma solidity >=0.7.0 <0.9.0;

/// @title IProxy - Helper interface to access masterCopy of the Proxy on-chain
/// @author Richard Meissner - <[email protected]>
interface IProxy {
    function masterCopy() external view returns (address);
}

/// @title GnosisSafeProxy - Generic proxy contract allows to execute all transactions applying the code of a master contract.
/// @author Stefan George - <[email protected]>
/// @author Richard Meissner - <[email protected]>
contract GnosisSafeProxy {
    // singleton always needs to be first declared variable, to ensure that it is at the same location in the contracts to which calls are delegated.
    // To reduce deployment costs this variable is internal and needs to be retrieved via `getStorageAt`
    address internal singleton;

    /// @dev Constructor function sets address of singleton contract.
    /// @param _singleton Singleton address.
    constructor(address _singleton) {
        require(_singleton != address(0), "Invalid singleton address provided");
        singleton = _singleton;
    }

    /// @dev Fallback function forwards all transactions and returns all received return data.
    fallback() external payable {
        // solhint-disable-next-line no-inline-assembly
        assembly {
            let _singleton := and(sload(0), 0xffffffffffffffffffffffffffffffffffffffff)
            // 0xa619486e == keccak("masterCopy()"). The value is right padded to 32-bytes with 0s
            if eq(calldataload(0), 0xa619486e00000000000000000000000000000000000000000000000000000000) {
                mstore(0, _singleton)
                return(0, 0x20)
            }
            calldatacopy(0, 0, calldatasize())
            let success := delegatecall(gas(), _singleton, 0, calldatasize(), 0, 0)
            returndatacopy(0, 0, returndatasize())
            if eq(success, 0) {
                revert(0, returndatasize())
            }
            return(0, returndatasize())
        }
    }
}

/// @title Proxy Factory - Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
/// @author Stefan George - <[email protected]>
contract GnosisSafeProxyFactory {
    event ProxyCreation(GnosisSafeProxy proxy, address singleton);

    /// @dev Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
    /// @param singleton Address of singleton contract.
    /// @param data Payload for message call sent to new proxy contract.
    function createProxy(address singleton, bytes memory data) public returns (GnosisSafeProxy proxy) {
        proxy = new GnosisSafeProxy(singleton);
        if (data.length > 0)
            // solhint-disable-next-line no-inline-assembly
            assembly {
                if eq(call(gas(), proxy, 0, add(data, 0x20), mload(data), 0, 0), 0) {
                    revert(0, 0)
                }
            }
        emit ProxyCreation(proxy, singleton);
    }

    /// @dev Allows to retrieve the runtime code of a deployed Proxy. This can be used to check that the expected Proxy was deployed.
    function proxyRuntimeCode() public pure returns (bytes memory) {
        return type(GnosisSafeProxy).runtimeCode;
    }

    /// @dev Allows to retrieve the creation code used for the Proxy deployment. With this it is easily possible to calculate predicted address.
    function proxyCreationCode() public pure returns (bytes memory) {
        return type(GnosisSafeProxy).creationCode;
    }

    /// @dev Allows to create new proxy contact using CREATE2 but it doesn't run the initializer.
    ///      This method is only meant as an utility to be called from other methods
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function deployProxyWithNonce(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce
    ) internal returns (GnosisSafeProxy proxy) {
        // If the initializer changes the proxy address should change too. Hashing the initializer data is cheaper than just concatinating it
        bytes32 salt = keccak256(abi.encodePacked(keccak256(initializer), saltNonce));
        bytes memory deploymentData = abi.encodePacked(type(GnosisSafeProxy).creationCode, uint256(uint160(_singleton)));
        // solhint-disable-next-line no-inline-assembly
        assembly {
            proxy := create2(0x0, add(0x20, deploymentData), mload(deploymentData), salt)
        }
        require(address(proxy) != address(0), "Create2 call failed");
    }

    /// @dev Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function createProxyWithNonce(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce
    ) public returns (GnosisSafeProxy proxy) {
        proxy = deployProxyWithNonce(_singleton, initializer, saltNonce);
        if (initializer.length > 0)
            // solhint-disable-next-line no-inline-assembly
            assembly {
                if eq(call(gas(), proxy, 0, add(initializer, 0x20), mload(initializer), 0, 0), 0) {
                    revert(0, 0)
                }
            }
        emit ProxyCreation(proxy, _singleton);
    }

    /// @dev Allows to create new proxy contact, execute a message call to the new proxy and call a specified callback within one transaction
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    /// @param callback Callback that will be invoced after the new proxy contract has been successfully deployed and initialized.
    function createProxyWithCallback(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce,
        IProxyCreationCallback callback
    ) public returns (GnosisSafeProxy proxy) {
        uint256 saltNonceWithCallback = uint256(keccak256(abi.encodePacked(saltNonce, callback)));
        proxy = createProxyWithNonce(_singleton, initializer, saltNonceWithCallback);
        if (address(callback) != address(0)) callback.proxyCreated(proxy, _singleton, initializer, saltNonce);
    }

    /// @dev Allows to get the address for a new proxy contact created via `createProxyWithNonce`
    ///      This method is only meant for address calculation purpose when you use an initializer that would revert,
    ///      therefore the response is returned with a revert. When calling this method set `from` to the address of the proxy factory.
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function calculateCreateProxyWithNonceAddress(
        address _singleton,
        bytes calldata initializer,
        uint256 saltNonce
    ) external returns (GnosisSafeProxy proxy) {
        proxy = deployProxyWithNonce(_singleton, initializer, saltNonce);
        revert(string(abi.encodePacked(proxy)));
    }
}

interface IProxyCreationCallback {
    function proxyCreated(
        GnosisSafeProxy proxy,
        address _singleton,
        bytes calldata initializer,
        uint256 saltNonce
    ) external;
}

Contract Security Audit

Contract ABI

[{"inputs":[{"internalType":"address","name":"_singleton","type":"address"}],"stateMutability":"nonpayable","type":"constructor"},{"stateMutability":"payable","type":"fallback"}]

Deployed Bytecode

0x608060405273ffffffffffffffffffffffffffffffffffffffff600054167fa619486e0000000000000000000000000000000000000000000000000000000060003514156050578060005260206000f35b3660008037600080366000845af43d6000803e60008114156070573d6000fd5b3d6000f3fea2646970667358221220d1429297349653a4918076d650332de1a1068c5f3e07c5c82360c277770b955264736f6c63430007060033

Deployed Bytecode Sourcemap

524:1528:0:-:0;;;1376:42;1372:1;1366:8;1362:57;1556:66;1552:1;1539:15;1536:87;1533:2;;;1653:10;1650:1;1643:21;1692:4;1689:1;1682:15;1533:2;1745:14;1742:1;1739;1726:34;1843:1;1840;1824:14;1821:1;1809:10;1802:5;1789:56;1880:16;1877:1;1874;1859:38;1926:1;1917:7;1914:14;1911:2;;;1958:16;1955:1;1948:27;1911:2;2014:16;2011:1;2004:27

Swarm Source

ipfs://d1429297349653a4918076d650332de1a1068c5f3e07c5c82360c277770b9552

Block Transaction Difficulty Gas Used Reward
View All Blocks Produced

Block Uncle Number Difficulty Gas Used Reward
View All Uncles
Loading...
Loading
Loading...
Loading

Validator Index Block Amount
View All Withdrawals

Transaction Hash Block Value Eth2 PubKey Valid
View All Deposits
Loading...
Loading
[ Download: CSV Export  ]
[ Download: CSV Export  ]

A contract address hosts a smart contract, which is a set of code stored on the blockchain that runs when predetermined conditions are met. Learn more about addresses in our Knowledge Base.