ETH Price: $3,481.10 (-0.16%)
Gas: 6 Gwei

Contract

0xa14664a2E58e804669E9fF1DFbC1bD981E13B0dC
 
Transaction Hash
Method
Block
From
To
Exec Transaction200711912024-06-11 21:12:1140 days ago1718140331IN
0xa14664a2...81E13B0dC
0 ETH0.0010510716
Exec Transaction197714902024-04-30 23:46:1182 days ago1714520771IN
0xa14664a2...81E13B0dC
0 ETH0.000574064.97595734
Exec Transaction197345392024-04-25 19:42:1187 days ago1714074131IN
0xa14664a2...81E13B0dC
0 ETH0.0006571610
Exec Transaction197054602024-04-21 18:05:5991 days ago1713722759IN
0xa14664a2...81E13B0dC
0 ETH0.0009164910.85742199
Exec Transaction196984072024-04-20 18:27:1192 days ago1713637631IN
0xa14664a2...81E13B0dC
0 ETH0.0069374513.88207516
Exec Transaction195978582024-04-06 16:23:59106 days ago1712420639IN
0xa14664a2...81E13B0dC
0 ETH0.0097586720.17579838
Exec Transaction192346662024-02-15 16:57:23157 days ago1708016243IN
0xa14664a2...81E13B0dC
0 ETH0.002505439.64001409
Exec Transaction190930142024-01-26 19:59:47177 days ago1706299187IN
0xa14664a2...81E13B0dC
0 ETH0.0010970417.71993081
Exec Transaction189501702024-01-06 19:19:59197 days ago1704568799IN
0xa14664a2...81E13B0dC
0 ETH0.0014091823.71488246
Exec Transaction188301532023-12-20 22:41:47214 days ago1703112107IN
0xa14664a2...81E13B0dC
0 ETH0.0117257250.80072574
Exec Transaction187660812023-12-11 22:57:11223 days ago1702335431IN
0xa14664a2...81E13B0dC
0 ETH0.0253322544.6974017
Exec Transaction187660542023-12-11 22:51:47223 days ago1702335107IN
0xa14664a2...81E13B0dC
0 ETH0.0028209638
Transfer187641822023-12-11 16:33:35223 days ago1702312415IN
0xa14664a2...81E13B0dC
0.5 ETH0.001217144.53512278
Transfer187602142023-12-11 3:14:35224 days ago1702264475IN
0xa14664a2...81E13B0dC
1.5 ETH0.001253245.85631465
Exec Transaction187359622023-12-07 17:40:35227 days ago1701970835IN
0xa14664a2...81E13B0dC
0 ETH0.0074028270.02426117
Exec Transaction186155402023-11-20 21:00:47244 days ago1700514047IN
0xa14664a2...81E13B0dC
0 ETH0.0028951244.06320796
Exec Transaction185459912023-11-11 3:23:59254 days ago1699673039IN
0xa14664a2...81E13B0dC
0 ETH0.0076952427.88659052
Exec Transaction185082552023-11-05 20:43:11259 days ago1699216991IN
0xa14664a2...81E13B0dC
0 ETH0.0045309318.37070214
Exec Transaction174649412023-06-12 15:44:59405 days ago1686584699IN
0xa14664a2...81E13B0dC
0 ETH0.0008174318
Exec Transaction174645232023-06-12 14:19:23405 days ago1686579563IN
0xa14664a2...81E13B0dC
0 ETH0.0015228325.62752852
Exec Transaction173690032023-05-30 3:12:59419 days ago1685416379IN
0xa14664a2...81E13B0dC
0 ETH0.0071826327.57153917
Exec Transaction173520702023-05-27 18:07:35421 days ago1685210855IN
0xa14664a2...81E13B0dC
0 ETH0.0051084824.06721416
Exec Transaction173515352023-05-27 16:19:11421 days ago1685204351IN
0xa14664a2...81E13B0dC
0 ETH0.0078809630.8987314
Exec Transaction171400922023-04-27 21:10:11451 days ago1682629811IN
0xa14664a2...81E13B0dC
0 ETH0.001912834
Exec Transaction170699872023-04-18 0:18:35461 days ago1681777115IN
0xa14664a2...81E13B0dC
0 ETH0.0027349639.67687672
View all transactions

Latest 25 internal transactions (View All)

Advanced mode:
Parent Transaction Hash Block From To
200711912024-06-11 21:12:1140 days ago1718140331
0xa14664a2...81E13B0dC
10 ETH
197345392024-04-25 19:42:1187 days ago1714074131
0xa14664a2...81E13B0dC
1.3 ETH
196984072024-04-20 18:27:1192 days ago1713637631
0xa14664a2...81E13B0dC
22.88 ETH
195978582024-04-06 16:23:59106 days ago1712420639
0xa14664a2...81E13B0dC
39.88302259 ETH
192346662024-02-15 16:57:23157 days ago1708016243
0xa14664a2...81E13B0dC
2 ETH
190979482024-01-27 12:34:59176 days ago1706358899
0xa14664a2...81E13B0dC
5 ETH
190930652024-01-26 20:10:11177 days ago1706299811
0xa14664a2...81E13B0dC
1.82165977 ETH
190930142024-01-26 19:59:47177 days ago1706299187
0xa14664a2...81E13B0dC
1 ETH
189501702024-01-06 19:19:59197 days ago1704568799
0xa14664a2...81E13B0dC
50 ETH
188301532023-12-20 22:41:47214 days ago1703112107
0xa14664a2...81E13B0dC
52.81165977 ETH
187660812023-12-11 22:57:11223 days ago1702335431
0xa14664a2...81E13B0dC
3.253 ETH
187660542023-12-11 22:51:47223 days ago1702335107
0xa14664a2...81E13B0dC
3.253 ETH
187359622023-12-07 17:40:35227 days ago1701970835
0xa14664a2...81E13B0dC
0.1 ETH
187359622023-12-07 17:40:35227 days ago1701970835
0xa14664a2...81E13B0dC
6.637 ETH
186155402023-11-20 21:00:47244 days ago1700514047
0xa14664a2...81E13B0dC
1 ETH
185459912023-11-11 3:23:59254 days ago1699673039
0xa14664a2...81E13B0dC
1 ETH
185317202023-11-09 3:30:23256 days ago1699500623
0xa14664a2...81E13B0dC
10 ETH
174645232023-06-12 14:19:23405 days ago1686579563
0xa14664a2...81E13B0dC
23.784 ETH
174314672023-06-07 22:31:59410 days ago1686177119
0xa14664a2...81E13B0dC
23.784 ETH
168299722023-03-15 1:13:35495 days ago1678842815
0xa14664a2...81E13B0dC
0.01 ETH
168299492023-03-15 1:08:59495 days ago1678842539
0xa14664a2...81E13B0dC
58.67962197 ETH
168299172023-03-15 1:02:35495 days ago1678842155
0xa14664a2...81E13B0dC
15 ETH
167883012023-03-09 4:34:23501 days ago1678336463
0xa14664a2...81E13B0dC
10 ETH
167882642023-03-09 4:26:47501 days ago1678336007
0xa14664a2...81E13B0dC
83.68962197 ETH
158839172022-11-02 17:46:35627 days ago1667411195
0xa14664a2...81E13B0dC
0.01 ETH
View All Internal Transactions
Loading...
Loading

Similar Match Source Code
This contract matches the deployed Bytecode of the Source Code for Contract 0xDaB5dc22...0ba42d2a6
The constructor portion of the code might be different and could alter the actual behaviour of the contract

Contract Name:
GnosisSafeProxy

Compiler Version
v0.7.6+commit.7338295f

Optimization Enabled:
No with 200 runs

Other Settings:
default evmVersion, GNU LGPLv3 license
/**
 *Submitted for verification at Etherscan.io on 2021-07-09
*/

// SPDX-License-Identifier: LGPL-3.0-only
pragma solidity >=0.7.0 <0.9.0;

/// @title IProxy - Helper interface to access masterCopy of the Proxy on-chain
/// @author Richard Meissner - <[email protected]>
interface IProxy {
    function masterCopy() external view returns (address);
}

/// @title GnosisSafeProxy - Generic proxy contract allows to execute all transactions applying the code of a master contract.
/// @author Stefan George - <[email protected]>
/// @author Richard Meissner - <[email protected]>
contract GnosisSafeProxy {
    // singleton always needs to be first declared variable, to ensure that it is at the same location in the contracts to which calls are delegated.
    // To reduce deployment costs this variable is internal and needs to be retrieved via `getStorageAt`
    address internal singleton;

    /// @dev Constructor function sets address of singleton contract.
    /// @param _singleton Singleton address.
    constructor(address _singleton) {
        require(_singleton != address(0), "Invalid singleton address provided");
        singleton = _singleton;
    }

    /// @dev Fallback function forwards all transactions and returns all received return data.
    fallback() external payable {
        // solhint-disable-next-line no-inline-assembly
        assembly {
            let _singleton := and(sload(0), 0xffffffffffffffffffffffffffffffffffffffff)
            // 0xa619486e == keccak("masterCopy()"). The value is right padded to 32-bytes with 0s
            if eq(calldataload(0), 0xa619486e00000000000000000000000000000000000000000000000000000000) {
                mstore(0, _singleton)
                return(0, 0x20)
            }
            calldatacopy(0, 0, calldatasize())
            let success := delegatecall(gas(), _singleton, 0, calldatasize(), 0, 0)
            returndatacopy(0, 0, returndatasize())
            if eq(success, 0) {
                revert(0, returndatasize())
            }
            return(0, returndatasize())
        }
    }
}

/// @title Proxy Factory - Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
/// @author Stefan George - <[email protected]>
contract GnosisSafeProxyFactory {
    event ProxyCreation(GnosisSafeProxy proxy, address singleton);

    /// @dev Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
    /// @param singleton Address of singleton contract.
    /// @param data Payload for message call sent to new proxy contract.
    function createProxy(address singleton, bytes memory data) public returns (GnosisSafeProxy proxy) {
        proxy = new GnosisSafeProxy(singleton);
        if (data.length > 0)
            // solhint-disable-next-line no-inline-assembly
            assembly {
                if eq(call(gas(), proxy, 0, add(data, 0x20), mload(data), 0, 0), 0) {
                    revert(0, 0)
                }
            }
        emit ProxyCreation(proxy, singleton);
    }

    /// @dev Allows to retrieve the runtime code of a deployed Proxy. This can be used to check that the expected Proxy was deployed.
    function proxyRuntimeCode() public pure returns (bytes memory) {
        return type(GnosisSafeProxy).runtimeCode;
    }

    /// @dev Allows to retrieve the creation code used for the Proxy deployment. With this it is easily possible to calculate predicted address.
    function proxyCreationCode() public pure returns (bytes memory) {
        return type(GnosisSafeProxy).creationCode;
    }

    /// @dev Allows to create new proxy contact using CREATE2 but it doesn't run the initializer.
    ///      This method is only meant as an utility to be called from other methods
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function deployProxyWithNonce(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce
    ) internal returns (GnosisSafeProxy proxy) {
        // If the initializer changes the proxy address should change too. Hashing the initializer data is cheaper than just concatinating it
        bytes32 salt = keccak256(abi.encodePacked(keccak256(initializer), saltNonce));
        bytes memory deploymentData = abi.encodePacked(type(GnosisSafeProxy).creationCode, uint256(uint160(_singleton)));
        // solhint-disable-next-line no-inline-assembly
        assembly {
            proxy := create2(0x0, add(0x20, deploymentData), mload(deploymentData), salt)
        }
        require(address(proxy) != address(0), "Create2 call failed");
    }

    /// @dev Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function createProxyWithNonce(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce
    ) public returns (GnosisSafeProxy proxy) {
        proxy = deployProxyWithNonce(_singleton, initializer, saltNonce);
        if (initializer.length > 0)
            // solhint-disable-next-line no-inline-assembly
            assembly {
                if eq(call(gas(), proxy, 0, add(initializer, 0x20), mload(initializer), 0, 0), 0) {
                    revert(0, 0)
                }
            }
        emit ProxyCreation(proxy, _singleton);
    }

    /// @dev Allows to create new proxy contact, execute a message call to the new proxy and call a specified callback within one transaction
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    /// @param callback Callback that will be invoced after the new proxy contract has been successfully deployed and initialized.
    function createProxyWithCallback(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce,
        IProxyCreationCallback callback
    ) public returns (GnosisSafeProxy proxy) {
        uint256 saltNonceWithCallback = uint256(keccak256(abi.encodePacked(saltNonce, callback)));
        proxy = createProxyWithNonce(_singleton, initializer, saltNonceWithCallback);
        if (address(callback) != address(0)) callback.proxyCreated(proxy, _singleton, initializer, saltNonce);
    }

    /// @dev Allows to get the address for a new proxy contact created via `createProxyWithNonce`
    ///      This method is only meant for address calculation purpose when you use an initializer that would revert,
    ///      therefore the response is returned with a revert. When calling this method set `from` to the address of the proxy factory.
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function calculateCreateProxyWithNonceAddress(
        address _singleton,
        bytes calldata initializer,
        uint256 saltNonce
    ) external returns (GnosisSafeProxy proxy) {
        proxy = deployProxyWithNonce(_singleton, initializer, saltNonce);
        revert(string(abi.encodePacked(proxy)));
    }
}

interface IProxyCreationCallback {
    function proxyCreated(
        GnosisSafeProxy proxy,
        address _singleton,
        bytes calldata initializer,
        uint256 saltNonce
    ) external;
}

Contract Security Audit

Contract ABI

[{"inputs":[{"internalType":"address","name":"_singleton","type":"address"}],"stateMutability":"nonpayable","type":"constructor"},{"stateMutability":"payable","type":"fallback"}]

Deployed Bytecode

0x608060405273ffffffffffffffffffffffffffffffffffffffff600054167fa619486e0000000000000000000000000000000000000000000000000000000060003514156050578060005260206000f35b3660008037600080366000845af43d6000803e60008114156070573d6000fd5b3d6000f3fea2646970667358221220d1429297349653a4918076d650332de1a1068c5f3e07c5c82360c277770b955264736f6c63430007060033

Deployed Bytecode Sourcemap

524:1528:0:-:0;;;1376:42;1372:1;1366:8;1362:57;1556:66;1552:1;1539:15;1536:87;1533:2;;;1653:10;1650:1;1643:21;1692:4;1689:1;1682:15;1533:2;1745:14;1742:1;1739;1726:34;1843:1;1840;1824:14;1821:1;1809:10;1802:5;1789:56;1880:16;1877:1;1874;1859:38;1926:1;1917:7;1914:14;1911:2;;;1958:16;1955:1;1948:27;1911:2;2014:16;2011:1;2004:27

Swarm Source

ipfs://d1429297349653a4918076d650332de1a1068c5f3e07c5c82360c277770b9552

Block Transaction Difficulty Gas Used Reward
View All Blocks Produced

Block Uncle Number Difficulty Gas Used Reward
View All Uncles
Loading...
Loading
Loading...
Loading

Validator Index Block Amount
View All Withdrawals

Transaction Hash Block Value Eth2 PubKey Valid
View All Deposits
Loading...
Loading
[ Download: CSV Export  ]
[ Download: CSV Export  ]

A contract address hosts a smart contract, which is a set of code stored on the blockchain that runs when predetermined conditions are met. Learn more about addresses in our Knowledge Base.