Contract 0xA01f4c825889646387F3D9D486aDc001452F4c3a 2

Token Contract 
 
 
Txn Hash
Method
Block
From
To
Value
0x6f967cdeae4f9be37629041ba956c3ee40f2804904bc9bb0f8d4307e0e4a8fc9Transfer122151212021-04-10 23:15:15661 days 22 hrs ago0x1b6303963c0f4f3bc9b6433e35ac3ff513e157a9 IN  Gorilla Mobile: GO Token0 Ether0.0036729770
0x1998683657263b04f453646d3ef7140097b68eac6a3662cb0f95ee4f874f78bcTransfer122148642021-04-10 22:25:02661 days 23 hrs ago0xe00875116709d70f1299eb06256d28fb35f824f8 IN  Gorilla Mobile: GO Token0 Ether0.0026229770
0xa36da0f51d26e0a0150bd3267978b1995f37d82298728b935319f03b82d45926Approve119428812021-02-28 1:29:35703 days 20 hrs ago0x60ec23e58d9837593b9e605077ef4b6f8bd19155 IN  Gorilla Mobile: GO Token0 Ether0.0031800370
0xec5fafa1beb96e278978f21dff5203fd7ddffd120e72b64479c1298b6bda9532Transfer117124132021-01-23 14:39:06739 days 7 hrs ago0xe00875116709d70f1299eb06256d28fb35f824f8 IN  Gorilla Mobile: GO Token0 Ether0.0026229770
0x6f51ac7c5ddb80f4218ed5873092be9f531213fb0816be711bc9608c1e95b1a4Withdraw Interes...115595312020-12-31 3:42:06762 days 18 hrs ago0xd0d31c98be0c86f978503a9a867db4c2baf55eae IN  Gorilla Mobile: GO Token0 Ether0.02770947111.99999999
0x1db2e63e91cbcd8c37c72f773c5d99716e5d3edc7f7858821723daa8b32ded6eSet Beneficiarie...115595262020-12-31 3:41:04762 days 18 hrs ago0xd0d31c98be0c86f978503a9a867db4c2baf55eae IN  Gorilla Mobile: GO Token0 Ether0.00329952112
0x7cb40e20e6dd15ceb67281a5950a4688901b0b8c88cafaa6677f2988be9a2ed7Approve114316572020-12-11 12:35:28782 days 9 hrs ago0x4f7546eed2bf04a0d6f878c33da038ce2c71e63d IN  Gorilla Mobile: GO Token0 Ether0.0013261429
0x779c71f324c948c409eed24bcdeaa69bb50e362a7fcce66fc1df287d86f9b8e4Transfer114316312020-12-11 12:29:51782 days 9 hrs ago0xb8b4f83e8f43bed73c6fee4ad76b16fdbad64dd5 IN  Gorilla Mobile: GO Token0 Ether0.0009786126.1
0x7995c3fb0add93897c836da81f937bf753a7ec4003875ca95214ca21ccf6ea6eTransfer114172952020-12-09 7:21:25784 days 14 hrs ago0xe00875116709d70f1299eb06256d28fb35f824f8 IN  Gorilla Mobile: GO Token0 Ether0.0026229770
0x8bb65351413ba50c3cac3d087983bda941ecd0ec390ab81e047ba99d58df1e19Transfer111955262020-11-05 6:19:47818 days 15 hrs ago0xe00875116709d70f1299eb06256d28fb35f824f8 IN  Gorilla Mobile: GO Token0 Ether0.0026229770
0xb1965a76514350013b7628770ef8b85539a9d92ae5537289f4f085f84294f712Transfer111762502020-11-02 7:18:16821 days 14 hrs ago0xe00875116709d70f1299eb06256d28fb35f824f8 IN  Gorilla Mobile: GO Token0 Ether0.0026229770
0xf30f57290668a530fe707faae012b2b30e8b435ceeb6d9989371db44148bc6edTransfer111697642020-11-01 7:22:25822 days 14 hrs ago0xe00875116709d70f1299eb06256d28fb35f824f8 IN  Gorilla Mobile: GO Token0 Ether0.0026229770
0xf449969b7071b4deb0beb3523325924e6e38c770507d6948434f587e787eb3a4Transfer111431842020-10-28 5:20:34826 days 16 hrs ago0x69dcc0fffe6192ca04bde7ffedbb3c89316f12e4 IN  Gorilla Mobile: GO Token0 Ether0.0010117127
0x7479e05ab9b67aff4cbd71ce04cb90098aaf04ea2841ace7b25b9efe9f3941eaTransfer111431802020-10-28 5:19:20826 days 16 hrs ago0x8e471e2917765f66168b6f53f241c97515a9f498 IN  Gorilla Mobile: GO Token0 Ether0.0010117127
0xc1a8be321177ebd3315298fd519f71f8206b4a14800bd0c4e2e607f7d81cf29eTransfer111375312020-10-27 8:37:20827 days 13 hrs ago0x1b6303963c0f4f3bc9b6433e35ac3ff513e157a9 IN  Gorilla Mobile: GO Token0 Ether0.0026238170
0xc8a7dbabf17a2018942d58f4b146ef4dc08fd419bac640fbc42934ebeef09e1cTransfer110919232020-10-20 8:32:12834 days 13 hrs ago0xe00875116709d70f1299eb06256d28fb35f824f8 IN  Gorilla Mobile: GO Token0 Ether0.0026238170
0x5a21af78b788d8bdeb19c8ac039953b06f20e370c8d318d603dfa26dd4b5bb69Transfer110918022020-10-20 8:04:55834 days 13 hrs ago0x81e9d68a129c008c6174014da3b9a947b86eb09f IN  Gorilla Mobile: GO Token0 Ether0.0026229770
0xceb0265c9df8a7bab8ed1895c5102d318688096b993f6e8fbf4c79da51275db2Transfer110917962020-10-20 8:02:45834 days 13 hrs ago0x1b6303963c0f4f3bc9b6433e35ac3ff513e157a9 IN  Gorilla Mobile: GO Token0 Ether0.0026229770
0x2b41b56b90bc1a1ff200387978ceaf3fb5b823e7bd77f9dfe97ea437bf7558dfTransfer110916532020-10-20 7:32:09834 days 14 hrs ago0x81e9d68a129c008c6174014da3b9a947b86eb09f IN  Gorilla Mobile: GO Token0 Ether0.0026238170
0x9dd5e79eec24241c47f743330296e770b927fd86253748352ed95bb78cc8eb8eApprove110916252020-10-20 7:24:56834 days 14 hrs ago0xa6188f617842c734ea14678eb8cc0aeafdb0432d IN  Gorilla Mobile: GO Token0 Ether0.0031800370
0x761d255cdcb4147efb50e36a8f17eb24f1ce6a6d05e9dce947c286a66a3e40a1Transfer110590492020-10-15 7:30:53839 days 14 hrs ago0x1b6303963c0f4f3bc9b6433e35ac3ff513e157a9 IN  Gorilla Mobile: GO Token0 Ether0.0036729770
0x1cbae7021043c57603f6f1fc555b64c56d920ad2925f939cef9158d7746c2107Transfer110535782020-10-14 11:46:34840 days 10 hrs ago0x599eb9718a36b2c090d829290e704e5389b1d6f7 IN  Gorilla Mobile: GO Token0 Ether0.0020615655
0x238a78e91cef8291bef563b0c726ca6c2375a597a84eb25f3f9a74bc23d60cf1Transfer110535192020-10-14 11:34:40840 days 10 hrs ago0x19d3db6fd98a362550afe5482f533b9c89596072 IN  Gorilla Mobile: GO Token0 Ether0.002060955
0xa76badafc18c714a068560226670fed41b74612f5b09598185ccc67496340640Transfer110534632020-10-14 11:21:13840 days 10 hrs ago0x8e471e2917765f66168b6f53f241c97515a9f498 IN  Gorilla Mobile: GO Token0 Ether0.0018741550
0x1fdee696a95de8a33582834b3d356407862c17c0f66e12d79dba67743148e0a6Transfer110524912020-10-14 7:35:26840 days 14 hrs ago0x19d3db6fd98a362550afe5482f533b9c89596072 IN  Gorilla Mobile: GO Token0 Ether0.0022482660
[ Download CSV Export 

OVERVIEW

GorillaGo is an on-chain protocol powering the Gorilla SIMs with instant and secure mobile data swap for users to make calls & access mobile internet. Experience the power to generate mobile data using your own decentralized wallet from anywhere in the world.

Latest 1 internal transaction
Parent Txn Hash Block From To Value
0x90010f005a61e4e821b2fb410e4211a8113a0e6f4ee36453d2f6906c70193c3197647332020-03-29 5:58:201039 days 15 hrs ago 0xb72b4b94d1ed3cc382d5beeefe3d03dd55ad8229  Contract Creation0 Ether
[ Download CSV Export 
Loading

Minimal Proxy Contract for 0x3d6d83649939baa953ddc589d2d5db775df91520

Contract Name:
PooledCDAI

Compiler Version
v0.5.17+commit.d19bba13

Optimization Enabled:
Yes with 200 runs

Other Settings:
default evmVersion, GNU GPLv3 license
Decompile ByteCode

Contract Source Code (Solidity Standard Json-Input format)

File 1 of 17 : PooledCDAIKyberExtension.sol
pragma solidity 0.5.17;

import "../PooledCDAI.sol";
import "../interfaces/KyberNetworkProxy.sol";
import "@openzeppelin/contracts/token/ERC20/SafeERC20.sol";


/**
  @dev An extension to PooledCDAI that enables minting & burning pcDAI using ETH & ERC20 tokens
    supported by Kyber Network, rather than just DAI. There's no need to deploy one for each pool,
    since it uses pcDAI as a black box.
 */
contract PooledCDAIKyberExtension {
    using SafeERC20 for ERC20;
    using SafeERC20 for PooledCDAI;
    using SafeMath for uint256;

    address public constant DAI_ADDRESS = 0x89d24A6b4CcB1B6fAA2625fE562bDD9a23260359;
    address public constant KYBER_ADDRESS = 0x818E6FECD516Ecc3849DAf6845e3EC868087B755;
    ERC20 internal constant ETH_TOKEN_ADDRESS = ERC20(
        0x00eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee
    );
    bytes internal constant PERM_HINT = "PERM"; // Only use permissioned reserves from Kyber
    uint256 internal constant MAX_QTY = (10**28); // 10B tokens

    function mintWithETH(PooledCDAI pcDAI, address to)
        public
        payable
        returns (bool)
    {
        // convert `msg.value` ETH to DAI
        ERC20 dai = ERC20(DAI_ADDRESS);
        (uint256 actualDAIAmount, uint256 actualETHAmount) = _kyberTrade(
            ETH_TOKEN_ADDRESS,
            msg.value,
            dai
        );

        // mint `actualDAIAmount` pcDAI
        _mint(pcDAI, to, actualDAIAmount);

        // return any leftover ETH
        if (actualETHAmount < msg.value) {
            msg.sender.transfer(msg.value.sub(actualETHAmount));
        }

        return true;
    }

    function mintWithToken(
        PooledCDAI pcDAI,
        address tokenAddress,
        address to,
        uint256 amount
    ) public returns (bool) {
        require(
            tokenAddress != address(ETH_TOKEN_ADDRESS),
            "Use mintWithETH() instead"
        );
        require(tokenAddress != DAI_ADDRESS, "Use mint() instead");

        // transfer `amount` token from msg.sender
        ERC20 token = ERC20(tokenAddress);
        token.safeTransferFrom(msg.sender, address(this), amount);

        // convert `amount` token to DAI
        ERC20 dai = ERC20(DAI_ADDRESS);
        (uint256 actualDAIAmount, uint256 actualTokenAmount) = _kyberTrade(
            token,
            amount,
            dai
        );

        // mint `actualDAIAmount` pcDAI
        _mint(pcDAI, to, actualDAIAmount);

        // return any leftover tokens
        if (actualTokenAmount < amount) {
            token.safeTransfer(msg.sender, amount.sub(actualTokenAmount));
        }

        return true;
    }

    function burnToETH(PooledCDAI pcDAI, address payable to, uint256 amount)
        public
        returns (bool)
    {
        // burn `amount` pcDAI for msg.sender to get DAI
        _burn(pcDAI, amount);

        // convert `amount` DAI to ETH
        ERC20 dai = ERC20(DAI_ADDRESS);
        (uint256 actualETHAmount, uint256 actualDAIAmount) = _kyberTrade(
            dai,
            amount,
            ETH_TOKEN_ADDRESS
        );

        // transfer `actualETHAmount` ETH to `to`
        to.transfer(actualETHAmount);

        // transfer any leftover DAI
        if (actualDAIAmount < amount) {
            dai.safeTransfer(msg.sender, amount.sub(actualDAIAmount));
        }

        return true;
    }

    function burnToToken(
        PooledCDAI pcDAI,
        address tokenAddress,
        address to,
        uint256 amount
    ) public returns (bool) {
        require(
            tokenAddress != address(ETH_TOKEN_ADDRESS),
            "Use burnToETH() instead"
        );
        require(tokenAddress != DAI_ADDRESS, "Use burn() instead");

        // burn `amount` pcDAI for msg.sender to get DAI
        _burn(pcDAI, amount);

        // convert `amount` DAI to token
        ERC20 dai = ERC20(DAI_ADDRESS);
        ERC20 token = ERC20(tokenAddress);
        (uint256 actualTokenAmount, uint256 actualDAIAmount) = _kyberTrade(
            dai,
            amount,
            token
        );

        // transfer `actualTokenAmount` token to `to`
        token.safeTransfer(to, actualTokenAmount);

        // transfer any leftover DAI
        if (actualDAIAmount < amount) {
            dai.safeTransfer(msg.sender, amount.sub(actualDAIAmount));
        }

        return true;
    }

    function _mint(PooledCDAI pcDAI, address to, uint256 actualDAIAmount)
        internal
    {
        ERC20 dai = ERC20(DAI_ADDRESS);
        dai.safeApprove(address(pcDAI), 0);
        dai.safeApprove(address(pcDAI), actualDAIAmount);
        require(pcDAI.mint(to, actualDAIAmount), "Failed to mint pcDAI");
    }

    function _burn(PooledCDAI pcDAI, uint256 amount) internal {
        // transfer `amount` pcDAI from msg.sender
        pcDAI.safeTransferFrom(msg.sender, address(this), amount);

        // burn `amount` pcDAI for DAI
        require(pcDAI.burn(address(this), amount), "Failed to burn pcDAI");
    }

    /**
     * @notice Get the token balance of an account
     * @param _token the token to be queried
     * @param _addr the account whose balance will be returned
     * @return token balance of the account
     */
    function _getBalance(ERC20 _token, address _addr)
        internal
        view
        returns (uint256)
    {
        if (address(_token) == address(ETH_TOKEN_ADDRESS)) {
            return uint256(_addr.balance);
        }
        return uint256(_token.balanceOf(_addr));
    }

    function _toPayableAddr(address _addr)
        internal
        pure
        returns (address payable)
    {
        return address(uint160(_addr));
    }

    /**
     * @notice Wrapper function for doing token conversion on Kyber Network
     * @param _srcToken the token to convert from
     * @param _srcAmount the amount of tokens to be converted
     * @param _destToken the destination token
     * @return _destPriceInSrc the price of the dest token, in terms of source tokens
     *         _srcPriceInDest the price of the source token, in terms of dest tokens
     *         _actualDestAmount actual amount of dest token traded
     *         _actualSrcAmount actual amount of src token traded
     */
    function _kyberTrade(ERC20 _srcToken, uint256 _srcAmount, ERC20 _destToken)
        internal
        returns (uint256 _actualDestAmount, uint256 _actualSrcAmount)
    {
        // Get current rate & ensure token is listed on Kyber
        KyberNetworkProxy kyber = KyberNetworkProxy(KYBER_ADDRESS);
        (, uint256 rate) = kyber.getExpectedRate(
            _srcToken,
            _destToken,
            _srcAmount
        );
        require(rate > 0, "Price for token is 0 on Kyber");

        uint256 beforeSrcBalance = _getBalance(_srcToken, address(this));
        uint256 msgValue;
        if (_srcToken != ETH_TOKEN_ADDRESS) {
            msgValue = 0;
            _srcToken.safeApprove(KYBER_ADDRESS, 0);
            _srcToken.safeApprove(KYBER_ADDRESS, _srcAmount);
        } else {
            msgValue = _srcAmount;
        }
        _actualDestAmount = kyber.tradeWithHint.value(msgValue)(
            _srcToken,
            _srcAmount,
            _destToken,
            _toPayableAddr(address(this)),
            MAX_QTY,
            rate,
            address(0),
            PERM_HINT
        );
        require(_actualDestAmount > 0, "Received 0 dest token");
        if (_srcToken != ETH_TOKEN_ADDRESS) {
            _srcToken.safeApprove(KYBER_ADDRESS, 0);
        }

        _actualSrcAmount = beforeSrcBalance.sub(
            _getBalance(_srcToken, address(this))
        );
    }

    function() external payable {}
}

File 2 of 17 : PooledCDAI.sol
pragma solidity 0.5.17;
pragma experimental ABIEncoderV2;

import "@openzeppelin/contracts/math/SafeMath.sol";
import "@openzeppelin/contracts/token/ERC20/SafeERC20.sol";
import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/ownership/Ownable.sol";
import "./interfaces/CERC20.sol";


contract PooledCDAI is ERC20, Ownable {
    using SafeERC20 for ERC20;
    using SafeMath for uint256;

    uint256 internal constant PRECISION = 10**18;
    uint256 internal constant ERR_CODE_OK = 0;

    CERC20 public constant cDAI = CERC20(
        0x5d3a536E4D6DbD6114cc1Ead35777bAB948E3643
    );
    ERC20 public constant dai = ERC20(
        0x6B175474E89094C44Da98b954EedeAC495271d0F
    );

    string private _name;
    string private _symbol;

    struct Beneficiary {
        address dest;
        uint256 weight;
    }
    Beneficiary[] public beneficiaries; // the accounts that will receive the interests from Compound
    uint256 public totalBeneficiaryWeight; // sum of all beneficiary weights
    bool public initialized;

    event Mint(address indexed sender, address indexed to, uint256 amount);
    event Burn(address indexed sender, address indexed to, uint256 amount);
    event WithdrawInterest(address indexed sender, uint256 amount);
    event SetBeneficiaries(address indexed sender);

    /**
     * @dev Sets the values for `name` and `symbol`. Both of
     * these values are immutable: they can only be set once during
     * construction.
     */
    function init(
        string calldata name,
        string calldata symbol,
        Beneficiary[] calldata _beneficiaries
    ) external {
        require(!initialized, "Already initialized");
        initialized = true;

        _name = name;
        _symbol = symbol;

        // Transfer ownership to msg.sender
        _transferOwnership(msg.sender);

        // Set beneficiaries
        uint256 totalWeight = 0;
        for (uint256 i = 0; i < _beneficiaries.length; i = i.add(1)) {
            totalWeight = totalWeight.add(_beneficiaries[i].weight);
            beneficiaries.push(
                Beneficiary({
                    dest: _beneficiaries[i].dest,
                    weight: _beneficiaries[i].weight
                })
            );
        }
        totalBeneficiaryWeight = totalWeight;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public pure returns (uint8) {
        return 18;
    }

    function mint(address to, uint256 amount) external returns (bool) {
        // transfer `amount` DAI from msg.sender
        dai.safeTransferFrom(msg.sender, address(this), amount);

        // use `amount` DAI to mint cDAI
        dai.safeApprove(address(cDAI), amount);
        require(cDAI.mint(amount) == ERR_CODE_OK, "Failed to mint cDAI");

        // mint `amount` pcDAI for `to`
        _mint(to, amount);

        // emit event
        emit Mint(msg.sender, to, amount);

        return true;
    }

    function burn(address to, uint256 amount) external returns (bool) {
        // burn `amount` pcDAI for msg.sender
        _burn(msg.sender, amount);

        // burn cDAI for `amount` DAI
        require(cDAI.redeemUnderlying(amount) == ERR_CODE_OK, "Failed to redeem");

        // transfer DAI to `to`
        dai.safeTransfer(to, amount);

        // emit event
        emit Burn(msg.sender, to, amount);

        return true;
    }

    function accruedInterestCurrent() public returns (uint256) {
        return
            cDAI
                .exchangeRateCurrent()
                .mul(cDAI.balanceOf(address(this)))
                .div(PRECISION)
                .sub(totalSupply());
    }

    function accruedInterestStored() public view returns (uint256) {
        return
            cDAI
                .exchangeRateStored()
                .mul(cDAI.balanceOf(address(this)))
                .div(PRECISION)
                .sub(totalSupply());
    }

    function withdrawInterestInDAI() external returns (bool) {
        // calculate amount of interest in DAI
        uint256 interestAmount = accruedInterestCurrent();

        // burn cDAI
        require(cDAI.redeemUnderlying(interestAmount) == ERR_CODE_OK, "Failed to redeem");

        // transfer DAI to beneficiaries
        uint256 transferAmount = 0;
        for (uint256 i = 0; i < beneficiaries.length; i = i.add(1)) {
            transferAmount = interestAmount.mul(beneficiaries[i].weight).div(
                totalBeneficiaryWeight
            );
            dai.safeTransfer(beneficiaries[i].dest, transferAmount);
        }

        emit WithdrawInterest(msg.sender, interestAmount);

        return true;
    }

    function setBeneficiaries(Beneficiary[] calldata newBeneficiaries)
        external
        onlyOwner
        returns (bool)
    {
        emit SetBeneficiaries(msg.sender);

        delete beneficiaries;
        uint256 newTotalWeight = 0;
        for (uint256 i = 0; i < newBeneficiaries.length; i = i.add(1)) {
            newTotalWeight = newTotalWeight.add(newBeneficiaries[i].weight);
            beneficiaries.push(
                Beneficiary({
                    dest: newBeneficiaries[i].dest,
                    weight: newBeneficiaries[i].weight
                })
            );
        }
        totalBeneficiaryWeight = newTotalWeight;

        return true;
    }
}

File 3 of 17 : SafeMath.sol
pragma solidity ^0.5.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     *
     * _Available since v2.4.0._
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     *
     * _Available since v2.4.0._
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     *
     * _Available since v2.4.0._
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

File 4 of 17 : SafeERC20.sol
pragma solidity ^0.5.0;

import "./IERC20.sol";
import "../../math/SafeMath.sol";
import "../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for ERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using SafeMath for uint256;
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require((value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).add(value);
        callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).sub(value, "SafeERC20: decreased allowance below zero");
        callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves.

        // A Solidity high level call has three parts:
        //  1. The target address is checked to verify it contains contract code
        //  2. The call itself is made, and success asserted
        //  3. The return value is decoded, which in turn checks the size of the returned data.
        // solhint-disable-next-line max-line-length
        require(address(token).isContract(), "SafeERC20: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = address(token).call(data);
        require(success, "SafeERC20: low-level call failed");

        if (returndata.length > 0) { // Return data is optional
            // solhint-disable-next-line max-line-length
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

File 5 of 17 : IERC20.sol
pragma solidity ^0.5.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP. Does not include
 * the optional functions; to access them see {ERC20Detailed}.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

File 6 of 17 : Address.sol
pragma solidity ^0.5.5;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following 
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // According to EIP-1052, 0x0 is the value returned for not-yet created accounts
        // and 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470 is returned
        // for accounts without code, i.e. `keccak256('')`
        bytes32 codehash;
        bytes32 accountHash = 0xc5d2460186f7233c927e7db2dcc703c0e500b653ca82273b7bfad8045d85a470;
        // solhint-disable-next-line no-inline-assembly
        assembly { codehash := extcodehash(account) }
        return (codehash != accountHash && codehash != 0x0);
    }

    /**
     * @dev Converts an `address` into `address payable`. Note that this is
     * simply a type cast: the actual underlying value is not changed.
     *
     * _Available since v2.4.0._
     */
    function toPayable(address account) internal pure returns (address payable) {
        return address(uint160(account));
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     *
     * _Available since v2.4.0._
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-call-value
        (bool success, ) = recipient.call.value(amount)("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }
}

File 7 of 17 : ERC20.sol
pragma solidity ^0.5.0;

import "../../GSN/Context.sol";
import "./IERC20.sol";
import "../../math/SafeMath.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20Mintable}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin guidelines: functions revert instead
 * of returning `false` on failure. This behavior is nonetheless conventional
 * and does not conflict with the expectations of ERC20 applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20 {
    using SafeMath for uint256;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowances;

    uint256 private _totalSupply;

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20};
     *
     * Requirements:
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for `sender`'s tokens of at least
     * `amount`.
     */
    function transferFrom(address sender, address recipient, uint256 amount) public returns (bool) {
        _transfer(sender, recipient, amount);
        _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].add(addedValue));
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].sub(subtractedValue, "ERC20: decreased allowance below zero"));
        return true;
    }

    /**
     * @dev Moves tokens `amount` from `sender` to `recipient`.
     *
     * This is internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(address sender, address recipient, uint256 amount) internal {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements
     *
     * - `to` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal {
        require(account != address(0), "ERC20: mint to the zero address");

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal {
        require(account != address(0), "ERC20: burn from the zero address");

        _balances[account] = _balances[account].sub(amount, "ERC20: burn amount exceeds balance");
        _totalSupply = _totalSupply.sub(amount);
        emit Transfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner`s tokens.
     *
     * This is internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`.`amount` is then deducted
     * from the caller's allowance.
     *
     * See {_burn} and {_approve}.
     */
    function _burnFrom(address account, uint256 amount) internal {
        _burn(account, amount);
        _approve(account, _msgSender(), _allowances[account][_msgSender()].sub(amount, "ERC20: burn amount exceeds allowance"));
    }
}

File 8 of 17 : Context.sol
pragma solidity ^0.5.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
contract Context {
    // Empty internal constructor, to prevent people from mistakenly deploying
    // an instance of this contract, which should be used via inheritance.
    constructor () internal { }
    // solhint-disable-previous-line no-empty-blocks

    function _msgSender() internal view returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

File 9 of 17 : Ownable.sol
pragma solidity ^0.5.0;

import "../GSN/Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () internal {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(isOwner(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Returns true if the caller is the current owner.
     */
    function isOwner() public view returns (bool) {
        return _msgSender() == _owner;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public onlyOwner {
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     */
    function _transferOwnership(address newOwner) internal {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

File 10 of 17 : CERC20.sol
pragma solidity 0.5.17;


// Compound finance ERC20 market interface
interface CERC20 {
    function mint(uint256 mintAmount) external returns (uint256);

    function redeemUnderlying(uint256 redeemAmount) external returns (uint256);

    function borrow(uint256 borrowAmount) external returns (uint256);

    function repayBorrow(uint256 repayAmount) external returns (uint256);

    function borrowBalanceCurrent(address account) external returns (uint256);

    function exchangeRateCurrent() external returns (uint256);

    function transfer(address recipient, uint256 amount)
        external
        returns (bool);

    function balanceOf(address account) external view returns (uint256);

    function decimals() external view returns (uint256);

    function underlying() external view returns (address);

    function exchangeRateStored() external view returns (uint256);
}

File 11 of 17 : KyberNetworkProxy.sol
pragma solidity 0.5.17;

/**
 * @title The interface for the KyberNetworkProxy smart contract
 */
import "@openzeppelin/contracts/token/ERC20/ERC20.sol";


interface KyberNetworkProxy {
    function getExpectedRate(ERC20 src, ERC20 dest, uint256 srcQty)
        external
        view
        returns (uint256 expectedRate, uint256 slippageRate);

    function tradeWithHint(
        ERC20 src,
        uint256 srcAmount,
        ERC20 dest,
        address payable destAddress,
        uint256 maxDestAmount,
        uint256 minConversionRate,
        address walletId,
        bytes calldata hint
    ) external payable returns (uint256);
}

File 12 of 17 : CloneFactory.sol
pragma solidity 0.5.17;


/*
The MIT License (MIT)

Copyright (c) 2018 Murray Software, LLC.

Permission is hereby granted, free of charge, to any person obtaining
a copy of this software and associated documentation files (the
"Software"), to deal in the Software without restriction, including
without limitation the rights to use, copy, modify, merge, publish,
distribute, sublicense, and/or sell copies of the Software, and to
permit persons to whom the Software is furnished to do so, subject to
the following conditions:

The above copyright notice and this permission notice shall be included
in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
*/
//solhint-disable max-line-length
//solhint-disable no-inline-assembly

contract CloneFactory {
    function createClone(address target) internal returns (address result) {
        bytes20 targetBytes = bytes20(target);
        assembly {
            let clone := mload(0x40)
            mstore(
                clone,
                0x3d602d80600a3d3981f3363d3d373d3d3d363d73000000000000000000000000
            )
            mstore(add(clone, 0x14), targetBytes)
            mstore(
                add(clone, 0x28),
                0x5af43d82803e903d91602b57fd5bf30000000000000000000000000000000000
            )
            result := create(0, clone, 0x37)
        }
    }

    function isClone(address target, address query)
        internal
        view
        returns (bool result)
    {
        bytes20 targetBytes = bytes20(target);
        assembly {
            let clone := mload(0x40)
            mstore(
                clone,
                0x363d3d373d3d3d363d7300000000000000000000000000000000000000000000
            )
            mstore(add(clone, 0xa), targetBytes)
            mstore(
                add(clone, 0x1e),
                0x5af43d82803e903d91602b57fd5bf30000000000000000000000000000000000
            )

            let other := add(clone, 0x40)
            extcodecopy(query, other, 0, 0x2d)
            result := and(
                eq(mload(clone), mload(other)),
                eq(mload(add(clone, 0xd)), mload(add(other, 0xd)))
            )
        }
    }
}

File 13 of 17 : MetadataPooledCDAIFactory.sol
pragma solidity 0.5.17;
pragma experimental ABIEncoderV2;

import "./PooledCDAIFactory.sol";


contract MetadataPooledCDAIFactory is PooledCDAIFactory {
    event CreatePoolWithMetadata(
        address sender,
        address pool,
        bool indexed renounceOwnership,
        bytes metadata
    );

    constructor(address _libraryAddress)
        public
        PooledCDAIFactory(_libraryAddress)
    {}

    function createPCDAIWithMetadata(
        string calldata name,
        string calldata symbol,
        PooledCDAI.Beneficiary[] calldata beneficiaries,
        bool renounceOwnership,
        bytes calldata metadata
    ) external returns (PooledCDAI) {
        PooledCDAI pcDAI = _createPCDAI(
            name,
            symbol,
            beneficiaries,
            renounceOwnership
        );
        emit CreatePoolWithMetadata(
            msg.sender,
            address(pcDAI),
            renounceOwnership,
            metadata
        );
    }
}

File 14 of 17 : PooledCDAIFactory.sol
pragma solidity 0.5.17;
pragma experimental ABIEncoderV2;

import "./lib/CloneFactory.sol";
import "./PooledCDAI.sol";


contract PooledCDAIFactory is CloneFactory {
    address public libraryAddress;

    event CreatePool(
        address sender,
        address pool,
        bool indexed renounceOwnership
    );

    constructor(address _libraryAddress) public {
        libraryAddress = _libraryAddress;
    }

    function createPCDAI(
        string calldata name,
        string calldata symbol,
        PooledCDAI.Beneficiary[] calldata beneficiaries,
        bool renounceOwnership
    ) external returns (PooledCDAI) {
        PooledCDAI pcDAI = _createPCDAI(
            name,
            symbol,
            beneficiaries,
            renounceOwnership
        );
        emit CreatePool(msg.sender, address(pcDAI), renounceOwnership);
        return pcDAI;
    }

    function _createPCDAI(
        string memory name,
        string memory symbol,
        PooledCDAI.Beneficiary[] memory beneficiaries,
        bool renounceOwnership
    ) internal returns (PooledCDAI) {
        address payable clone = _toPayableAddr(createClone(libraryAddress));
        PooledCDAI pcDAI = PooledCDAI(clone);
        pcDAI.init(name, symbol, beneficiaries);
        if (renounceOwnership) {
            pcDAI.renounceOwnership();
        } else {
            pcDAI.transferOwnership(msg.sender);
        }
        return pcDAI;
    }

    function _toPayableAddr(address _addr)
        internal
        pure
        returns (address payable)
    {
        return address(uint160(_addr));
    }
}

File 15 of 17 : PooledCSAI.sol
pragma solidity 0.5.17;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/ownership/Ownable.sol";
import "../interfaces/CERC20.sol";


contract PooledCSAI is ERC20, Ownable {
    uint256 internal constant PRECISION = 10**18;

    address public constant CDAI_ADDRESS = 0xF5DCe57282A584D2746FaF1593d3121Fcac444dC;
    address public constant DAI_ADDRESS = 0x89d24A6b4CcB1B6fAA2625fE562bDD9a23260359;

    string private _name;
    string private _symbol;

    address public beneficiary; // the account that will receive the interests from Compound

    event Mint(address indexed sender, address indexed to, uint256 amount);
    event Burn(address indexed sender, address indexed to, uint256 amount);
    event WithdrawInterest(
        address indexed sender,
        address beneficiary,
        uint256 amount,
        bool indexed inDAI
    );
    event SetBeneficiary(address oldBeneficiary, address newBeneficiary);

    /**
     * @dev Sets the values for `name` and `symbol`. Both of
     * these values are immutable: they can only be set once during
     * construction.
     */
    function init(
        string memory name,
        string memory symbol,
        address _beneficiary
    ) public {
        require(beneficiary == address(0), "Already initialized");

        _name = name;
        _symbol = symbol;

        // Set beneficiary
        require(_beneficiary != address(0), "Beneficiary can't be zero");
        beneficiary = _beneficiary;
        emit SetBeneficiary(address(0), _beneficiary);

        _transferOwnership(msg.sender);
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public pure returns (uint8) {
        return 18;
    }

    function mint(address to, uint256 amount) public returns (bool) {
        // transfer `amount` DAI from msg.sender
        ERC20 dai = ERC20(DAI_ADDRESS);
        require(
            dai.transferFrom(msg.sender, address(this), amount),
            "Failed to transfer DAI from msg.sender"
        );

        // use `amount` DAI to mint cDAI
        CERC20 cDAI = CERC20(CDAI_ADDRESS);
        require(dai.approve(CDAI_ADDRESS, 0), "Failed to clear DAI allowance");
        require(
            dai.approve(CDAI_ADDRESS, amount),
            "Failed to set DAI allowance"
        );
        require(cDAI.mint(amount) == 0, "Failed to mint cDAI");

        // mint `amount` pcDAI for `to`
        _mint(to, amount);

        // emit event
        emit Mint(msg.sender, to, amount);

        return true;
    }

    function burn(address to, uint256 amount) public returns (bool) {
        // burn `amount` pcDAI for msg.sender
        _burn(msg.sender, amount);

        // burn cDAI for `amount` DAI
        CERC20 cDAI = CERC20(CDAI_ADDRESS);
        require(cDAI.redeemUnderlying(amount) == 0, "Failed to redeem");

        // transfer DAI to `to`
        ERC20 dai = ERC20(DAI_ADDRESS);
        require(dai.transfer(to, amount), "Failed to transfer DAI to target");

        // emit event
        emit Burn(msg.sender, to, amount);

        return true;
    }

    function accruedInterestCurrent() public returns (uint256) {
        CERC20 cDAI = CERC20(CDAI_ADDRESS);
        return
            cDAI
                .exchangeRateCurrent()
                .mul(cDAI.balanceOf(address(this)))
                .div(PRECISION)
                .sub(totalSupply());
    }

    function accruedInterestStored() public view returns (uint256) {
        CERC20 cDAI = CERC20(CDAI_ADDRESS);
        return
            cDAI
                .exchangeRateStored()
                .mul(cDAI.balanceOf(address(this)))
                .div(PRECISION)
                .sub(totalSupply());
    }

    function withdrawInterestInDAI() public returns (bool) {
        // calculate amount of interest in DAI
        uint256 interestAmount = accruedInterestCurrent();

        // burn cDAI
        CERC20 cDAI = CERC20(CDAI_ADDRESS);
        require(cDAI.redeemUnderlying(interestAmount) == 0, "Failed to redeem");

        // transfer DAI to beneficiary
        ERC20 dai = ERC20(DAI_ADDRESS);
        require(
            dai.transfer(beneficiary, interestAmount),
            "Failed to transfer DAI to beneficiary"
        );

        emit WithdrawInterest(msg.sender, beneficiary, interestAmount, true);

        return true;
    }

    function withdrawInterestInCDAI() public returns (bool) {
        // calculate amount of cDAI to transfer
        CERC20 cDAI = CERC20(CDAI_ADDRESS);
        uint256 interestAmountInCDAI = accruedInterestCurrent()
            .mul(PRECISION)
            .div(cDAI.exchangeRateCurrent());

        // transfer cDAI to beneficiary
        require(
            cDAI.transfer(beneficiary, interestAmountInCDAI),
            "Failed to transfer cDAI to beneficiary"
        );

        // emit event
        emit WithdrawInterest(
            msg.sender,
            beneficiary,
            interestAmountInCDAI,
            false
        );

        return true;
    }

    function setBeneficiary(address newBeneficiary)
        public
        onlyOwner
        returns (bool)
    {
        require(newBeneficiary != address(0), "Beneficiary can't be zero");
        emit SetBeneficiary(beneficiary, newBeneficiary);

        beneficiary = newBeneficiary;

        return true;
    }

    function() external payable {
        revert("Contract doesn't support receiving Ether");
    }
}

File 16 of 17 : Sai2Dai.sol
pragma solidity 0.5.17;
pragma experimental ABIEncoderV2;

import "@openzeppelin/contracts/ownership/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/SafeERC20.sol";
import "./PooledCSAI.sol";
import "../PooledCDAI.sol";
import "../MetadataPooledCDAIFactory.sol";
import "./ScdMcdMigration.sol";

contract Sai2Dai is Ownable {
    using SafeERC20 for IERC20;
    using SafeERC20 for PooledCSAI;

    uint256 public constant DEV_WEIGHT = 5;
    uint256 public constant BENEFICIARY_WEIGHT = 95;

    mapping (address => address) pSAI2pDAI;
    address public dev;

    MetadataPooledCDAIFactory public factory;
    IERC20 public constant sai = IERC20(0x89d24A6b4CcB1B6fAA2625fE562bDD9a23260359);
    IERC20 public constant dai = IERC20(0x6B175474E89094C44Da98b954EedeAC495271d0F);
    ScdMcdMigration public constant mcdaiMigration = ScdMcdMigration(0xc73e0383F3Aff3215E6f04B0331D58CeCf0Ab849);

    constructor (address factoryAddress) public {
        dev = 0x332D87209f7c8296389C307eAe170c2440830A47;
        factory = MetadataPooledCDAIFactory(factoryAddress);
    }

    function migrate(address payable pSAIAddress, uint256 amount) public {
        // Transfer `amount` pSAI from `msg.sender`
        PooledCSAI pSAI = PooledCSAI(pSAIAddress);
        pSAI.safeTransferFrom(msg.sender, address(this), amount);

        // Burn `amount` pSAI for SAI
        pSAI.burn(address(this), amount);

        // Convert `amount` SAI to DAI
        sai.safeApprove(address(mcdaiMigration), amount);
        mcdaiMigration.swapSaiToDai(amount);

        // Create pDAI contract if not already created
        PooledCDAI pDAI;
        if (pSAI2pDAI[pSAIAddress] == address(0)) {
            PooledCDAI.Beneficiary[] memory beneficiaries = new PooledCDAI.Beneficiary[](2);
            beneficiaries[0] = PooledCDAI.Beneficiary({
                dest: pSAI.beneficiary(),
                weight: BENEFICIARY_WEIGHT
            });
            beneficiaries[1] = PooledCDAI.Beneficiary({
                dest: dev,
                weight: DEV_WEIGHT
            });
            pDAI = factory.createPCDAI(pSAI.name(), pSAI.symbol(), beneficiaries, false);
            pDAI.transferOwnership(pSAI.owner());
            pSAI2pDAI[pSAIAddress] = address(pDAI);
        } else {
            pDAI = PooledCDAI(pSAI2pDAI[pSAIAddress]);
        }

        // Mint `amount` pDAI for `msg.sender`
        dai.safeApprove(address(pDAI), amount);
        pDAI.mint(msg.sender, amount);
    }

    function setDev(address newDev) external onlyOwner {
        dev = newDev;
    }
}

File 17 of 17 : ScdMcdMigration.sol
pragma solidity 0.5.17;


interface ScdMcdMigration {
    // Function to swap SAI to DAI
    // This function is to be used by users that want to get new DAI in exchange of old one (aka SAI)
    // wad amount has to be <= the value pending to reach the debt ceiling (the minimum between general and ilk one)
    function swapSaiToDai(uint256 wad) external;
}

Settings
{
  "metadata": {
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "abi"
      ]
    }
  }
}

Contract ABI

[{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"owner","type":"address"},{"indexed":true,"internalType":"address","name":"spender","type":"address"},{"indexed":false,"internalType":"uint256","name":"value","type":"uint256"}],"name":"Approval","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"sender","type":"address"},{"indexed":true,"internalType":"address","name":"to","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"Burn","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"sender","type":"address"},{"indexed":true,"internalType":"address","name":"to","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"Mint","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"previousOwner","type":"address"},{"indexed":true,"internalType":"address","name":"newOwner","type":"address"}],"name":"OwnershipTransferred","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"sender","type":"address"}],"name":"SetBeneficiaries","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"from","type":"address"},{"indexed":true,"internalType":"address","name":"to","type":"address"},{"indexed":false,"internalType":"uint256","name":"value","type":"uint256"}],"name":"Transfer","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"sender","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"WithdrawInterest","type":"event"},{"constant":false,"inputs":[],"name":"accruedInterestCurrent","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":true,"inputs":[],"name":"accruedInterestStored","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":true,"inputs":[{"internalType":"address","name":"owner","type":"address"},{"internalType":"address","name":"spender","type":"address"}],"name":"allowance","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":false,"inputs":[{"internalType":"address","name":"spender","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"approve","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":true,"inputs":[{"internalType":"address","name":"account","type":"address"}],"name":"balanceOf","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":true,"inputs":[{"internalType":"uint256","name":"","type":"uint256"}],"name":"beneficiaries","outputs":[{"internalType":"address","name":"dest","type":"address"},{"internalType":"uint256","name":"weight","type":"uint256"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":false,"inputs":[{"internalType":"address","name":"to","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"burn","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":true,"inputs":[],"name":"cDAI","outputs":[{"internalType":"contract CERC20","name":"","type":"address"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":true,"inputs":[],"name":"dai","outputs":[{"internalType":"contract ERC20","name":"","type":"address"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":true,"inputs":[],"name":"decimals","outputs":[{"internalType":"uint8","name":"","type":"uint8"}],"payable":false,"stateMutability":"pure","type":"function"},{"constant":false,"inputs":[{"internalType":"address","name":"spender","type":"address"},{"internalType":"uint256","name":"subtractedValue","type":"uint256"}],"name":"decreaseAllowance","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":false,"inputs":[{"internalType":"address","name":"spender","type":"address"},{"internalType":"uint256","name":"addedValue","type":"uint256"}],"name":"increaseAllowance","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":false,"inputs":[{"internalType":"string","name":"name","type":"string"},{"internalType":"string","name":"symbol","type":"string"},{"components":[{"internalType":"address","name":"dest","type":"address"},{"internalType":"uint256","name":"weight","type":"uint256"}],"internalType":"struct PooledCDAI.Beneficiary[]","name":"_beneficiaries","type":"tuple[]"}],"name":"init","outputs":[],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":true,"inputs":[],"name":"initialized","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":true,"inputs":[],"name":"isOwner","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":false,"inputs":[{"internalType":"address","name":"to","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"mint","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":true,"inputs":[],"name":"name","outputs":[{"internalType":"string","name":"","type":"string"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":true,"inputs":[],"name":"owner","outputs":[{"internalType":"address","name":"","type":"address"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":false,"inputs":[],"name":"renounceOwnership","outputs":[],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":false,"inputs":[{"components":[{"internalType":"address","name":"dest","type":"address"},{"internalType":"uint256","name":"weight","type":"uint256"}],"internalType":"struct PooledCDAI.Beneficiary[]","name":"newBeneficiaries","type":"tuple[]"}],"name":"setBeneficiaries","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":true,"inputs":[],"name":"symbol","outputs":[{"internalType":"string","name":"","type":"string"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":true,"inputs":[],"name":"totalBeneficiaryWeight","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":true,"inputs":[],"name":"totalSupply","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":false,"inputs":[{"internalType":"address","name":"recipient","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"transfer","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":false,"inputs":[{"internalType":"address","name":"sender","type":"address"},{"internalType":"address","name":"recipient","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"transferFrom","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":false,"inputs":[{"internalType":"address","name":"newOwner","type":"address"}],"name":"transferOwnership","outputs":[],"payable":false,"stateMutability":"nonpayable","type":"function"},{"constant":false,"inputs":[],"name":"withdrawInterestInDAI","outputs":[{"internalType":"bool","name":"","type":"bool"}],"payable":false,"stateMutability":"nonpayable","type":"function"}]

Block Transaction Difficulty Gas Used Reward
Block Uncle Number Difficulty Gas Used Reward
Loading
Loading
Make sure to use the "Vote Down" button for any spammy posts, and the "Vote Up" for interesting conversations.

A contract address hosts a smart contract, which is a set of code stored on the blockchain that runs when predetermined conditions are met. Learn more about addresses in our Knowledge Base.