ETH Price: $2,757.10 (-0.52%)

Contract

0xE8e8041cB5E3158A0829A19E014CA1cf91098554
 

Overview

ETH Balance

3.406613033467897296 ETH

Eth Value

$9,392.37 (@ $2,757.10/ETH)

Token Holdings

Multichain Info

No addresses found
Transaction Hash
Method
Block
From
To
Exec Transaction216671022025-01-20 17:09:2317 days ago1737392963IN
0xE8e8041c...f91098554
0 ETH0.0952637650.58063475
Exec Transaction213370552024-12-05 15:01:1163 days ago1733410871IN
0xE8e8041c...f91098554
0 ETH0.0022696827.85165591
Exec Transaction212751342024-11-26 23:12:5972 days ago1732662779IN
0xE8e8041c...f91098554
0 ETH0.000806787.04553616
Exec Transaction210944632024-11-01 18:02:5997 days ago1730484179IN
0xE8e8041c...f91098554
0 ETH0.0014680512.80369878
Exec Transaction209855032024-10-17 13:11:47112 days ago1729170707IN
0xE8e8041c...f91098554
0 ETH0.0015253421.53255816
Exec Transaction208281842024-09-25 14:22:11134 days ago1727274131IN
0xE8e8041c...f91098554
0 ETH0.0860258431.17297342
Exec Transaction205702212024-08-20 13:46:23170 days ago1724161583IN
0xE8e8041c...f91098554
0 ETH0.008918842.478239
Exec Transaction205641122024-08-19 17:18:23171 days ago1724087903IN
0xE8e8041c...f91098554
0 ETH0.000247592.74026925
Exec Transaction204199002024-07-30 14:14:59191 days ago1722348899IN
0xE8e8041c...f91098554
0 ETH0.0012377314.25120764
Exec Transaction204197312024-07-30 13:40:47191 days ago1722346847IN
0xE8e8041c...f91098554
0 ETH0.0008299710
Exec Transaction204129242024-07-29 14:49:35192 days ago1722264575IN
0xE8e8041c...f91098554
0 ETH0.000725997.53963467
Exec Transaction203765622024-07-24 13:00:23197 days ago1721826023IN
0xE8e8041c...f91098554
0 ETH0.041585037.65657723
Exec Transaction201709002024-06-25 19:51:23226 days ago1719345083IN
0xE8e8041c...f91098554
0 ETH0.0013787512.82944573
Exec Transaction200818212024-06-13 8:50:35239 days ago1718268635IN
0xE8e8041c...f91098554
0 ETH0.0022849114
Exec Transaction199685062024-05-28 12:56:35254 days ago1716900995IN
0xE8e8041c...f91098554
0 ETH0.0022495824.89359825
Exec Transaction199624422024-05-27 16:36:47255 days ago1716827807IN
0xE8e8041c...f91098554
0 ETH0.002695625.08563591
Exec Transaction199205002024-05-21 19:54:35261 days ago1716321275IN
0xE8e8041c...f91098554
0 ETH0.0116187816
Exec Transaction197765162024-05-01 16:36:35281 days ago1714581395IN
0xE8e8041c...f91098554
0 ETH0.0094894213
Exec Transaction197758122024-05-01 14:15:23281 days ago1714572923IN
0xE8e8041c...f91098554
0 ETH0.0141313612
Exec Transaction197191232024-04-23 15:55:59289 days ago1713887759IN
0xE8e8041c...f91098554
0 ETH0.0008508617
Exec Transaction197189292024-04-23 15:16:59289 days ago1713885419IN
0xE8e8041c...f91098554
0 ETH0.0027335519.39557902
Exec Transaction197185772024-04-23 14:05:59289 days ago1713881159IN
0xE8e8041c...f91098554
0 ETH0.00394528
Exec Transaction197185682024-04-23 14:04:11289 days ago1713881051IN
0xE8e8041c...f91098554
0 ETH0.0042159129.92322266
Exec Transaction197185432024-04-23 13:58:59289 days ago1713880739IN
0xE8e8041c...f91098554
0 ETH0.0010631416.27415264
Exec Transaction196703022024-04-16 20:04:11296 days ago1713297851IN
0xE8e8041c...f91098554
0 ETH0.0010186113.27271155
View all transactions

Latest 11 internal transactions

Advanced mode:
Parent Transaction Hash Block
From
To
216988702025-01-25 3:34:2313 days ago1737776063
0xE8e8041c...f91098554
0.0069927 ETH
216970182025-01-24 21:21:5913 days ago1737753719
0xE8e8041c...f91098554
0.01869084 ETH
204621082024-08-05 11:36:59186 days ago1722857819
0xE8e8041c...f91098554
0.07817695 ETH
200805152024-06-13 4:27:11239 days ago1718252831
0xE8e8041c...f91098554
0.0000419 ETH
200805082024-06-13 4:25:47239 days ago1718252747
0xE8e8041c...f91098554
0.00003921 ETH
200804842024-06-13 4:20:59239 days ago1718252459
0xE8e8041c...f91098554
0.00004079 ETH
200804772024-06-13 4:19:35239 days ago1718252375
0xE8e8041c...f91098554
0.00002504 ETH
200108682024-06-03 11:02:47249 days ago1717412567
0xE8e8041c...f91098554
0.23949891 ETH
197019002024-04-21 6:09:59292 days ago1713679799
0xE8e8041c...f91098554
0.0132117 ETH
171757052023-05-02 21:18:35646 days ago1683062315
0xE8e8041c...f91098554
0.05 ETH
171753762023-05-02 20:12:23646 days ago1683058343  Contract Creation0 ETH
Loading...
Loading

Similar Match Source Code
This contract matches the deployed Bytecode of the Source Code for Contract 0xDaB5dc22...0ba42d2a6
The constructor portion of the code might be different and could alter the actual behaviour of the contract

Contract Name:
GnosisSafeProxy

Compiler Version
v0.7.6+commit.7338295f

Optimization Enabled:
No with 200 runs

Other Settings:
default evmVersion, GNU LGPLv3 license
/**
 *Submitted for verification at Etherscan.io on 2021-07-09
*/

// SPDX-License-Identifier: LGPL-3.0-only
pragma solidity >=0.7.0 <0.9.0;

/// @title IProxy - Helper interface to access masterCopy of the Proxy on-chain
/// @author Richard Meissner - <[email protected]>
interface IProxy {
    function masterCopy() external view returns (address);
}

/// @title GnosisSafeProxy - Generic proxy contract allows to execute all transactions applying the code of a master contract.
/// @author Stefan George - <[email protected]>
/// @author Richard Meissner - <[email protected]>
contract GnosisSafeProxy {
    // singleton always needs to be first declared variable, to ensure that it is at the same location in the contracts to which calls are delegated.
    // To reduce deployment costs this variable is internal and needs to be retrieved via `getStorageAt`
    address internal singleton;

    /// @dev Constructor function sets address of singleton contract.
    /// @param _singleton Singleton address.
    constructor(address _singleton) {
        require(_singleton != address(0), "Invalid singleton address provided");
        singleton = _singleton;
    }

    /// @dev Fallback function forwards all transactions and returns all received return data.
    fallback() external payable {
        // solhint-disable-next-line no-inline-assembly
        assembly {
            let _singleton := and(sload(0), 0xffffffffffffffffffffffffffffffffffffffff)
            // 0xa619486e == keccak("masterCopy()"). The value is right padded to 32-bytes with 0s
            if eq(calldataload(0), 0xa619486e00000000000000000000000000000000000000000000000000000000) {
                mstore(0, _singleton)
                return(0, 0x20)
            }
            calldatacopy(0, 0, calldatasize())
            let success := delegatecall(gas(), _singleton, 0, calldatasize(), 0, 0)
            returndatacopy(0, 0, returndatasize())
            if eq(success, 0) {
                revert(0, returndatasize())
            }
            return(0, returndatasize())
        }
    }
}

/// @title Proxy Factory - Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
/// @author Stefan George - <[email protected]>
contract GnosisSafeProxyFactory {
    event ProxyCreation(GnosisSafeProxy proxy, address singleton);

    /// @dev Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
    /// @param singleton Address of singleton contract.
    /// @param data Payload for message call sent to new proxy contract.
    function createProxy(address singleton, bytes memory data) public returns (GnosisSafeProxy proxy) {
        proxy = new GnosisSafeProxy(singleton);
        if (data.length > 0)
            // solhint-disable-next-line no-inline-assembly
            assembly {
                if eq(call(gas(), proxy, 0, add(data, 0x20), mload(data), 0, 0), 0) {
                    revert(0, 0)
                }
            }
        emit ProxyCreation(proxy, singleton);
    }

    /// @dev Allows to retrieve the runtime code of a deployed Proxy. This can be used to check that the expected Proxy was deployed.
    function proxyRuntimeCode() public pure returns (bytes memory) {
        return type(GnosisSafeProxy).runtimeCode;
    }

    /// @dev Allows to retrieve the creation code used for the Proxy deployment. With this it is easily possible to calculate predicted address.
    function proxyCreationCode() public pure returns (bytes memory) {
        return type(GnosisSafeProxy).creationCode;
    }

    /// @dev Allows to create new proxy contact using CREATE2 but it doesn't run the initializer.
    ///      This method is only meant as an utility to be called from other methods
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function deployProxyWithNonce(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce
    ) internal returns (GnosisSafeProxy proxy) {
        // If the initializer changes the proxy address should change too. Hashing the initializer data is cheaper than just concatinating it
        bytes32 salt = keccak256(abi.encodePacked(keccak256(initializer), saltNonce));
        bytes memory deploymentData = abi.encodePacked(type(GnosisSafeProxy).creationCode, uint256(uint160(_singleton)));
        // solhint-disable-next-line no-inline-assembly
        assembly {
            proxy := create2(0x0, add(0x20, deploymentData), mload(deploymentData), salt)
        }
        require(address(proxy) != address(0), "Create2 call failed");
    }

    /// @dev Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function createProxyWithNonce(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce
    ) public returns (GnosisSafeProxy proxy) {
        proxy = deployProxyWithNonce(_singleton, initializer, saltNonce);
        if (initializer.length > 0)
            // solhint-disable-next-line no-inline-assembly
            assembly {
                if eq(call(gas(), proxy, 0, add(initializer, 0x20), mload(initializer), 0, 0), 0) {
                    revert(0, 0)
                }
            }
        emit ProxyCreation(proxy, _singleton);
    }

    /// @dev Allows to create new proxy contact, execute a message call to the new proxy and call a specified callback within one transaction
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    /// @param callback Callback that will be invoced after the new proxy contract has been successfully deployed and initialized.
    function createProxyWithCallback(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce,
        IProxyCreationCallback callback
    ) public returns (GnosisSafeProxy proxy) {
        uint256 saltNonceWithCallback = uint256(keccak256(abi.encodePacked(saltNonce, callback)));
        proxy = createProxyWithNonce(_singleton, initializer, saltNonceWithCallback);
        if (address(callback) != address(0)) callback.proxyCreated(proxy, _singleton, initializer, saltNonce);
    }

    /// @dev Allows to get the address for a new proxy contact created via `createProxyWithNonce`
    ///      This method is only meant for address calculation purpose when you use an initializer that would revert,
    ///      therefore the response is returned with a revert. When calling this method set `from` to the address of the proxy factory.
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function calculateCreateProxyWithNonceAddress(
        address _singleton,
        bytes calldata initializer,
        uint256 saltNonce
    ) external returns (GnosisSafeProxy proxy) {
        proxy = deployProxyWithNonce(_singleton, initializer, saltNonce);
        revert(string(abi.encodePacked(proxy)));
    }
}

interface IProxyCreationCallback {
    function proxyCreated(
        GnosisSafeProxy proxy,
        address _singleton,
        bytes calldata initializer,
        uint256 saltNonce
    ) external;
}

Contract Security Audit

Contract ABI

[{"inputs":[{"internalType":"address","name":"_singleton","type":"address"}],"stateMutability":"nonpayable","type":"constructor"},{"stateMutability":"payable","type":"fallback"}]

Deployed Bytecode

0x608060405273ffffffffffffffffffffffffffffffffffffffff600054167fa619486e0000000000000000000000000000000000000000000000000000000060003514156050578060005260206000f35b3660008037600080366000845af43d6000803e60008114156070573d6000fd5b3d6000f3fea2646970667358221220d1429297349653a4918076d650332de1a1068c5f3e07c5c82360c277770b955264736f6c63430007060033

Deployed Bytecode Sourcemap

524:1528:0:-:0;;;1376:42;1372:1;1366:8;1362:57;1556:66;1552:1;1539:15;1536:87;1533:2;;;1653:10;1650:1;1643:21;1692:4;1689:1;1682:15;1533:2;1745:14;1742:1;1739;1726:34;1843:1;1840;1824:14;1821:1;1809:10;1802:5;1789:56;1880:16;1877:1;1874;1859:38;1926:1;1917:7;1914:14;1911:2;;;1958:16;1955:1;1948:27;1911:2;2014:16;2011:1;2004:27

Swarm Source

ipfs://d1429297349653a4918076d650332de1a1068c5f3e07c5c82360c277770b9552

Block Transaction Difficulty Gas Used Reward
View All Blocks Produced

Block Uncle Number Difficulty Gas Used Reward
View All Uncles
Loading...
Loading
Loading...
Loading

Validator Index Block Amount
View All Withdrawals

Transaction Hash Block Value Eth2 PubKey Valid
View All Deposits
Chain Token Portfolio % Price Amount Value
ETH79.88%$2,757.8420.5825$56,763.19
ETH
Ether (ETH)
13.22%$2,757.843.4066$9,394.9
ETH3.68%$0.9999672,614.6724$2,614.59
ETH1.59%$25.1344.9978$1,130.79
ETH0.48%$0.355522950.4406$337.9
ETH0.34%$3,272.010.0741$242.5
ETH0.16%$6,850.740.0171$117.18
ETH0.16%$3,080.870.0378$116.51
ETH0.16%$2.1851.6409$112.45
ETH0.13%$1.9247.8286$91.83
ETH0.05%$135.8886$35.89
ETH0.03%$0.000012,439,926.7404$23.18
ETH0.03%$5.933.8739$22.97
ETH0.03%$2,895.740.00690488$19.99
ETH0.02%$88.660.1994$17.68
ETH<0.01%$1.016.6215$6.67
ETH<0.01%$3,281.30.00115777$3.8
ETH<0.01%$0.4868356.4243$3.13
ETH<0.01%$2,993.20.00077487$2.32
ETH<0.01%$5,820.50.00023947$1.39
ETH<0.01%$97,4480.00001282$1.25
Loading...
Loading
[ Download: CSV Export  ]
[ Download: CSV Export  ]

A contract address hosts a smart contract, which is a set of code stored on the blockchain that runs when predetermined conditions are met. Learn more about addresses in our Knowledge Base.